WebSVN – HelenOS – Diff – /trunk/kernel/arch/amd64/src/boot/boot.S


 
# Copyright (c) 2005 Ondrej Palkovsky
# Copyright (c) 2006 Martin Decky
# Copyright (c) 2008 Jakub Jermar
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
#
# - Redistributions of source code must retain the above copyright
#   notice, this list of conditions and the following disclaimer.
# - Redistributions in binary form must reproduce the above copyright
#   notice, this list of conditions and the following disclaimer in the
#   documentation and/or other materials provided with the distribution.
# - The name of the author may not be used to endorse or promote products
#   derived from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
#
 
#include <arch/boot/boot.h>
#include <arch/boot/memmap.h>
#include <arch/mm/page.h>	
#include <arch/mm/ptl.h>
#include <arch/pm.h>
#include <arch/cpu.h>
#include <arch/cpuid.h>
 
#define START_STACK	(BOOT_OFFSET - BOOT_STACK_SIZE)
	
.section K_TEXT_START, "ax"
 
.code32
.align 4
.global multiboot_image_start
multiboot_header:
	.long MULTIBOOT_HEADER_MAGIC
	.long MULTIBOOT_HEADER_FLAGS
	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS)	# checksum
	.long multiboot_header
	.long unmapped_ktext_start
	.long 0
	.long 0
	.long multiboot_image_start
 
multiboot_image_start:
	movl $START_STACK, %esp			# initialize stack pointer
	lgdtl bootstrap_gdtr			# initialize Global Descriptor Table register
 
	movw $gdtselector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %ds							# kernel data + stack
	movw %cx, %ss
	# Simics seems to remove hidden part of GS on entering user mode
	#  when _visible_ part of GS does not point to user-mode segment
	movw $gdtselector(UDATA_DES), %cx
	movw %cx, %fs
	movw %cx, %gs
	
	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point
	multiboot_meeting_point:
	
	movl %eax, grub_eax						# save parameters from GRUB
	movl %ebx, grub_ebx
	
	# Protected 32-bit. We want to reuse the code-seg descriptor,
	# the Default operand size must not be 1 when entering long mode
	
	movl $(INTEL_CPUID_EXTENDED), %eax  
 	cpuid
 	cmp $(INTEL_CPUID_EXTENDED), %eax
	ja extended_cpuid_supported
		
		movl $extended_cpuid_msg, %esi
		jmp error_halt
	
	extended_cpuid_supported:
	
	movl $(AMD_CPUID_EXTENDED), %eax
	cpuid
	bt $(AMD_EXT_LONG_MODE), %edx
 	jc long_mode_supported
		
		movl $long_mode_msg, %esi
		jmp error_halt
 
	long_mode_supported:
	
	bt $(AMD_EXT_NOEXECUTE), %edx
	jc noexecute_supported
	
		movl $noexecute_msg, %esi
		jmp error_halt
	
	noexecute_supported:
	
	movl $(INTEL_CPUID_STANDARD), %eax
	cpuid
	bt $(INTEL_FXSAVE), %edx
 	jc fx_supported
	
		movl $fx_msg, %esi
		jmp error_halt
	
	fx_supported:
	
	bt $(INTEL_SSE2), %edx
 	jc sse2_supported
	
		movl $sse2_msg, %esi
		jmp error_halt
	
	sse2_supported:
	
#ifdef CONFIG_FB
	mov $vesa_init, %esi
	mov $VESA_INIT_SEGMENT << 4, %edi
	mov $e_vesa_init - vesa_init, %ecx
	cld
	rep movsb
 
	mov $VESA_INIT_SEGMENT << 4, %edi
	jmpl *%edi
	
	vesa_meeting_point:
	
	mov %esi, KA2PA(vesa_ph_addr)
	mov %di, KA2PA(vesa_height)
	shr $16, %edi
	mov %di, KA2PA(vesa_width)
	mov %bx, KA2PA(vesa_scanline)
	shr $16, %ebx
	mov %bx, KA2PA(vesa_bpp)
#endif	
	
	# Enable 64-bit page translation entries - CR4.PAE = 1.
	# Paging is not enabled until after long mode is enabled
	
	movl %cr4, %eax
	btsl $5, %eax
	movl %eax, %cr4
 
	# Set up paging tables
	
	leal ptl_0, %eax
	movl %eax, %cr3
	
	# Enable long mode
	
	movl $EFER_MSR_NUM, %ecx			# EFER MSR number
	rdmsr						# Read EFER
	btsl $AMD_LME_FLAG, %eax			# Set LME = 1
	wrmsr						# Write EFER
	
	# Enable paging to activate long mode (set CR0.PG = 1)
	
	movl %cr0, %eax
	btsl $31, %eax
	movl %eax, %cr0
	
	# At this point we are in compatibility mode
	
	jmpl $gdtselector(KTEXT_DES), $start64
 
.code64
start64:
	movq $(PA2KA(START_STACK)), %rsp
	movl grub_eax, %eax
	movl grub_ebx, %ebx
	
	cmpl $MULTIBOOT_LOADER_MAGIC, %eax			# compare GRUB signature
	je valid_boot
		
		xorl %ecx, %ecx					# no memory size or map available
 
		movl %ecx, e820counter
		
		jmp invalid_boot
		
	valid_boot:
		
		movl (%ebx), %eax				# ebx = physical address of struct multiboot_info
		
 
 
 
 
 
 
 
 
 
 
 
 
 
		bt $3, %eax					# mbi->flags[3] (mods_count, mods_addr valid)
		jc mods_valid
			
			xorq %rcx, %rcx
			movq %rcx, init
			jmp mods_end
		
		mods_valid:
		
		xorq %rcx, %rcx
		movl 20(%ebx), %ecx				# mbi->mods_count
		movq %rcx, init
		
		cmpl $0, %ecx
		je mods_end
		
		movl 24(%ebx), %esi				# mbi->mods_addr
		movq $init, %rdi
		
		mods_loop:
			
			xorq %rdx, %rdx
			movl 0(%esi), %edx			# mods->mod_start
			movq $0xffff800000000000, %r10
			addq %r10, %rdx
			movq %rdx, 8(%rdi)
			
			xorq %rdx, %rdx
			movl 4(%esi), %edx
			subl 0(%esi), %edx			# mods->mod_end - mods->mod_start
			movq %rdx, 16(%rdi)
			
			addl $16, %esi
			addq $16, %rdi
			
			loop mods_loop
			
		mods_end:
		
		bt $6, %eax					# mbi->flags[6] (mmap_length, mmap_addr valid)	
		jc mmap_valid
			
			xorl %edx, %edx
			jmp mmap_invalid
			
		mmap_valid:
		movl 44(%ebx), %ecx				# mbi->mmap_length
		movl 48(%ebx), %esi				# mbi->mmap_addr
		movq $e820table, %rdi
		xorl %edx, %edx
		
		mmap_loop:
			cmpl $0, %ecx
			jle mmap_end
			
			movl 4(%esi), %eax			# mmap->base_addr_low
			movl %eax, (%rdi)
			
			movl 8(%esi), %eax			# mmap->base_addr_high
			movl %eax, 4(%rdi)
			
			movl 12(%esi), %eax			# mmap->length_low
			movl %eax, 8(%rdi)
			
			movl 16(%esi), %eax			# mmap->length_high
			movl %eax, 12(%rdi)
			
			movl 20(%esi), %eax			# mmap->type
			movl %eax, 16(%rdi)
			
			movl (%esi), %eax			# mmap->size
			addl $0x4, %eax
			addl %eax, %esi
			subl %eax, %ecx
			addq $MEMMAP_E820_RECORD_SIZE, %rdi
			incl %edx
			jmp mmap_loop
		
		mmap_end:
		
		mmap_invalid:
		movl %edx, e820counter
		
	invalid_boot:
	
#ifdef CONFIG_SMP
	
	# copy AP bootstrap routines below 1 MB
	
	movq $BOOT_OFFSET, %rsi
	movq $AP_BOOT_OFFSET, %rdi
	movq $_hardcoded_unmapped_size, %rcx
	cld
	rep movsb
	
#endif
	
	call main_bsp   # never returns
	
	cli
	hlt
 
#ifdef CONFIG_FB
.code32
vesa_init:
	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init
	
.code16
vesa_init_real:
	
	mov %cr0, %eax
	and $~1, %eax
	mov %eax, %cr0
	
	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
	
vesa_init_real2:
	
	mov $VESA_INIT_SEGMENT, %bx
	
	mov %bx, %es
	mov %bx, %fs
	mov %bx, %gs
	mov %bx, %ds
	mov %bx, %ss
	
	movl $0x0000fffc, %esp
	movl $0x0000fffc, %ebp
	
#define VESA_INFO_SIZE 1024
 
#define VESA_MODE_ATTRIBUTES_OFFSET 0
#define VESA_MODE_LIST_PTR_OFFSET 14
#define VESA_MODE_SCANLINE_OFFSET 16
#define VESA_MODE_WIDTH_OFFSET 18
#define VESA_MODE_HEIGHT_OFFSET 20
#define VESA_MODE_BPP_OFFSET 25
#define VESA_MODE_PHADDR_OFFSET 40
 
#define VESA_END_OF_MODES 0xffff
 
#define VESA_OK 0x4f
 
#define VESA_GET_INFO 0x4f00
#define VESA_GET_MODE_INFO 0x4f01
#define VESA_SET_MODE 0x4f02
#define VESA_SET_PALETTE 0x4f09
 
#define CONFIG_VESA_BPP_a 255
 
#if CONFIG_VESA_BPP == 24
#define CONFIG_VESA_BPP_VARIANT 32
#endif
 
	mov $VESA_GET_INFO, %ax
	mov $e_vesa_init - vesa_init, %di
	push %di
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
	
	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
	mov %si, %gs
	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
	
	add $VESA_INFO_SIZE, %di
 
1:# Try next mode
	mov %gs:(%si), %cx
	cmp $VESA_END_OF_MODES, %cx
	jz 0f
	
	inc %si
	inc %si
	push %cx
	push %di
	push %si
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %si
	pop %di
	pop %cx
	cmp $VESA_OK, %al
	jnz 0f
	
	mov $CONFIG_VESA_WIDTH, %ax
	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_HEIGHT, %ax
	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_BPP, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
 
#ifdef CONFIG_VESA_BPP_VARIANT
	jz 2f
	
	mov $CONFIG_VESA_BPP_VARIANT, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
#endif
	jnz 1b
	
2:
	
	mov %cx, %bx
	or $0xc000, %bx
	push %di
	mov $VESA_SET_MODE, %ax
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
 
#if CONFIG_VESA_BPP == 8
	
	# Set 3:2:3 VGA palette
	
	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax
	push %di
	mov $vga323 - vesa_init, %di
	mov $0x100, %ecx
	
	bt $5, %ax						# Test if VGA compatible registers are present
	jnc vga_compat
		
		# Try VESA routine to set palette
		
		mov $VESA_SET_PALETTE, %ax
		xor %bl, %bl
		xor %dx, %dx
		int $0x10
		
		jmp vga_not_compat
	
	vga_compat:
		
		# Try VGA registers to set palette
		
		movw $0x3c6, %dx				# Set palette mask
		movb $0xff, %al
		outb %al, %dx
		
		movw $0x3c8, %dx				# First index to set
		xor %al, %al
		outb %al, %dx
		
		movw $0x3c9, %dx				# Data port
		vga_loop:
			movb %es:2(%di), %al
			outb %al, %dx
			
			movb %es:1(%di), %al
			outb %al, %dx
			
			movb %es:(%di), %al
			outb %al, %dx
			
			addw $4, %di
			loop vga_loop
		
	vga_not_compat:
	
	pop %di
	
#endif
	
	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
	shl $16, %eax
	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
	mov VESA_MODE_BPP_OFFSET(%di), %bl
	xor %bh, %bh
	shl $16, %ebx
	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
	mov %eax, %edi
	
8:
	
	mov %cr0, %eax
	or $1, %eax
	mov %eax, %cr0
	
	jmp 9f
9:
	
	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
	
0:# No prefered mode found
	mov $0x111, %cx
	push %di
	push %cx
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %cx
	pop %di
	cmp $VESA_OK, %al
	jnz 1f
	jz 2b						# Force relative jump
 
1:
	mov $0x0003, %ax
	int $0x10
	mov $0xffffffff, %edi				# EGA text mode used, because of problems with VESA
	xor %ax, %ax
	jz 8b						# Force relative jump
 
vga323:
#include "vga323.pal"	
	
.code32
vesa_init_protect:
	movw $gdtselector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %ds					# kernel data + stack
	movw %cx, %ss
	# Simics seems to remove hidden part of GS on entering user mode
	#  when _visible_ part of GS does not point to user-mode segment
	movw $gdtselector(UDATA_DES), %cx
	movw %cx, %fs
	movw %cx, %gs
	
	movl $START_STACK, %esp				# initialize stack pointer
	
	jmpl $gdtselector(KTEXT32_DES), $vesa_meeting_point
	
.align 4
e_vesa_init:
#endif
 
# Print string from %esi to EGA display (in red) and halt
error_halt:
	movl $0xb8000, %edi				# base of EGA text mode memory
	xorl %eax, %eax
	
	movw $0x3d4, %dx				# read bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	shl $8, %ax
	
	movw $0x3d4, %dx				# read bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	
	cmp $1920, %ax
	jbe cursor_ok
		movw $1920, %ax				# sanity check for the cursor on the last line
	cursor_ok:
	
	movw %ax, %bx
	shl $1, %eax
	addl %eax, %edi
	
	movw $0x0c00, %ax				# black background, light red foreground
	cld
	
	ploop:
		lodsb
		cmp $0, %al
		je ploop_end
		stosw
		inc %bx	
		jmp ploop
	ploop_end:
	
	movw $0x3d4, %dx				# write bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bh, %al
	outb %al, %dx
	
	movw $0x3d4, %dx				# write bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bl, %al
	outb %al, %dx
		
	cli
	hlt
				
 
.section K_INI_PTLS, "aw", @progbits
 
#
# Macro for generating initial page table contents.
# @param cnt	Number of entries to generat. Must be multiple of 8.
# @param g	Number of GB that will be added to the mapping.
#
.macro ptl2gen cnt g 
.if \cnt
	ptl2gen "\cnt - 8" \g 
	.quad ((\cnt - 8) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 7) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 6) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 5) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 4) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 3) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 2) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 1) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
.endif
.endm
 
# Page table for pages in the first gigabyte.
.align 4096
.global ptl_2_0g
ptl_2_0g:	
	ptl2gen 512 0
 
# Page table for pages in the second gigabyte.
.align 4096
.global ptl_2_1g
ptl_2_1g:
	ptl2gen 512 1
 
# Page table for pages in the third gigabyte.
.align 4096
.global ptl_2_2g
ptl_2_2g:
	ptl2gen 512 2
 
# Page table for pages in the fourth gigabyte.
.align 4096
.global ptl_2_3g
ptl_2_3g:
	ptl2gen 512 3
 
.align 4096
.global ptl_1
ptl_1:
	# Identity mapping for [0; 4G)
	.quad ptl_2_0g + (PTL_WRITABLE | PTL_PRESENT)
	.quad ptl_2_1g + (PTL_WRITABLE | PTL_PRESENT) 
	.quad ptl_2_2g + (PTL_WRITABLE | PTL_PRESENT)
	.quad ptl_2_3g + (PTL_WRITABLE | PTL_PRESENT)
	.fill 506, 8, 0
	# Mapping of [0; 1G) at -2G
	.quad ptl_2_0g + (PTL_WRITABLE | PTL_PRESENT)
	.fill 1, 8, 0
	
.align 4096
.global ptl_0
ptl_0:
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
	.fill 255,8,0
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
	.fill 254,8,0
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
 
.section K_DATA_START, "aw", @progbits
 
.global bootstrap_gdtr
bootstrap_gdtr:
	.word gdtselector(GDT_ITEMS)
	.long KA2PA(gdt)
 
grub_eax:
	.long 0
 
grub_ebx:
	.long 0
 
extended_cpuid_msg:
	.asciz "Extended CPUID not supported. System halted."
long_mode_msg:
	.asciz "64 bit long mode not supported. System halted."
noexecute_msg:
	.asciz "No-execute pages not supported. System halted."
fx_msg:
	.asciz "FXSAVE/FXRESTORE instructions not supported. System halted."
sse2_msg:
	.asciz "SSE2 instructions not supported. System halted."
 

Rev 2713	Rev 2725
1		1
2	# Copyright (c) 2005 Ondrej Palkovsky	2	# Copyright (c) 2005 Ondrej Palkovsky
3	# Copyright (c) 2006 Martin Decky	3	# Copyright (c) 2006 Martin Decky
4	# Copyright (c) 2008 Jakub Jermar	4	# Copyright (c) 2008 Jakub Jermar
5	# All rights reserved.	5	# All rights reserved.
6	#	6	#
7	# Redistribution and use in source and binary forms, with or without	7	# Redistribution and use in source and binary forms, with or without
8	# modification, are permitted provided that the following conditions	8	# modification, are permitted provided that the following conditions
9	# are met:	9	# are met:
10	#	10	#
11	# - Redistributions of source code must retain the above copyright	11	# - Redistributions of source code must retain the above copyright
12	# notice, this list of conditions and the following disclaimer.	12	# notice, this list of conditions and the following disclaimer.
13	# - Redistributions in binary form must reproduce the above copyright	13	# - Redistributions in binary form must reproduce the above copyright
14	# notice, this list of conditions and the following disclaimer in the	14	# notice, this list of conditions and the following disclaimer in the
15	# documentation and/or other materials provided with the distribution.	15	# documentation and/or other materials provided with the distribution.
16	# - The name of the author may not be used to endorse or promote products	16	# - The name of the author may not be used to endorse or promote products
17	# derived from this software without specific prior written permission.	17	# derived from this software without specific prior written permission.
18	#	18	#
19	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR	19	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
20	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES	20	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
21	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.	21	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
22	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,	22	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
23	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT	23	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
24	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,	24	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
25	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY	25	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
26	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT	26	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF	27	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.	28	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29	#	29	#
30		30
31	#include <arch/boot/boot.h>	31	#include <arch/boot/boot.h>
32	#include <arch/boot/memmap.h>	32	#include <arch/boot/memmap.h>
33	#include <arch/mm/page.h>	33	#include <arch/mm/page.h>
34	#include <arch/mm/ptl.h>	34	#include <arch/mm/ptl.h>
35	#include <arch/pm.h>	35	#include <arch/pm.h>
36	#include <arch/cpu.h>	36	#include <arch/cpu.h>
37	#include <arch/cpuid.h>	37	#include <arch/cpuid.h>
38		38
39	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)	39	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
40		40
41	.section K_TEXT_START, "ax"	41	.section K_TEXT_START, "ax"
42		42
43	.code32	43	.code32
44	.align 4	44	.align 4
45	.global multiboot_image_start	45	.global multiboot_image_start
46	multiboot_header:	46	multiboot_header:
47	.long MULTIBOOT_HEADER_MAGIC	47	.long MULTIBOOT_HEADER_MAGIC
48	.long MULTIBOOT_HEADER_FLAGS	48	.long MULTIBOOT_HEADER_FLAGS
49	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum	49	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum
50	.long multiboot_header	50	.long multiboot_header
51	.long unmapped_ktext_start	51	.long unmapped_ktext_start
52	.long 0	52	.long 0
53	.long 0	53	.long 0
54	.long multiboot_image_start	54	.long multiboot_image_start
55		55
56	multiboot_image_start:	56	multiboot_image_start:
57	movl $START_STACK, %esp # initialize stack pointer	57	movl $START_STACK, %esp # initialize stack pointer
58	lgdtl bootstrap_gdtr # initialize Global Descriptor Table register	58	lgdtl bootstrap_gdtr # initialize Global Descriptor Table register
59		59
60	movw $gdtselector(KDATA_DES), %cx	60	movw $gdtselector(KDATA_DES), %cx
61	movw %cx, %es	61	movw %cx, %es
62	movw %cx, %ds # kernel data + stack	62	movw %cx, %ds # kernel data + stack
63	movw %cx, %ss	63	movw %cx, %ss
64	# Simics seems to remove hidden part of GS on entering user mode	64	# Simics seems to remove hidden part of GS on entering user mode
65	# when _visible_ part of GS does not point to user-mode segment	65	# when _visible_ part of GS does not point to user-mode segment
66	movw $gdtselector(UDATA_DES), %cx	66	movw $gdtselector(UDATA_DES), %cx
67	movw %cx, %fs	67	movw %cx, %fs
68	movw %cx, %gs	68	movw %cx, %gs
69		69
70	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point	70	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point
71	multiboot_meeting_point:	71	multiboot_meeting_point:
72		72
73	movl %eax, grub_eax # save parameters from GRUB	73	movl %eax, grub_eax # save parameters from GRUB
74	movl %ebx, grub_ebx	74	movl %ebx, grub_ebx
75		75
76	# Protected 32-bit. We want to reuse the code-seg descriptor,	76	# Protected 32-bit. We want to reuse the code-seg descriptor,
77	# the Default operand size must not be 1 when entering long mode	77	# the Default operand size must not be 1 when entering long mode
78		78
79	movl $(INTEL_CPUID_EXTENDED), %eax	79	movl $(INTEL_CPUID_EXTENDED), %eax
80	cpuid	80	cpuid
81	cmp $(INTEL_CPUID_EXTENDED), %eax	81	cmp $(INTEL_CPUID_EXTENDED), %eax
82	ja extended_cpuid_supported	82	ja extended_cpuid_supported
83		83
84	movl $extended_cpuid_msg, %esi	84	movl $extended_cpuid_msg, %esi
85	jmp error_halt	85	jmp error_halt
86		86
87	extended_cpuid_supported:	87	extended_cpuid_supported:
88		88
89	movl $(AMD_CPUID_EXTENDED), %eax	89	movl $(AMD_CPUID_EXTENDED), %eax
90	cpuid	90	cpuid
91	bt $(AMD_EXT_LONG_MODE), %edx	91	bt $(AMD_EXT_LONG_MODE), %edx
92	jc long_mode_supported	92	jc long_mode_supported
93		93
94	movl $long_mode_msg, %esi	94	movl $long_mode_msg, %esi
95	jmp error_halt	95	jmp error_halt
96		96
97	long_mode_supported:	97	long_mode_supported:
98		98
99	bt $(AMD_EXT_NOEXECUTE), %edx	99	bt $(AMD_EXT_NOEXECUTE), %edx
100	jc noexecute_supported	100	jc noexecute_supported
101		101
102	movl $noexecute_msg, %esi	102	movl $noexecute_msg, %esi
103	jmp error_halt	103	jmp error_halt
104		104
105	noexecute_supported:	105	noexecute_supported:
106		106
107	movl $(INTEL_CPUID_STANDARD), %eax	107	movl $(INTEL_CPUID_STANDARD), %eax
108	cpuid	108	cpuid
109	bt $(INTEL_FXSAVE), %edx	109	bt $(INTEL_FXSAVE), %edx
110	jc fx_supported	110	jc fx_supported
111		111
112	movl $fx_msg, %esi	112	movl $fx_msg, %esi
113	jmp error_halt	113	jmp error_halt
114		114
115	fx_supported:	115	fx_supported:
116		116
117	bt $(INTEL_SSE2), %edx	117	bt $(INTEL_SSE2), %edx
118	jc sse2_supported	118	jc sse2_supported
119		119
120	movl $sse2_msg, %esi	120	movl $sse2_msg, %esi
121	jmp error_halt	121	jmp error_halt
122		122
123	sse2_supported:	123	sse2_supported:
124		124
125	#ifdef CONFIG_FB	125	#ifdef CONFIG_FB
126	mov $vesa_init, %esi	126	mov $vesa_init, %esi
127	mov $VESA_INIT_SEGMENT << 4, %edi	127	mov $VESA_INIT_SEGMENT << 4, %edi
128	mov $e_vesa_init - vesa_init, %ecx	128	mov $e_vesa_init - vesa_init, %ecx
129	cld	129	cld
130	rep movsb	130	rep movsb
131		131
132	mov $VESA_INIT_SEGMENT << 4, %edi	132	mov $VESA_INIT_SEGMENT << 4, %edi
133	jmpl *%edi	133	jmpl *%edi
134		134
135	vesa_meeting_point:	135	vesa_meeting_point:
136		136
137	mov %esi, KA2PA(vesa_ph_addr)	137	mov %esi, KA2PA(vesa_ph_addr)
138	mov %di, KA2PA(vesa_height)	138	mov %di, KA2PA(vesa_height)
139	shr $16, %edi	139	shr $16, %edi
140	mov %di, KA2PA(vesa_width)	140	mov %di, KA2PA(vesa_width)
141	mov %bx, KA2PA(vesa_scanline)	141	mov %bx, KA2PA(vesa_scanline)
142	shr $16, %ebx	142	shr $16, %ebx
143	mov %bx, KA2PA(vesa_bpp)	143	mov %bx, KA2PA(vesa_bpp)
144	#endif	144	#endif
145		145
146	# Enable 64-bit page translation entries - CR4.PAE = 1.	146	# Enable 64-bit page translation entries - CR4.PAE = 1.
147	# Paging is not enabled until after long mode is enabled	147	# Paging is not enabled until after long mode is enabled
148		148
149	movl %cr4, %eax	149	movl %cr4, %eax
150	btsl $5, %eax	150	btsl $5, %eax
151	movl %eax, %cr4	151	movl %eax, %cr4
152		152
153	# Set up paging tables	153	# Set up paging tables
154		154
155	leal ptl_0, %eax	155	leal ptl_0, %eax
156	movl %eax, %cr3	156	movl %eax, %cr3
157		157
158	# Enable long mode	158	# Enable long mode
159		159
160	movl $EFER_MSR_NUM, %ecx # EFER MSR number	160	movl $EFER_MSR_NUM, %ecx # EFER MSR number
161	rdmsr # Read EFER	161	rdmsr # Read EFER
162	btsl $AMD_LME_FLAG, %eax # Set LME = 1	162	btsl $AMD_LME_FLAG, %eax # Set LME = 1
163	wrmsr # Write EFER	163	wrmsr # Write EFER
164		164
165	# Enable paging to activate long mode (set CR0.PG = 1)	165	# Enable paging to activate long mode (set CR0.PG = 1)
166		166
167	movl %cr0, %eax	167	movl %cr0, %eax
168	btsl $31, %eax	168	btsl $31, %eax
169	movl %eax, %cr0	169	movl %eax, %cr0
170		170
171	# At this point we are in compatibility mode	171	# At this point we are in compatibility mode
172		172
173	jmpl $gdtselector(KTEXT_DES), $start64	173	jmpl $gdtselector(KTEXT_DES), $start64
174		174
175	.code64	175	.code64
176	start64:	176	start64:
177	movq $(PA2KA(START_STACK)), %rsp	177	movq $(PA2KA(START_STACK)), %rsp
178	movl grub_eax, %eax	178	movl grub_eax, %eax
179	movl grub_ebx, %ebx	179	movl grub_ebx, %ebx
180		180
181	cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature	181	cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature
182	je valid_boot	182	je valid_boot
183		183
184	xorl %ecx, %ecx # no memory size or map available	184	xorl %ecx, %ecx # no memory size or map available
185	movl %ecx, e801memorysize	-
186	movl %ecx, e820counter	185	movl %ecx, e820counter
187		186
188	jmp invalid_boot	187	jmp invalid_boot
189		188
190	valid_boot:	189	valid_boot:
191		190
192	movl (%ebx), %eax # ebx = physical address of struct multiboot_info	191	movl (%ebx), %eax # ebx = physical address of struct multiboot_info
193		192
194	bt $0, %eax # mbi->flags[0] (mem_lower, mem_upper valid)	-
195	jc mem_valid	-
196		-
197	xorl %ecx, %ecx	-
198	jmp mem_invalid	-
199		-
200	mem_valid:	-
201	movl 4(%ebx), %ecx # mbi->mem_lower	-
202	addl 8(%ebx), %ecx # mbi->mem_upper	-
203		-
204	mem_invalid:	-
205	movl %ecx, e801memorysize	-
206		-
207	bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)	193	bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)
208	jc mods_valid	194	jc mods_valid
209		195
210	xorq %rcx, %rcx	196	xorq %rcx, %rcx
211	movq %rcx, init	197	movq %rcx, init
212	jmp mods_end	198	jmp mods_end
213		199
214	mods_valid:	200	mods_valid:
215		201
216	xorq %rcx, %rcx	202	xorq %rcx, %rcx
217	movl 20(%ebx), %ecx # mbi->mods_count	203	movl 20(%ebx), %ecx # mbi->mods_count
218	movq %rcx, init	204	movq %rcx, init
219		205
220	cmpl $0, %ecx	206	cmpl $0, %ecx
221	je mods_end	207	je mods_end
222		208
223	movl 24(%ebx), %esi # mbi->mods_addr	209	movl 24(%ebx), %esi # mbi->mods_addr
224	movq $init, %rdi	210	movq $init, %rdi
225		211
226	mods_loop:	212	mods_loop:
227		213
228	xorq %rdx, %rdx	214	xorq %rdx, %rdx
229	movl 0(%esi), %edx # mods->mod_start	215	movl 0(%esi), %edx # mods->mod_start
230	movq $0xffff800000000000, %r10	216	movq $0xffff800000000000, %r10
231	addq %r10, %rdx	217	addq %r10, %rdx
232	movq %rdx, 8(%rdi)	218	movq %rdx, 8(%rdi)
233		219
234	xorq %rdx, %rdx	220	xorq %rdx, %rdx
235	movl 4(%esi), %edx	221	movl 4(%esi), %edx
236	subl 0(%esi), %edx # mods->mod_end - mods->mod_start	222	subl 0(%esi), %edx # mods->mod_end - mods->mod_start
237	movq %rdx, 16(%rdi)	223	movq %rdx, 16(%rdi)
238		224
239	addl $16, %esi	225	addl $16, %esi
240	addq $16, %rdi	226	addq $16, %rdi
241		227
242	loop mods_loop	228	loop mods_loop
243		229
244	mods_end:	230	mods_end:
245		231
246	bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)	232	bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)
247	jc mmap_valid	233	jc mmap_valid
248		234
249	xorl %edx, %edx	235	xorl %edx, %edx
250	jmp mmap_invalid	236	jmp mmap_invalid
251		237
252	mmap_valid:	238	mmap_valid:
253	movl 44(%ebx), %ecx # mbi->mmap_length	239	movl 44(%ebx), %ecx # mbi->mmap_length
254	movl 48(%ebx), %esi # mbi->mmap_addr	240	movl 48(%ebx), %esi # mbi->mmap_addr
255	movq $e820table, %rdi	241	movq $e820table, %rdi
256	xorl %edx, %edx	242	xorl %edx, %edx
257		243
258	mmap_loop:	244	mmap_loop:
259	cmpl $0, %ecx	245	cmpl $0, %ecx
260	jle mmap_end	246	jle mmap_end
261		247
262	movl 4(%esi), %eax # mmap->base_addr_low	248	movl 4(%esi), %eax # mmap->base_addr_low
263	movl %eax, (%rdi)	249	movl %eax, (%rdi)
264		250
265	movl 8(%esi), %eax # mmap->base_addr_high	251	movl 8(%esi), %eax # mmap->base_addr_high
266	movl %eax, 4(%rdi)	252	movl %eax, 4(%rdi)
267		253
268	movl 12(%esi), %eax # mmap->length_low	254	movl 12(%esi), %eax # mmap->length_low
269	movl %eax, 8(%rdi)	255	movl %eax, 8(%rdi)
270		256
271	movl 16(%esi), %eax # mmap->length_high	257	movl 16(%esi), %eax # mmap->length_high
272	movl %eax, 12(%rdi)	258	movl %eax, 12(%rdi)
273		259
274	movl 20(%esi), %eax # mmap->type	260	movl 20(%esi), %eax # mmap->type
275	movl %eax, 16(%rdi)	261	movl %eax, 16(%rdi)
276		262
277	movl (%esi), %eax # mmap->size	263	movl (%esi), %eax # mmap->size
278	addl $0x4, %eax	264	addl $0x4, %eax
279	addl %eax, %esi	265	addl %eax, %esi
280	subl %eax, %ecx	266	subl %eax, %ecx
281	addq $MEMMAP_E820_RECORD_SIZE, %rdi	267	addq $MEMMAP_E820_RECORD_SIZE, %rdi
282	incl %edx	268	incl %edx
283	jmp mmap_loop	269	jmp mmap_loop
284		270
285	mmap_end:	271	mmap_end:
286		272
287	mmap_invalid:	273	mmap_invalid:
288	movl %edx, e820counter	274	movl %edx, e820counter
289		275
290	invalid_boot:	276	invalid_boot:
291		277
292	#ifdef CONFIG_SMP	278	#ifdef CONFIG_SMP
293		279
294	# copy AP bootstrap routines below 1 MB	280	# copy AP bootstrap routines below 1 MB
295		281
296	movq $BOOT_OFFSET, %rsi	282	movq $BOOT_OFFSET, %rsi
297	movq $AP_BOOT_OFFSET, %rdi	283	movq $AP_BOOT_OFFSET, %rdi
298	movq $_hardcoded_unmapped_size, %rcx	284	movq $_hardcoded_unmapped_size, %rcx
299	cld	285	cld
300	rep movsb	286	rep movsb
301		287
302	#endif	288	#endif
303		289
304	call main_bsp # never returns	290	call main_bsp # never returns
305		291
306	cli	292	cli
307	hlt	293	hlt
308		294
309	#ifdef CONFIG_FB	295	#ifdef CONFIG_FB
310	.code32	296	.code32
311	vesa_init:	297	vesa_init:
312	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init	298	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init
313		299
314	.code16	300	.code16
315	vesa_init_real:	301	vesa_init_real:
316		302
317	mov %cr0, %eax	303	mov %cr0, %eax
318	and $~1, %eax	304	and $~1, %eax
319	mov %eax, %cr0	305	mov %eax, %cr0
320		306
321	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init	307	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
322		308
323	vesa_init_real2:	309	vesa_init_real2:
324		310
325	mov $VESA_INIT_SEGMENT, %bx	311	mov $VESA_INIT_SEGMENT, %bx
326		312
327	mov %bx, %es	313	mov %bx, %es
328	mov %bx, %fs	314	mov %bx, %fs
329	mov %bx, %gs	315	mov %bx, %gs
330	mov %bx, %ds	316	mov %bx, %ds
331	mov %bx, %ss	317	mov %bx, %ss
332		318
333	movl $0x0000fffc, %esp	319	movl $0x0000fffc, %esp
334	movl $0x0000fffc, %ebp	320	movl $0x0000fffc, %ebp
335		321
336	#define VESA_INFO_SIZE 1024	322	#define VESA_INFO_SIZE 1024
337		323
338	#define VESA_MODE_ATTRIBUTES_OFFSET 0	324	#define VESA_MODE_ATTRIBUTES_OFFSET 0
339	#define VESA_MODE_LIST_PTR_OFFSET 14	325	#define VESA_MODE_LIST_PTR_OFFSET 14
340	#define VESA_MODE_SCANLINE_OFFSET 16	326	#define VESA_MODE_SCANLINE_OFFSET 16
341	#define VESA_MODE_WIDTH_OFFSET 18	327	#define VESA_MODE_WIDTH_OFFSET 18
342	#define VESA_MODE_HEIGHT_OFFSET 20	328	#define VESA_MODE_HEIGHT_OFFSET 20
343	#define VESA_MODE_BPP_OFFSET 25	329	#define VESA_MODE_BPP_OFFSET 25
344	#define VESA_MODE_PHADDR_OFFSET 40	330	#define VESA_MODE_PHADDR_OFFSET 40
345		331
346	#define VESA_END_OF_MODES 0xffff	332	#define VESA_END_OF_MODES 0xffff
347		333
348	#define VESA_OK 0x4f	334	#define VESA_OK 0x4f
349		335
350	#define VESA_GET_INFO 0x4f00	336	#define VESA_GET_INFO 0x4f00
351	#define VESA_GET_MODE_INFO 0x4f01	337	#define VESA_GET_MODE_INFO 0x4f01
352	#define VESA_SET_MODE 0x4f02	338	#define VESA_SET_MODE 0x4f02
353	#define VESA_SET_PALETTE 0x4f09	339	#define VESA_SET_PALETTE 0x4f09
354		340
355	#define CONFIG_VESA_BPP_a 255	341	#define CONFIG_VESA_BPP_a 255
356		342
357	#if CONFIG_VESA_BPP == 24	343	#if CONFIG_VESA_BPP == 24
358	#define CONFIG_VESA_BPP_VARIANT 32	344	#define CONFIG_VESA_BPP_VARIANT 32
359	#endif	345	#endif
360		346
361	mov $VESA_GET_INFO, %ax	347	mov $VESA_GET_INFO, %ax
362	mov $e_vesa_init - vesa_init, %di	348	mov $e_vesa_init - vesa_init, %di
363	push %di	349	push %di
364	int $0x10	350	int $0x10
365		351
366	pop %di	352	pop %di
367	cmp $VESA_OK, %al	353	cmp $VESA_OK, %al
368	jnz 0f	354	jnz 0f
369		355
370	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si	356	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
371	mov %si, %gs	357	mov %si, %gs
372	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si	358	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
373		359
374	add $VESA_INFO_SIZE, %di	360	add $VESA_INFO_SIZE, %di
375		361
376	1:# Try next mode	362	1:# Try next mode
377	mov %gs:(%si), %cx	363	mov %gs:(%si), %cx
378	cmp $VESA_END_OF_MODES, %cx	364	cmp $VESA_END_OF_MODES, %cx
379	jz 0f	365	jz 0f
380		366
381	inc %si	367	inc %si
382	inc %si	368	inc %si
383	push %cx	369	push %cx
384	push %di	370	push %di
385	push %si	371	push %si
386	mov $VESA_GET_MODE_INFO, %ax	372	mov $VESA_GET_MODE_INFO, %ax
387	int $0x10	373	int $0x10
388		374
389	pop %si	375	pop %si
390	pop %di	376	pop %di
391	pop %cx	377	pop %cx
392	cmp $VESA_OK, %al	378	cmp $VESA_OK, %al
393	jnz 0f	379	jnz 0f
394		380
395	mov $CONFIG_VESA_WIDTH, %ax	381	mov $CONFIG_VESA_WIDTH, %ax
396	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax	382	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
397	jnz 1b	383	jnz 1b
398		384
399	mov $CONFIG_VESA_HEIGHT, %ax	385	mov $CONFIG_VESA_HEIGHT, %ax
400	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax	386	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
401	jnz 1b	387	jnz 1b
402		388
403	mov $CONFIG_VESA_BPP, %al	389	mov $CONFIG_VESA_BPP, %al
404	cmp VESA_MODE_BPP_OFFSET(%di), %al	390	cmp VESA_MODE_BPP_OFFSET(%di), %al
405		391
406	#ifdef CONFIG_VESA_BPP_VARIANT	392	#ifdef CONFIG_VESA_BPP_VARIANT
407	jz 2f	393	jz 2f
408		394
409	mov $CONFIG_VESA_BPP_VARIANT, %al	395	mov $CONFIG_VESA_BPP_VARIANT, %al
410	cmp VESA_MODE_BPP_OFFSET(%di), %al	396	cmp VESA_MODE_BPP_OFFSET(%di), %al
411	#endif	397	#endif
412	jnz 1b	398	jnz 1b
413		399
414	2:	400	2:
415		401
416	mov %cx, %bx	402	mov %cx, %bx
417	or $0xc000, %bx	403	or $0xc000, %bx
418	push %di	404	push %di
419	mov $VESA_SET_MODE, %ax	405	mov $VESA_SET_MODE, %ax
420	int $0x10	406	int $0x10
421		407
422	pop %di	408	pop %di
423	cmp $VESA_OK, %al	409	cmp $VESA_OK, %al
424	jnz 0f	410	jnz 0f
425		411
426	#if CONFIG_VESA_BPP == 8	412	#if CONFIG_VESA_BPP == 8
427		413
428	# Set 3:2:3 VGA palette	414	# Set 3:2:3 VGA palette
429		415
430	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax	416	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax
431	push %di	417	push %di
432	mov $vga323 - vesa_init, %di	418	mov $vga323 - vesa_init, %di
433	mov $0x100, %ecx	419	mov $0x100, %ecx
434		420
435	bt $5, %ax # Test if VGA compatible registers are present	421	bt $5, %ax # Test if VGA compatible registers are present
436	jnc vga_compat	422	jnc vga_compat
437		423
438	# Try VESA routine to set palette	424	# Try VESA routine to set palette
439		425
440	mov $VESA_SET_PALETTE, %ax	426	mov $VESA_SET_PALETTE, %ax
441	xor %bl, %bl	427	xor %bl, %bl
442	xor %dx, %dx	428	xor %dx, %dx
443	int $0x10	429	int $0x10
444		430
445	jmp vga_not_compat	431	jmp vga_not_compat
446		432
447	vga_compat:	433	vga_compat:
448		434
449	# Try VGA registers to set palette	435	# Try VGA registers to set palette
450		436
451	movw $0x3c6, %dx # Set palette mask	437	movw $0x3c6, %dx # Set palette mask
452	movb $0xff, %al	438	movb $0xff, %al
453	outb %al, %dx	439	outb %al, %dx
454		440
455	movw $0x3c8, %dx # First index to set	441	movw $0x3c8, %dx # First index to set
456	xor %al, %al	442	xor %al, %al
457	outb %al, %dx	443	outb %al, %dx
458		444
459	movw $0x3c9, %dx # Data port	445	movw $0x3c9, %dx # Data port
460	vga_loop:	446	vga_loop:
461	movb %es:2(%di), %al	447	movb %es:2(%di), %al
462	outb %al, %dx	448	outb %al, %dx
463		449
464	movb %es:1(%di), %al	450	movb %es:1(%di), %al
465	outb %al, %dx	451	outb %al, %dx
466		452
467	movb %es:(%di), %al	453	movb %es:(%di), %al
468	outb %al, %dx	454	outb %al, %dx
469		455
470	addw $4, %di	456	addw $4, %di
471	loop vga_loop	457	loop vga_loop
472		458
473	vga_not_compat:	459	vga_not_compat:
474		460
475	pop %di	461	pop %di
476		462
477	#endif	463	#endif
478		464
479	mov VESA_MODE_PHADDR_OFFSET(%di), %esi	465	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
480	mov VESA_MODE_WIDTH_OFFSET(%di), %ax	466	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
481	shl $16, %eax	467	shl $16, %eax
482	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax	468	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
483	mov VESA_MODE_BPP_OFFSET(%di), %bl	469	mov VESA_MODE_BPP_OFFSET(%di), %bl
484	xor %bh, %bh	470	xor %bh, %bh
485	shl $16, %ebx	471	shl $16, %ebx
486	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx	472	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
487	mov %eax, %edi	473	mov %eax, %edi
488		474
489	8:	475	8:
490		476
491	mov %cr0, %eax	477	mov %cr0, %eax
492	or $1, %eax	478	or $1, %eax
493	mov %eax, %cr0	479	mov %eax, %cr0
494		480
495	jmp 9f	481	jmp 9f
496	9:	482	9:
497		483
498	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)	484	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
499		485
500	0:# No prefered mode found	486	0:# No prefered mode found

Subversion Repositories HelenOS

(root)/trunk/kernel/arch/amd64/src/boot/boot.S – Rev 2713 → 2725