WebSVN – HelenOS – Diff – /trunk/kernel/arch/ia32/src/asm.S


#
# Copyright (c) 2001-2004 Jakub Jermar
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
#
# - Redistributions of source code must retain the above copyright
#   notice, this list of conditions and the following disclaimer.
# - Redistributions in binary form must reproduce the above copyright
#   notice, this list of conditions and the following disclaimer in the
#   documentation and/or other materials provided with the distribution.
# - The name of the author may not be used to endorse or promote products
#   derived from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
#
 
## very low and hardware-level functions
 
# Mask for interrupts 0 - 31 (bits 0 - 31) where 0 means that int has no error
# word and 1 means interrupt with error word
#define ERROR_WORD_INTERRUPT_LIST 0x00027d00
 
.text
 
.global paging_on
.global enable_l_apic_in_msr
.global interrupt_handlers
.global memsetb
.global memsetw
.global memcpy
.global memcpy_from_uspace
.global memcpy_from_uspace_failover_address
.global memcpy_to_uspace
.global memcpy_to_uspace_failover_address
 
 
# Wrapper for generic memsetb
memsetb:
	jmp _memsetb
 
# Wrapper for generic memsetw
memsetw:
	jmp _memsetw
 
 
#define MEMCPY_DST	4
#define MEMCPY_SRC	8
#define MEMCPY_SIZE	12
 
/** Copy memory to/from userspace.
 *
 * This is almost conventional memcpy().
 * The difference is that there is a failover part
 * to where control is returned from a page fault
 * if the page fault occurs during copy_from_uspace()
 * or copy_to_uspace().
 *
 * @param MEMCPY_DST(%esp)	Destination address.
 * @param MEMCPY_SRC(%esp)	Source address.
 * @param MEMCPY_SIZE(%esp)	Size.
 *
 * @return MEMCPY_DST(%esp) on success and 0 on failure.
 */
memcpy:
memcpy_from_uspace:
memcpy_to_uspace:
	movl %edi, %edx			/* save %edi */
	movl %esi, %eax			/* save %esi */
	
	movl MEMCPY_SIZE(%esp), %ecx
	shrl $2, %ecx			/* size / 4 */
	
	movl MEMCPY_DST(%esp), %edi
	movl MEMCPY_SRC(%esp), %esi
	
	rep movsl			/* copy whole words */
 
	movl MEMCPY_SIZE(%esp), %ecx
	andl $3, %ecx			/* size % 4 */
	jz 0f
	
	rep movsb			/* copy the rest byte by byte */
 
0:
	movl %edx, %edi
	movl %eax, %esi
	movl MEMCPY_DST(%esp), %eax	/* MEMCPY_DST(%esp), success */
	ret
	
/*
 * We got here from as_page_fault() after the memory operations
 * above had caused a page fault.
 */
memcpy_from_uspace_failover_address:
memcpy_to_uspace_failover_address:
	movl %edx, %edi
	movl %eax, %esi
	xorl %eax, %eax			/* return 0, failure */
	ret
 
## Turn paging on
#
# Enable paging and write-back caching in CR0.
#
paging_on:
	movl %cr0, %edx
	orl $(1 << 31), %edx		# paging on
	# clear Cache Disable and not Write Though
	andl $~((1 << 30) | (1 << 29)), %edx
	movl %edx,%cr0
	jmp 0f
0:
	ret
 
 
## Enable local APIC
#
# Enable local APIC in MSR.
#
enable_l_apic_in_msr:
	movl $0x1b, %ecx
	rdmsr
	orl $(1 << 11), %eax
	orl $(0xfee00000), %eax
	wrmsr
	ret
 
# Clear nested flag
# overwrites %ecx
.macro CLEAR_NT_FLAG
	pushfl
	pop %ecx
	and $0xffffbfff, %ecx
	push %ecx
	popfl
.endm	
 
/*
 * The SYSENTER syscall mechanism can be used for syscalls with
 * four or fewer arguments. To pass these four arguments, we
 * use four registers: EDX, ECX, EBX, ESI. The syscall number
 * is passed in EAX. We use EDI to remember the return address
 * and EBP to remember the stack. The INT-based syscall mechanism
 * can actually handle six arguments plus the syscall number
 * entirely in registers.
 */
.global sysenter_handler
sysenter_handler:
	pushl %ebp	# remember user stack
	pushl %edi	# remember return user address
 
	pushl %gs	# remember TLS
 
	pushl %eax	# syscall number
	subl $8, %esp	# unused sixth and fifth argument
	pushl %esi	# fourth argument
	pushl %ebx	# third argument
	pushl %ecx	# second argument
	pushl %edx	# first argument
 
	movw $16, %ax
	movw %ax, %ds
	movw %ax, %es
 
	cld
	call syscall_handler
	addl $28, %esp	# remove arguments from stack
 
	pop %gs		# restore TLS
 
	pop %edx	# prepare return EIP for SYSEXIT
	pop %ecx	# prepare userspace ESP for SYSEXIT
 
	sysexit		# return to userspace
 
 
## Declare interrupt handlers
#
# Declare interrupt handlers for n interrupt
# vectors starting at vector i.
#
# The handlers setup data segment registers
# and call exc_dispatch().
#
#define INTERRUPT_ALIGN 64
.macro handler i n
 
.ifeq \i - 0x30     # Syscall handler
	pushl %ds
	pushl %es
	pushl %fs
	pushl %gs
 
	#
	# Push syscall arguments onto the stack
	#
	# NOTE: The idea behind the order of arguments passed in registers is to
	#	use all scratch registers first and preserved registers next.
	#	An optimized libc syscall wrapper can make use of this setup.
	#
	pushl %eax
	pushl %ebp
	pushl %edi
	pushl %esi
	pushl %ebx
	pushl %ecx
	pushl %edx
	
	# we must fill the data segment registers
	movw $16, %ax
	movw %ax, %ds
	movw %ax, %es
	
	cld
	sti
	# syscall_handler(edx, ecx, ebx, esi, edi, ebp, eax)
	call syscall_handler   
	cli
	addl $28, %esp         # clean-up of parameters
	
	popl %gs
	popl %fs
	popl %es
	popl %ds
	
	CLEAR_NT_FLAG
	iret
.else	
	/*
	 * This macro distinguishes between two versions of ia32 exceptions.
	 * One version has error word and the other does not have it.
	 * The latter version fakes the error word on the stack so that the
	 * handlers and istate_t can be the same for both types.
	 */
	.iflt \i - 32
		.if (1 << \i) & ERROR_WORD_INTERRUPT_LIST
			/* 
			 * With error word, do nothing
			 */
                .else
                        /*
                         * Version without error word,
                         */
			subl $4, %esp
                .endif
        .else
                /*
                 * Version without error word,
                 */
		subl $4, %esp
	.endif
	
	pushl %ds
	pushl %es
	pushl %fs
	pushl %gs
 
#ifdef CONFIG_DEBUG_ALLREGS
	pushl %ebx
	pushl %ebp
	pushl %edi
	pushl %esi
#else
	subl $16, %esp
#endif
	pushl %edx
	pushl %ecx
	pushl %eax
	
	# we must fill the data segment registers
	movw $16, %ax
	movw %ax, %ds
	movw %ax, %es
 
	cld
 
	pushl %esp          # *istate
	pushl $(\i)         # intnum
	call exc_dispatch   # excdispatch(intnum, *istate)
	addl $8, %esp       # Clear arguments from stack
 
	CLEAR_NT_FLAG # Modifies %ecx
	
	popl %eax
	popl %ecx
	popl %edx
#ifdef CONFIG_DEBUG_ALLREGS
	popl %esi
	popl %edi
	popl %ebp
	popl %ebx
#else
	addl $16, %esp
#endif	
	
	popl %gs
	popl %fs
	popl %es
	popl %ds
 
	addl $4, %esp	# Skip error word, no matter whether real or fake.
	iret
.endif
 
	.align INTERRUPT_ALIGN
	.if (\n- \i) - 1
	handler "(\i + 1)", \n
	.endif
.endm
 
# keep in sync with pm.h !!!
IDT_ITEMS = 64
.align INTERRUPT_ALIGN
interrupt_handlers:
h_start:
	handler 0 IDT_ITEMS
h_end:
 
.data
.global interrupt_handler_size
 
interrupt_handler_size: .long (h_end - h_start) / IDT_ITEMS
 

Rev 3274	Rev 3485
1	#	1	#
2	# Copyright (c) 2001-2004 Jakub Jermar	2	# Copyright (c) 2001-2004 Jakub Jermar
3	# All rights reserved.	3	# All rights reserved.
4	#	4	#
5	# Redistribution and use in source and binary forms, with or without	5	# Redistribution and use in source and binary forms, with or without
6	# modification, are permitted provided that the following conditions	6	# modification, are permitted provided that the following conditions
7	# are met:	7	# are met:
8	#	8	#
9	# - Redistributions of source code must retain the above copyright	9	# - Redistributions of source code must retain the above copyright
10	# notice, this list of conditions and the following disclaimer.	10	# notice, this list of conditions and the following disclaimer.
11	# - Redistributions in binary form must reproduce the above copyright	11	# - Redistributions in binary form must reproduce the above copyright
12	# notice, this list of conditions and the following disclaimer in the	12	# notice, this list of conditions and the following disclaimer in the
13	# documentation and/or other materials provided with the distribution.	13	# documentation and/or other materials provided with the distribution.
14	# - The name of the author may not be used to endorse or promote products	14	# - The name of the author may not be used to endorse or promote products
15	# derived from this software without specific prior written permission.	15	# derived from this software without specific prior written permission.
16	#	16	#
17	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR	17	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
18	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES	18	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
19	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.	19	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
20	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,	20	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
21	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT	21	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
22	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,	22	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
23	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY	23	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
24	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT	24	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
25	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF	25	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
26	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.	26	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
27	#	27	#
28		28
29	## very low and hardware-level functions	29	## very low and hardware-level functions
30		30
31	# Mask for interrupts 0 - 31 (bits 0 - 31) where 0 means that int has no error	31	# Mask for interrupts 0 - 31 (bits 0 - 31) where 0 means that int has no error
32	# word and 1 means interrupt with error word	32	# word and 1 means interrupt with error word
33	#define ERROR_WORD_INTERRUPT_LIST 0x00027d00	33	#define ERROR_WORD_INTERRUPT_LIST 0x00027d00
34		34
35	.text	35	.text
36		36
37	.global paging_on	37	.global paging_on
38	.global enable_l_apic_in_msr	38	.global enable_l_apic_in_msr
39	.global interrupt_handlers	39	.global interrupt_handlers
40	.global memsetb	40	.global memsetb
41	.global memsetw	41	.global memsetw
42	.global memcpy	42	.global memcpy
43	.global memcpy_from_uspace	43	.global memcpy_from_uspace
44	.global memcpy_from_uspace_failover_address	44	.global memcpy_from_uspace_failover_address
45	.global memcpy_to_uspace	45	.global memcpy_to_uspace
46	.global memcpy_to_uspace_failover_address	46	.global memcpy_to_uspace_failover_address
47		47
48		48
49	# Wrapper for generic memsetb	49	# Wrapper for generic memsetb
50	memsetb:	50	memsetb:
51	jmp _memsetb	51	jmp _memsetb
52		52
53	# Wrapper for generic memsetw	53	# Wrapper for generic memsetw
54	memsetw:	54	memsetw:
55	jmp _memsetw	55	jmp _memsetw
56		56
57		57
58	#define MEMCPY_DST 4	58	#define MEMCPY_DST 4
59	#define MEMCPY_SRC 8	59	#define MEMCPY_SRC 8
60	#define MEMCPY_SIZE 12	60	#define MEMCPY_SIZE 12
61		61
62	/** Copy memory to/from userspace.	62	/** Copy memory to/from userspace.
63	*	63	*
64	* This is almost conventional memcpy().	64	* This is almost conventional memcpy().
65	* The difference is that there is a failover part	65	* The difference is that there is a failover part
66	* to where control is returned from a page fault	66	* to where control is returned from a page fault
67	* if the page fault occurs during copy_from_uspace()	67	* if the page fault occurs during copy_from_uspace()
68	* or copy_to_uspace().	68	* or copy_to_uspace().
69	*	69	*
70	* @param MEMCPY_DST(%esp) Destination address.	70	* @param MEMCPY_DST(%esp) Destination address.
71	* @param MEMCPY_SRC(%esp) Source address.	71	* @param MEMCPY_SRC(%esp) Source address.
72	* @param MEMCPY_SIZE(%esp) Size.	72	* @param MEMCPY_SIZE(%esp) Size.
73	*	73	*
74	* @return MEMCPY_DST(%esp) on success and 0 on failure.	74	* @return MEMCPY_DST(%esp) on success and 0 on failure.
75	*/	75	*/
76	memcpy:	76	memcpy:
77	memcpy_from_uspace:	77	memcpy_from_uspace:
78	memcpy_to_uspace:	78	memcpy_to_uspace:
79	movl %edi, %edx /* save %edi */	79	movl %edi, %edx /* save %edi */
80	movl %esi, %eax /* save %esi */	80	movl %esi, %eax /* save %esi */
81		81
82	movl MEMCPY_SIZE(%esp), %ecx	82	movl MEMCPY_SIZE(%esp), %ecx
83	shrl $2, %ecx /* size / 4 */	83	shrl $2, %ecx /* size / 4 */
84		84
85	movl MEMCPY_DST(%esp), %edi	85	movl MEMCPY_DST(%esp), %edi
86	movl MEMCPY_SRC(%esp), %esi	86	movl MEMCPY_SRC(%esp), %esi
87		87
88	rep movsl /* copy whole words */	88	rep movsl /* copy whole words */
89		89
90	movl MEMCPY_SIZE(%esp), %ecx	90	movl MEMCPY_SIZE(%esp), %ecx
91	andl $3, %ecx /* size % 4 */	91	andl $3, %ecx /* size % 4 */
92	jz 0f	92	jz 0f
93		93
94	rep movsb /* copy the rest byte by byte */	94	rep movsb /* copy the rest byte by byte */
95		95
96	0:	96	0:
97	movl %edx, %edi	97	movl %edx, %edi
98	movl %eax, %esi	98	movl %eax, %esi
99	movl MEMCPY_DST(%esp), %eax /* MEMCPY_DST(%esp), success */	99	movl MEMCPY_DST(%esp), %eax /* MEMCPY_DST(%esp), success */
100	ret	100	ret
101		101
102	/*	102	/*
103	* We got here from as_page_fault() after the memory operations	103	* We got here from as_page_fault() after the memory operations
104	* above had caused a page fault.	104	* above had caused a page fault.
105	*/	105	*/
106	memcpy_from_uspace_failover_address:	106	memcpy_from_uspace_failover_address:
107	memcpy_to_uspace_failover_address:	107	memcpy_to_uspace_failover_address:
108	movl %edx, %edi	108	movl %edx, %edi
109	movl %eax, %esi	109	movl %eax, %esi
110	xorl %eax, %eax /* return 0, failure */	110	xorl %eax, %eax /* return 0, failure */
111	ret	111	ret
112		112
113	## Turn paging on	113	## Turn paging on
114	#	114	#
115	# Enable paging and write-back caching in CR0.	115	# Enable paging and write-back caching in CR0.
116	#	116	#
117	paging_on:	117	paging_on:
118	movl %cr0, %edx	118	movl %cr0, %edx
119	orl $(1 << 31), %edx # paging on	119	orl $(1 << 31), %edx # paging on
120	# clear Cache Disable and not Write Though	120	# clear Cache Disable and not Write Though
121	andl $~((1 << 30) \| (1 << 29)), %edx	121	andl $~((1 << 30) \| (1 << 29)), %edx
122	movl %edx,%cr0	122	movl %edx,%cr0
123	jmp 0f	123	jmp 0f
124	0:	124	0:
125	ret	125	ret
126		126
127		127
128	## Enable local APIC	128	## Enable local APIC
129	#	129	#
130	# Enable local APIC in MSR.	130	# Enable local APIC in MSR.
131	#	131	#
132	enable_l_apic_in_msr:	132	enable_l_apic_in_msr:
133	movl $0x1b, %ecx	133	movl $0x1b, %ecx
134	rdmsr	134	rdmsr
135	orl $(1 << 11), %eax	135	orl $(1 << 11), %eax
136	orl $(0xfee00000), %eax	136	orl $(0xfee00000), %eax
137	wrmsr	137	wrmsr
138	ret	138	ret
139		139
140	# Clear nested flag	140	# Clear nested flag
141	# overwrites %ecx	141	# overwrites %ecx
142	.macro CLEAR_NT_FLAG	142	.macro CLEAR_NT_FLAG
143	pushfl	143	pushfl
144	pop %ecx	144	pop %ecx
145	and $0xffffbfff, %ecx	145	and $0xffffbfff, %ecx
146	push %ecx	146	push %ecx
147	popfl	147	popfl
148	.endm	148	.endm
149		149
-		150	/*
-		151	* The SYSENTER syscall mechanism can be used for syscalls with
-		152	* four or fewer arguments. To pass these four arguments, we
-		153	* use four registers: EDX, ECX, EBX, ESI. The syscall number
-		154	* is passed in EAX. We use EDI to remember the return address
-		155	* and EBP to remember the stack. The INT-based syscall mechanism
-		156	* can actually handle six arguments plus the syscall number
-		157	* entirely in registers.
-		158	*/
-		159	.global sysenter_handler
-		160	sysenter_handler:
-		161	pushl %ebp # remember user stack
-		162	pushl %edi # remember return user address
-		163
-		164	pushl %gs # remember TLS
-		165
-		166	pushl %eax # syscall number
-		167	subl $8, %esp # unused sixth and fifth argument
-		168	pushl %esi # fourth argument
-		169	pushl %ebx # third argument
-		170	pushl %ecx # second argument
-		171	pushl %edx # first argument
-		172
-		173	movw $16, %ax
-		174	movw %ax, %ds
-		175	movw %ax, %es
-		176
-		177	cld
-		178	call syscall_handler
-		179	addl $28, %esp # remove arguments from stack
-		180
-		181	pop %gs # restore TLS
-		182
-		183	pop %edx # prepare return EIP for SYSEXIT
-		184	pop %ecx # prepare userspace ESP for SYSEXIT
-		185
-		186	sysexit # return to userspace
-		187
-		188
150	## Declare interrupt handlers	189	## Declare interrupt handlers
151	#	190	#
152	# Declare interrupt handlers for n interrupt	191	# Declare interrupt handlers for n interrupt
153	# vectors starting at vector i.	192	# vectors starting at vector i.
154	#	193	#
155	# The handlers setup data segment registers	194	# The handlers setup data segment registers
156	# and call exc_dispatch().	195	# and call exc_dispatch().
157	#	196	#
158	#define INTERRUPT_ALIGN 64	197	#define INTERRUPT_ALIGN 64
159	.macro handler i n	198	.macro handler i n
160		199
161	.ifeq \i - 0x30 # Syscall handler	200	.ifeq \i - 0x30 # Syscall handler
162	pushl %ds	201	pushl %ds
163	pushl %es	202	pushl %es
164	pushl %fs	203	pushl %fs
165	pushl %gs	204	pushl %gs
166		205
167	#	206	#
168	# Push syscall arguments onto the stack	207	# Push syscall arguments onto the stack
169	#	208	#
170	# NOTE: The idea behind the order of arguments passed in registers is to	209	# NOTE: The idea behind the order of arguments passed in registers is to
171	# use all scratch registers first and preserved registers next.	210	# use all scratch registers first and preserved registers next.
172	# An optimized libc syscall wrapper can make use of this setup.	211	# An optimized libc syscall wrapper can make use of this setup.
173	#	212	#
174	pushl %eax	213	pushl %eax
175	pushl %ebp	214	pushl %ebp
176	pushl %edi	215	pushl %edi
177	pushl %esi	216	pushl %esi
178	pushl %ebx	217	pushl %ebx
179	pushl %ecx	218	pushl %ecx
180	pushl %edx	219	pushl %edx
181		220
182	# we must fill the data segment registers	221	# we must fill the data segment registers
183	movw $16, %ax	222	movw $16, %ax
184	movw %ax, %ds	223	movw %ax, %ds
185	movw %ax, %es	224	movw %ax, %es
186		225
187	cld	226	cld
188	sti	227	sti
189	# syscall_handler(edx, ecx, ebx, esi, edi, ebp, eax)	228	# syscall_handler(edx, ecx, ebx, esi, edi, ebp, eax)
190	call syscall_handler	229	call syscall_handler
191	cli	230	cli
192	addl $28, %esp # clean-up of parameters	231	addl $28, %esp # clean-up of parameters
193		232
194	popl %gs	233	popl %gs
195	popl %fs	234	popl %fs
196	popl %es	235	popl %es
197	popl %ds	236	popl %ds
198		237
199	CLEAR_NT_FLAG	238	CLEAR_NT_FLAG
200	iret	239	iret
201	.else	240	.else
202	/*	241	/*
203	* This macro distinguishes between two versions of ia32 exceptions.	242	* This macro distinguishes between two versions of ia32 exceptions.
204	* One version has error word and the other does not have it.	243	* One version has error word and the other does not have it.
205	* The latter version fakes the error word on the stack so that the	244	* The latter version fakes the error word on the stack so that the
206	* handlers and istate_t can be the same for both types.	245	* handlers and istate_t can be the same for both types.
207	*/	246	*/
208	.iflt \i - 32	247	.iflt \i - 32
209	.if (1 << \i) & ERROR_WORD_INTERRUPT_LIST	248	.if (1 << \i) & ERROR_WORD_INTERRUPT_LIST
210	/*	249	/*
211	* With error word, do nothing	250	* With error word, do nothing
212	*/	251	*/
213	.else	252	.else
214	/*	253	/*
215	* Version without error word,	254	* Version without error word,
216	*/	255	*/
217	subl $4, %esp	256	subl $4, %esp
218	.endif	257	.endif
219	.else	258	.else
220	/*	259	/*
221	* Version without error word,	260	* Version without error word,
222	*/	261	*/
223	subl $4, %esp	262	subl $4, %esp
224	.endif	263	.endif
225		264
226	pushl %ds	265	pushl %ds
227	pushl %es	266	pushl %es
228	pushl %fs	267	pushl %fs
229	pushl %gs	268	pushl %gs
230		269
231	#ifdef CONFIG_DEBUG_ALLREGS	270	#ifdef CONFIG_DEBUG_ALLREGS
232	pushl %ebx	271	pushl %ebx
233	pushl %ebp	272	pushl %ebp
234	pushl %edi	273	pushl %edi
235	pushl %esi	274	pushl %esi
236	#else	275	#else
237	subl $16, %esp	276	subl $16, %esp
238	#endif	277	#endif
239	pushl %edx	278	pushl %edx
240	pushl %ecx	279	pushl %ecx
241	pushl %eax	280	pushl %eax
242		281
243	# we must fill the data segment registers	282	# we must fill the data segment registers
244	movw $16, %ax	283	movw $16, %ax
245	movw %ax, %ds	284	movw %ax, %ds
246	movw %ax, %es	285	movw %ax, %es
247		286
248	cld	287	cld
249		288
250	pushl %esp # *istate	289	pushl %esp # *istate
251	pushl $(\i) # intnum	290	pushl $(\i) # intnum
252	call exc_dispatch # excdispatch(intnum, *istate)	291	call exc_dispatch # excdispatch(intnum, *istate)
253	addl $8, %esp # Clear arguments from stack	292	addl $8, %esp # Clear arguments from stack
254		293
255	CLEAR_NT_FLAG # Modifies %ecx	294	CLEAR_NT_FLAG # Modifies %ecx
256		295
257	popl %eax	296	popl %eax
258	popl %ecx	297	popl %ecx
259	popl %edx	298	popl %edx
260	#ifdef CONFIG_DEBUG_ALLREGS	299	#ifdef CONFIG_DEBUG_ALLREGS
261	popl %esi	300	popl %esi
262	popl %edi	301	popl %edi
263	popl %ebp	302	popl %ebp
264	popl %ebx	303	popl %ebx
265	#else	304	#else
266	addl $16, %esp	305	addl $16, %esp
267	#endif	306	#endif
268		307
269	popl %gs	308	popl %gs
270	popl %fs	309	popl %fs
271	popl %es	310	popl %es
272	popl %ds	311	popl %ds
273		312
274	addl $4, %esp # Skip error word, no matter whether real or fake.	313	addl $4, %esp # Skip error word, no matter whether real or fake.
275	iret	314	iret
276	.endif	315	.endif
277		316
278	.align INTERRUPT_ALIGN	317	.align INTERRUPT_ALIGN
279	.if (\n- \i) - 1	318	.if (\n- \i) - 1
280	handler "(\i + 1)", \n	319	handler "(\i + 1)", \n
281	.endif	320	.endif
282	.endm	321	.endm
283		322
284	# keep in sync with pm.h !!!	323	# keep in sync with pm.h !!!
285	IDT_ITEMS = 64	324	IDT_ITEMS = 64
286	.align INTERRUPT_ALIGN	325	.align INTERRUPT_ALIGN
287	interrupt_handlers:	326	interrupt_handlers:
288	h_start:	327	h_start:
289	handler 0 IDT_ITEMS	328	handler 0 IDT_ITEMS
290	h_end:	329	h_end:
291		330
292	.data	331	.data
293	.global interrupt_handler_size	332	.global interrupt_handler_size
294		333
295	interrupt_handler_size: .long (h_end - h_start) / IDT_ITEMS	334	interrupt_handler_size: .long (h_end - h_start) / IDT_ITEMS
296		335

Subversion Repositories HelenOS

(root)/trunk/kernel/arch/ia32/src/asm.S – Rev 3274 → 3485