WebSVN – HelenOS – Diff – /branches/dynload/kernel/arch/ia32/src/boot/boot.S


#
# Copyright (c) 2001-2004 Jakub Jermar
# Copyright (c) 2005-2006 Martin Decky
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
#
# - Redistributions of source code must retain the above copyright
#   notice, this list of conditions and the following disclaimer.
# - Redistributions in binary form must reproduce the above copyright
#   notice, this list of conditions and the following disclaimer in the
#   documentation and/or other materials provided with the distribution.
# - The name of the author may not be used to endorse or promote products
#   derived from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
#
 
#include <arch/boot/boot.h>
#include <arch/boot/memmap.h>
#include <arch/mm/page.h>
#include <arch/pm.h>
 
#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
 
.section K_TEXT_START, "ax"
 
.code32
.align 4
.global multiboot_image_start
multiboot_header:
	.long MULTIBOOT_HEADER_MAGIC
	.long MULTIBOOT_HEADER_FLAGS
	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS)	# checksum
	.long multiboot_header
	.long unmapped_ktext_start
	.long 0
	.long 0
	.long multiboot_image_start
	
multiboot_image_start:
	cld
	movl $START_STACK, %esp			# initialize stack pointer
	lgdt KA2PA(bootstrap_gdtr)		# initialize Global Descriptor Table register
 
	movw $selector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %fs
	movw %cx, %gs
	movw %cx, %ds					# kernel data + stack
	movw %cx, %ss
	
	jmpl $selector(KTEXT_DES), $multiboot_meeting_point
	multiboot_meeting_point:
	
	movl %eax, grub_eax					# save parameters from GRUB
	movl %ebx, grub_ebx
	
	xorl %eax, %eax  
 	cpuid
 	cmp $0x0, %eax						# any function > 0?
	jbe pse_unsupported
	movl $0x1, %eax						# Basic function code 1
	cpuid
	bt $3, %edx							# Test if PSE is supported
	jc pse_supported
 
	pse_unsupported:
		movl $pse_msg, %esi
		jmp error_halt
	
	pse_supported:
	
#ifdef CONFIG_FB
	mov $vesa_init, %esi
	mov $VESA_INIT_SEGMENT << 4, %edi
	mov $e_vesa_init - vesa_init, %ecx
	rep movsb
 
	mov $VESA_INIT_SEGMENT << 4, %edi
	jmpl *%edi
	
	vesa_meeting_point:
	
	mov %esi, KA2PA(vesa_ph_addr)
	mov %di, KA2PA(vesa_height)
	shr $16, %edi
	mov %di, KA2PA(vesa_width)
	mov %bx, KA2PA(vesa_scanline)
	shr $16, %ebx
	mov %bx, KA2PA(vesa_bpp)
#endif	
 
	call map_kernel							# map kernel and turn paging on
 
	# arch_pre_main(grub_eax, grub_ebx)
	pushl grub_ebx
	pushl grub_eax
	call arch_pre_main
	
	call main_bsp
	
	# Not reached.
	
	cli
	hlt
 
.global map_kernel
map_kernel:
	#
	# Here we setup mapping for both the unmapped and mapped sections of the kernel.
	# For simplicity, we map the entire 4G space.
	#
	movl %cr4, %ecx
	orl $(1 << 4), %ecx							# turn PSE on
	andl $(~(1 << 5)), %ecx						# turn PAE off
	movl %ecx, %cr4
	
	movl $(page_directory + 0), %esi
	movl $(page_directory + 2048), %edi
	xorl %ecx, %ecx
	xorl %ebx, %ebx
0:
	movl $((1 << 7) | (1 << 1) | (1 << 0)), %eax
	orl %ebx, %eax
	movl %eax, (%esi, %ecx, 4)					# mapping 0x00000000 + %ecx * 4M => 0x00000000 + %ecx * 4M
	movl %eax, (%edi, %ecx, 4)					# mapping 0x80000000 + %ecx * 4M => 0x00000000 + %ecx * 4M
	addl $(4 * 1024 * 1024), %ebx
 
	incl %ecx
	cmpl $512, %ecx
	jl 0b
 
	movl %esi, %cr3
	
	movl %cr0, %ebx
	orl $(1 << 31), %ebx						# turn paging on
	movl %ebx, %cr0
	ret
 
# Print string from %esi to EGA display (in red) and halt
error_halt:
	movl $0xb8000, %edi						# base of EGA text mode memory
	xorl %eax, %eax
	
	movw $0x3d4, %dx						# read bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	shl $8, %ax
	
	movw $0x3d4, %dx						# read bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	
	cmp $1920, %ax
	jbe cursor_ok
		movw $1920, %ax						# sanity check for the cursor on the last line
	cursor_ok:
	
	movw %ax, %bx
	shl $1, %eax
	addl %eax, %edi
	
	movw $0x0c00, %ax						# black background, light red foreground
	
	ploop:
		lodsb
		cmp $0, %al
		je ploop_end
		stosw
		inc %bx	
		jmp ploop
	ploop_end:
	
	movw $0x3d4, %dx						# write bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bh, %al
	outb %al, %dx
	
	movw $0x3d4, %dx						# write bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bl, %al
	outb %al, %dx
		
	cli
	hlt
 
#ifdef CONFIG_FB
vesa_init:
	jmp $selector(VESA_INIT_DES), $vesa_init_real - vesa_init
	
.code16
vesa_init_real:
	
	mov %cr0, %eax
	and $~1, %eax
	mov %eax, %cr0
	
	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
	
vesa_init_real2:
	
	mov $VESA_INIT_SEGMENT, %bx
	
	mov %bx, %es
	mov %bx, %fs
	mov %bx, %gs
	mov %bx, %ds
	mov %bx, %ss
	
	movl %esp, %eax
	movl $0x0000fffc, %esp
	movl $0x0000fffc, %ebp
	pushl %eax
	
#define VESA_INFO_SIZE 1024
 
#define VESA_MODE_ATTRIBUTES_OFFSET 0
#define VESA_MODE_LIST_PTR_OFFSET 14
#define VESA_MODE_SCANLINE_OFFSET 16
#define VESA_MODE_WIDTH_OFFSET 18
#define VESA_MODE_HEIGHT_OFFSET 20
#define VESA_MODE_BPP_OFFSET 25
#define VESA_MODE_PHADDR_OFFSET 40
 
#define VESA_END_OF_MODES 0xffff
 
#define VESA_OK 0x4f
 
#define VESA_GET_INFO 0x4f00
#define VESA_GET_MODE_INFO 0x4f01
#define VESA_SET_MODE 0x4f02
#define VESA_SET_PALETTE 0x4f09
 
#if CONFIG_VESA_BPP == 24
#define CONFIG_VESA_BPP_VARIANT 32
#endif
 
	mov $VESA_GET_INFO, %ax
	mov $e_vesa_init - vesa_init, %di
	push %di
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
	
	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
	mov %si, %gs
	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
	
	add $VESA_INFO_SIZE, %di
 
1:# Try next mode
	mov %gs:(%si), %cx
	cmp $VESA_END_OF_MODES, %cx
	jz 0f
	
	inc %si
	inc %si
	push %cx
	push %di
	push %si
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %si
	pop %di
	pop %cx
	cmp $VESA_OK, %al
	jnz 0f
	
	mov $CONFIG_VESA_WIDTH, %ax
	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_HEIGHT, %ax
	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_BPP, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
 
#ifdef CONFIG_VESA_BPP_VARIANT
	jz 2f
	
	mov $CONFIG_VESA_BPP_VARIANT, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
#endif
	jnz 1b
 
2:
	
	mov %cx, %bx
	or $0xc000, %bx
	push %di
	mov $VESA_SET_MODE, %ax
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
 
#if CONFIG_VESA_BPP == 8
	
	# Set 3:2:3 VGA palette
	
	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax
	push %di
	mov $vga323 - vesa_init, %di
	mov $0x100, %ecx
	
	bt $5, %ax							# Test if VGA compatible registers are present
	jnc vga_compat
		
		# Try VESA routine to set palette
		
		mov $VESA_SET_PALETTE, %ax
		xor %bl, %bl
		xor %dx, %dx
		int $0x10
		
		cmp $0x00, %ah
		je vga_not_compat
	
	vga_compat:
		
		# Try VGA registers to set palette
		
		movw $0x3c6, %dx						# Set palette mask
		movb $0xff, %al
		outb %al, %dx
		
		movw $0x3c8, %dx						# First index to set
		xor %al, %al
		outb %al, %dx
		
		movw $0x3c9, %dx						# Data port
		vga_loop:
			movb %es:2(%di), %al
			outb %al, %dx
			
			movb %es:1(%di), %al
			outb %al, %dx
			
			movb %es:(%di), %al
			outb %al, %dx
			
			addw $4, %di
			loop vga_loop
		
	vga_not_compat:
	
	pop %di
	
#endif
	
	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
	shl $16, %eax
	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
	mov VESA_MODE_BPP_OFFSET(%di), %bl
	xor %bh, %bh
	shl $16, %ebx
	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
	mov %eax, %edi
	
8:	
	
	mov %cr0, %eax
	or $1, %eax
	mov %eax, %cr0
	
	jmp 9f
9:
	
	ljmpl $selector(KTEXT_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
 
0:# No prefered mode found
	mov $0x111, %cx
	push %di
	push %cx
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %cx
	pop %di
	cmp $VESA_OK, %al
	jnz 1f
	jz 2b						# Force relative jump
	
1:
	mov $0x0003, %ax
	int $0x10
	mov $0xffffffff, %edi		# EGA text mode used, because of problems with VESA
	xor %ax, %ax
	jz 8b						# Force relative jump
 
vga323:
#include "vga323.pal"
 
.code32
vesa_init_protect:
	movw $selector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %fs
	movw %cx, %gs
	movw %cx, %ds					# kernel data + stack
	movw %cx, %ss
	
	movl $START_STACK, %esp			# initialize stack pointer
 
	jmpl $selector(KTEXT_DES), $vesa_meeting_point
 
.align 4
e_vesa_init:
#endif	
 
.section K_DATA_START, "aw", @progbits
 
.align 4096
page_directory:
	.space 4096, 0
 
grub_eax:
	.long 0
 
grub_ebx:
	.long 0
 
pse_msg:
	.asciz "Page Size Extension not supported. System halted."
 

Rev 4344	Rev 4345
1	#	1	#
2	# Copyright (c) 2001-2004 Jakub Jermar	2	# Copyright (c) 2001-2004 Jakub Jermar
3	# Copyright (c) 2005-2006 Martin Decky	3	# Copyright (c) 2005-2006 Martin Decky
4	# All rights reserved.	4	# All rights reserved.
5	#	5	#
6	# Redistribution and use in source and binary forms, with or without	6	# Redistribution and use in source and binary forms, with or without
7	# modification, are permitted provided that the following conditions	7	# modification, are permitted provided that the following conditions
8	# are met:	8	# are met:
9	#	9	#
10	# - Redistributions of source code must retain the above copyright	10	# - Redistributions of source code must retain the above copyright
11	# notice, this list of conditions and the following disclaimer.	11	# notice, this list of conditions and the following disclaimer.
12	# - Redistributions in binary form must reproduce the above copyright	12	# - Redistributions in binary form must reproduce the above copyright
13	# notice, this list of conditions and the following disclaimer in the	13	# notice, this list of conditions and the following disclaimer in the
14	# documentation and/or other materials provided with the distribution.	14	# documentation and/or other materials provided with the distribution.
15	# - The name of the author may not be used to endorse or promote products	15	# - The name of the author may not be used to endorse or promote products
16	# derived from this software without specific prior written permission.	16	# derived from this software without specific prior written permission.
17	#	17	#
18	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR	18	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
19	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES	19	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
20	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.	20	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
21	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,	21	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
22	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT	22	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
23	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,	23	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY	24	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT	25	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF	26	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
27	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.	27	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28	#	28	#
29		29
30	#include <arch/boot/boot.h>	30	#include <arch/boot/boot.h>
31	#include <arch/boot/memmap.h>	31	#include <arch/boot/memmap.h>
32	#include <arch/mm/page.h>	32	#include <arch/mm/page.h>
33	#include <arch/pm.h>	33	#include <arch/pm.h>
34		34
35	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)	35	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
36		36
37	.section K_TEXT_START, "ax"	37	.section K_TEXT_START, "ax"
38		38
39	.code32	39	.code32
40	.align 4	40	.align 4
41	.global multiboot_image_start	41	.global multiboot_image_start
42	multiboot_header:	42	multiboot_header:
43	.long MULTIBOOT_HEADER_MAGIC	43	.long MULTIBOOT_HEADER_MAGIC
44	.long MULTIBOOT_HEADER_FLAGS	44	.long MULTIBOOT_HEADER_FLAGS
45	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum	45	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum
46	.long multiboot_header	46	.long multiboot_header
47	.long unmapped_ktext_start	47	.long unmapped_ktext_start
48	.long 0	48	.long 0
49	.long 0	49	.long 0
50	.long multiboot_image_start	50	.long multiboot_image_start
51		51
52	multiboot_image_start:	52	multiboot_image_start:
53	cld	53	cld
54	movl $START_STACK, %esp # initialize stack pointer	54	movl $START_STACK, %esp # initialize stack pointer
55	lgdt KA2PA(bootstrap_gdtr) # initialize Global Descriptor Table register	55	lgdt KA2PA(bootstrap_gdtr) # initialize Global Descriptor Table register
56		56
57	movw $selector(KDATA_DES), %cx	57	movw $selector(KDATA_DES), %cx
58	movw %cx, %es	58	movw %cx, %es
59	movw %cx, %fs	59	movw %cx, %fs
60	movw %cx, %gs	60	movw %cx, %gs
61	movw %cx, %ds # kernel data + stack	61	movw %cx, %ds # kernel data + stack
62	movw %cx, %ss	62	movw %cx, %ss
63		63
64	jmpl $selector(KTEXT_DES), $multiboot_meeting_point	64	jmpl $selector(KTEXT_DES), $multiboot_meeting_point
65	multiboot_meeting_point:	65	multiboot_meeting_point:
66		66
67	movl %eax, grub_eax # save parameters from GRUB	67	movl %eax, grub_eax # save parameters from GRUB
68	movl %ebx, grub_ebx	68	movl %ebx, grub_ebx
69		69
70	xorl %eax, %eax	70	xorl %eax, %eax
71	cpuid	71	cpuid
72	cmp $0x0, %eax # any function > 0?	72	cmp $0x0, %eax # any function > 0?
73	jbe pse_unsupported	73	jbe pse_unsupported
74	movl $0x1, %eax # Basic function code 1	74	movl $0x1, %eax # Basic function code 1
75	cpuid	75	cpuid
76	bt $3, %edx # Test if PSE is supported	76	bt $3, %edx # Test if PSE is supported
77	jc pse_supported	77	jc pse_supported
78		78
79	pse_unsupported:	79	pse_unsupported:
80	movl $pse_msg, %esi	80	movl $pse_msg, %esi
81	jmp error_halt	81	jmp error_halt
82		82
83	pse_supported:	83	pse_supported:
84		84
85	#ifdef CONFIG_FB	85	#ifdef CONFIG_FB
86	mov $vesa_init, %esi	86	mov $vesa_init, %esi
87	mov $VESA_INIT_SEGMENT << 4, %edi	87	mov $VESA_INIT_SEGMENT << 4, %edi
88	mov $e_vesa_init - vesa_init, %ecx	88	mov $e_vesa_init - vesa_init, %ecx
89	rep movsb	89	rep movsb
90		90
91	mov $VESA_INIT_SEGMENT << 4, %edi	91	mov $VESA_INIT_SEGMENT << 4, %edi
92	jmpl *%edi	92	jmpl *%edi
93		93
94	vesa_meeting_point:	94	vesa_meeting_point:
95		95
96	mov %esi, KA2PA(vesa_ph_addr)	96	mov %esi, KA2PA(vesa_ph_addr)
97	mov %di, KA2PA(vesa_height)	97	mov %di, KA2PA(vesa_height)
98	shr $16, %edi	98	shr $16, %edi
99	mov %di, KA2PA(vesa_width)	99	mov %di, KA2PA(vesa_width)
100	mov %bx, KA2PA(vesa_scanline)	100	mov %bx, KA2PA(vesa_scanline)
101	shr $16, %ebx	101	shr $16, %ebx
102	mov %bx, KA2PA(vesa_bpp)	102	mov %bx, KA2PA(vesa_bpp)
103	#endif	103	#endif
104		104
105	call map_kernel # map kernel and turn paging on	105	call map_kernel # map kernel and turn paging on
106		106
107	# ia32_cboot(grub_eax, grub_ebx)	107	# arch_pre_main(grub_eax, grub_ebx)
108	pushl grub_ebx	108	pushl grub_ebx
109	pushl grub_eax	109	pushl grub_eax
110	call ia32_cboot # Does not return.	110	call arch_pre_main
111		111
-		112	call main_bsp
-		113
112	# Not reached.	114	# Not reached.
113		115
114	cli	116	cli
115	hlt	117	hlt
116		118
117	.global map_kernel	119	.global map_kernel
118	map_kernel:	120	map_kernel:
119	#	121	#
120	# Here we setup mapping for both the unmapped and mapped sections of the kernel.	122	# Here we setup mapping for both the unmapped and mapped sections of the kernel.
121	# For simplicity, we map the entire 4G space.	123	# For simplicity, we map the entire 4G space.
122	#	124	#
123	movl %cr4, %ecx	125	movl %cr4, %ecx
124	orl $(1 << 4), %ecx # turn PSE on	126	orl $(1 << 4), %ecx # turn PSE on
125	andl $(~(1 << 5)), %ecx # turn PAE off	127	andl $(~(1 << 5)), %ecx # turn PAE off
126	movl %ecx, %cr4	128	movl %ecx, %cr4
127		129
128	movl $(page_directory + 0), %esi	130	movl $(page_directory + 0), %esi
129	movl $(page_directory + 2048), %edi	131	movl $(page_directory + 2048), %edi
130	xorl %ecx, %ecx	132	xorl %ecx, %ecx
131	xorl %ebx, %ebx	133	xorl %ebx, %ebx
132	0:	134	0:
133	movl $((1 << 7) \| (1 << 1) \| (1 << 0)), %eax	135	movl $((1 << 7) \| (1 << 1) \| (1 << 0)), %eax
134	orl %ebx, %eax	136	orl %ebx, %eax
135	movl %eax, (%esi, %ecx, 4) # mapping 0x00000000 + %ecx * 4M => 0x00000000 + %ecx * 4M	137	movl %eax, (%esi, %ecx, 4) # mapping 0x00000000 + %ecx * 4M => 0x00000000 + %ecx * 4M
136	movl %eax, (%edi, %ecx, 4) # mapping 0x80000000 + %ecx * 4M => 0x00000000 + %ecx * 4M	138	movl %eax, (%edi, %ecx, 4) # mapping 0x80000000 + %ecx * 4M => 0x00000000 + %ecx * 4M
137	addl $(4 * 1024 * 1024), %ebx	139	addl $(4 * 1024 * 1024), %ebx
138		140
139	incl %ecx	141	incl %ecx
140	cmpl $512, %ecx	142	cmpl $512, %ecx
141	jl 0b	143	jl 0b
142		144
143	movl %esi, %cr3	145	movl %esi, %cr3
144		146
145	movl %cr0, %ebx	147	movl %cr0, %ebx
146	orl $(1 << 31), %ebx # turn paging on	148	orl $(1 << 31), %ebx # turn paging on
147	movl %ebx, %cr0	149	movl %ebx, %cr0
148	ret	150	ret
149		151
150	# Print string from %esi to EGA display (in red) and halt	152	# Print string from %esi to EGA display (in red) and halt
151	error_halt:	153	error_halt:
152	movl $0xb8000, %edi # base of EGA text mode memory	154	movl $0xb8000, %edi # base of EGA text mode memory
153	xorl %eax, %eax	155	xorl %eax, %eax
154		156
155	movw $0x3d4, %dx # read bits 8 - 15 of the cursor address	157	movw $0x3d4, %dx # read bits 8 - 15 of the cursor address
156	movb $0xe, %al	158	movb $0xe, %al
157	outb %al, %dx	159	outb %al, %dx
158		160
159	movw $0x3d5, %dx	161	movw $0x3d5, %dx
160	inb %dx, %al	162	inb %dx, %al
161	shl $8, %ax	163	shl $8, %ax
162		164
163	movw $0x3d4, %dx # read bits 0 - 7 of the cursor address	165	movw $0x3d4, %dx # read bits 0 - 7 of the cursor address
164	movb $0xf, %al	166	movb $0xf, %al
165	outb %al, %dx	167	outb %al, %dx
166		168
167	movw $0x3d5, %dx	169	movw $0x3d5, %dx
168	inb %dx, %al	170	inb %dx, %al
169		171
170	cmp $1920, %ax	172	cmp $1920, %ax
171	jbe cursor_ok	173	jbe cursor_ok
172	movw $1920, %ax # sanity check for the cursor on the last line	174	movw $1920, %ax # sanity check for the cursor on the last line
173	cursor_ok:	175	cursor_ok:
174		176
175	movw %ax, %bx	177	movw %ax, %bx
176	shl $1, %eax	178	shl $1, %eax
177	addl %eax, %edi	179	addl %eax, %edi
178		180
179	movw $0x0c00, %ax # black background, light red foreground	181	movw $0x0c00, %ax # black background, light red foreground
180		182
181	ploop:	183	ploop:
182	lodsb	184	lodsb
183	cmp $0, %al	185	cmp $0, %al
184	je ploop_end	186	je ploop_end
185	stosw	187	stosw
186	inc %bx	188	inc %bx
187	jmp ploop	189	jmp ploop
188	ploop_end:	190	ploop_end:
189		191
190	movw $0x3d4, %dx # write bits 8 - 15 of the cursor address	192	movw $0x3d4, %dx # write bits 8 - 15 of the cursor address
191	movb $0xe, %al	193	movb $0xe, %al
192	outb %al, %dx	194	outb %al, %dx
193		195
194	movw $0x3d5, %dx	196	movw $0x3d5, %dx
195	movb %bh, %al	197	movb %bh, %al
196	outb %al, %dx	198	outb %al, %dx
197		199
198	movw $0x3d4, %dx # write bits 0 - 7 of the cursor address	200	movw $0x3d4, %dx # write bits 0 - 7 of the cursor address
199	movb $0xf, %al	201	movb $0xf, %al
200	outb %al, %dx	202	outb %al, %dx
201		203
202	movw $0x3d5, %dx	204	movw $0x3d5, %dx
203	movb %bl, %al	205	movb %bl, %al
204	outb %al, %dx	206	outb %al, %dx
205		207
206	cli	208	cli
207	hlt	209	hlt
208		210
209	#ifdef CONFIG_FB	211	#ifdef CONFIG_FB
210	vesa_init:	212	vesa_init:
211	jmp $selector(VESA_INIT_DES), $vesa_init_real - vesa_init	213	jmp $selector(VESA_INIT_DES), $vesa_init_real - vesa_init
212		214
213	.code16	215	.code16
214	vesa_init_real:	216	vesa_init_real:
215		217
216	mov %cr0, %eax	218	mov %cr0, %eax
217	and $~1, %eax	219	and $~1, %eax
218	mov %eax, %cr0	220	mov %eax, %cr0
219		221
220	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init	222	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
221		223
222	vesa_init_real2:	224	vesa_init_real2:
223		225
224	mov $VESA_INIT_SEGMENT, %bx	226	mov $VESA_INIT_SEGMENT, %bx
225		227
226	mov %bx, %es	228	mov %bx, %es
227	mov %bx, %fs	229	mov %bx, %fs
228	mov %bx, %gs	230	mov %bx, %gs
229	mov %bx, %ds	231	mov %bx, %ds
230	mov %bx, %ss	232	mov %bx, %ss
231		233
232	movl %esp, %eax	234	movl %esp, %eax
233	movl $0x0000fffc, %esp	235	movl $0x0000fffc, %esp
234	movl $0x0000fffc, %ebp	236	movl $0x0000fffc, %ebp
235	pushl %eax	237	pushl %eax
236		238
237	#define VESA_INFO_SIZE 1024	239	#define VESA_INFO_SIZE 1024
238		240
239	#define VESA_MODE_ATTRIBUTES_OFFSET 0	241	#define VESA_MODE_ATTRIBUTES_OFFSET 0
240	#define VESA_MODE_LIST_PTR_OFFSET 14	242	#define VESA_MODE_LIST_PTR_OFFSET 14
241	#define VESA_MODE_SCANLINE_OFFSET 16	243	#define VESA_MODE_SCANLINE_OFFSET 16
242	#define VESA_MODE_WIDTH_OFFSET 18	244	#define VESA_MODE_WIDTH_OFFSET 18
243	#define VESA_MODE_HEIGHT_OFFSET 20	245	#define VESA_MODE_HEIGHT_OFFSET 20
244	#define VESA_MODE_BPP_OFFSET 25	246	#define VESA_MODE_BPP_OFFSET 25
245	#define VESA_MODE_PHADDR_OFFSET 40	247	#define VESA_MODE_PHADDR_OFFSET 40
246		248
247	#define VESA_END_OF_MODES 0xffff	249	#define VESA_END_OF_MODES 0xffff
248		250
249	#define VESA_OK 0x4f	251	#define VESA_OK 0x4f
250		252
251	#define VESA_GET_INFO 0x4f00	253	#define VESA_GET_INFO 0x4f00
252	#define VESA_GET_MODE_INFO 0x4f01	254	#define VESA_GET_MODE_INFO 0x4f01
253	#define VESA_SET_MODE 0x4f02	255	#define VESA_SET_MODE 0x4f02
254	#define VESA_SET_PALETTE 0x4f09	256	#define VESA_SET_PALETTE 0x4f09
255		257
256	#if CONFIG_VESA_BPP == 24	258	#if CONFIG_VESA_BPP == 24
257	#define CONFIG_VESA_BPP_VARIANT 32	259	#define CONFIG_VESA_BPP_VARIANT 32
258	#endif	260	#endif
259		261
260	mov $VESA_GET_INFO, %ax	262	mov $VESA_GET_INFO, %ax
261	mov $e_vesa_init - vesa_init, %di	263	mov $e_vesa_init - vesa_init, %di
262	push %di	264	push %di
263	int $0x10	265	int $0x10
264		266
265	pop %di	267	pop %di
266	cmp $VESA_OK, %al	268	cmp $VESA_OK, %al
267	jnz 0f	269	jnz 0f
268		270
269	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si	271	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
270	mov %si, %gs	272	mov %si, %gs
271	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si	273	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
272		274
273	add $VESA_INFO_SIZE, %di	275	add $VESA_INFO_SIZE, %di
274		276
275	1:# Try next mode	277	1:# Try next mode
276	mov %gs:(%si), %cx	278	mov %gs:(%si), %cx
277	cmp $VESA_END_OF_MODES, %cx	279	cmp $VESA_END_OF_MODES, %cx
278	jz 0f	280	jz 0f
279		281
280	inc %si	282	inc %si
281	inc %si	283	inc %si
282	push %cx	284	push %cx
283	push %di	285	push %di
284	push %si	286	push %si
285	mov $VESA_GET_MODE_INFO, %ax	287	mov $VESA_GET_MODE_INFO, %ax
286	int $0x10	288	int $0x10
287		289
288	pop %si	290	pop %si
289	pop %di	291	pop %di
290	pop %cx	292	pop %cx
291	cmp $VESA_OK, %al	293	cmp $VESA_OK, %al
292	jnz 0f	294	jnz 0f
293		295
294	mov $CONFIG_VESA_WIDTH, %ax	296	mov $CONFIG_VESA_WIDTH, %ax
295	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax	297	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
296	jnz 1b	298	jnz 1b
297		299
298	mov $CONFIG_VESA_HEIGHT, %ax	300	mov $CONFIG_VESA_HEIGHT, %ax
299	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax	301	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
300	jnz 1b	302	jnz 1b
301		303
302	mov $CONFIG_VESA_BPP, %al	304	mov $CONFIG_VESA_BPP, %al
303	cmp VESA_MODE_BPP_OFFSET(%di), %al	305	cmp VESA_MODE_BPP_OFFSET(%di), %al
304		306
305	#ifdef CONFIG_VESA_BPP_VARIANT	307	#ifdef CONFIG_VESA_BPP_VARIANT
306	jz 2f	308	jz 2f
307		309
308	mov $CONFIG_VESA_BPP_VARIANT, %al	310	mov $CONFIG_VESA_BPP_VARIANT, %al
309	cmp VESA_MODE_BPP_OFFSET(%di), %al	311	cmp VESA_MODE_BPP_OFFSET(%di), %al
310	#endif	312	#endif
311	jnz 1b	313	jnz 1b
312		314
313	2:	315	2:
314		316
315	mov %cx, %bx	317	mov %cx, %bx
316	or $0xc000, %bx	318	or $0xc000, %bx
317	push %di	319	push %di
318	mov $VESA_SET_MODE, %ax	320	mov $VESA_SET_MODE, %ax
319	int $0x10	321	int $0x10
320		322
321	pop %di	323	pop %di
322	cmp $VESA_OK, %al	324	cmp $VESA_OK, %al
323	jnz 0f	325	jnz 0f
324		326
325	#if CONFIG_VESA_BPP == 8	327	#if CONFIG_VESA_BPP == 8
326		328
327	# Set 3:2:3 VGA palette	329	# Set 3:2:3 VGA palette
328		330
329	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax	331	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax
330	push %di	332	push %di
331	mov $vga323 - vesa_init, %di	333	mov $vga323 - vesa_init, %di
332	mov $0x100, %ecx	334	mov $0x100, %ecx
333		335
334	bt $5, %ax # Test if VGA compatible registers are present	336	bt $5, %ax # Test if VGA compatible registers are present
335	jnc vga_compat	337	jnc vga_compat
336		338
337	# Try VESA routine to set palette	339	# Try VESA routine to set palette
338		340
339	mov $VESA_SET_PALETTE, %ax	341	mov $VESA_SET_PALETTE, %ax
340	xor %bl, %bl	342	xor %bl, %bl
341	xor %dx, %dx	343	xor %dx, %dx
342	int $0x10	344	int $0x10
343		345
344	cmp $0x00, %ah	346	cmp $0x00, %ah
345	je vga_not_compat	347	je vga_not_compat
346		348
347	vga_compat:	349	vga_compat:
348		350
349	# Try VGA registers to set palette	351	# Try VGA registers to set palette
350		352
351	movw $0x3c6, %dx # Set palette mask	353	movw $0x3c6, %dx # Set palette mask
352	movb $0xff, %al	354	movb $0xff, %al
353	outb %al, %dx	355	outb %al, %dx
354		356
355	movw $0x3c8, %dx # First index to set	357	movw $0x3c8, %dx # First index to set
356	xor %al, %al	358	xor %al, %al
357	outb %al, %dx	359	outb %al, %dx
358		360
359	movw $0x3c9, %dx # Data port	361	movw $0x3c9, %dx # Data port
360	vga_loop:	362	vga_loop:
361	movb %es:2(%di), %al	363	movb %es:2(%di), %al
362	outb %al, %dx	364	outb %al, %dx
363		365
364	movb %es:1(%di), %al	366	movb %es:1(%di), %al
365	outb %al, %dx	367	outb %al, %dx
366		368
367	movb %es:(%di), %al	369	movb %es:(%di), %al
368	outb %al, %dx	370	outb %al, %dx
369		371
370	addw $4, %di	372	addw $4, %di
371	loop vga_loop	373	loop vga_loop
372		374
373	vga_not_compat:	375	vga_not_compat:
374		376
375	pop %di	377	pop %di
376		378
377	#endif	379	#endif
378		380
379	mov VESA_MODE_PHADDR_OFFSET(%di), %esi	381	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
380	mov VESA_MODE_WIDTH_OFFSET(%di), %ax	382	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
381	shl $16, %eax	383	shl $16, %eax
382	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax	384	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
383	mov VESA_MODE_BPP_OFFSET(%di), %bl	385	mov VESA_MODE_BPP_OFFSET(%di), %bl
384	xor %bh, %bh	386	xor %bh, %bh
385	shl $16, %ebx	387	shl $16, %ebx
386	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx	388	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
387	mov %eax, %edi	389	mov %eax, %edi
388		390
389	8:	391	8:
390		392
391	mov %cr0, %eax	393	mov %cr0, %eax
392	or $1, %eax	394	or $1, %eax
393	mov %eax, %cr0	395	mov %eax, %cr0
394		396
395	jmp 9f	397	jmp 9f
396	9:	398	9:
397		399
398	ljmpl $selector(KTEXT_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)	400	ljmpl $selector(KTEXT_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
399		401
400	0:# No prefered mode found	402	0:# No prefered mode found
401	mov $0x111, %cx	403	mov $0x111, %cx
402	push %di	404	push %di
403	push %cx	405	push %cx
404	mov $VESA_GET_MODE_INFO, %ax	406	mov $VESA_GET_MODE_INFO, %ax
405	int $0x10	407	int $0x10
406		408
407	pop %cx	409	pop %cx
408	pop %di	410	pop %di
409	cmp $VESA_OK, %al	411	cmp $VESA_OK, %al
410	jnz 1f	412	jnz 1f
411	jz 2b # Force relative jump	413	jz 2b # Force relative jump
412		414
413	1:	415	1:
414	mov $0x0003, %ax	416	mov $0x0003, %ax
415	int $0x10	417	int $0x10
416	mov $0xffffffff, %edi # EGA text mode used, because of problems with VESA	418	mov $0xffffffff, %edi # EGA text mode used, because of problems with VESA
417	xor %ax, %ax	419	xor %ax, %ax
418	jz 8b # Force relative jump	420	jz 8b # Force relative jump
419		421
420	vga323:	422	vga323:
421	#include "vga323.pal"	423	#include "vga323.pal"
422		424
423	.code32	425	.code32
424	vesa_init_protect:	426	vesa_init_protect:
425	movw $selector(KDATA_DES), %cx	427	movw $selector(KDATA_DES), %cx
426	movw %cx, %es	428	movw %cx, %es
427	movw %cx, %fs	429	movw %cx, %fs
428	movw %cx, %gs	430	movw %cx, %gs
429	movw %cx, %ds # kernel data + stack	431	movw %cx, %ds # kernel data + stack
430	movw %cx, %ss	432	movw %cx, %ss
431		433
432	movl $START_STACK, %esp # initialize stack pointer	434	movl $START_STACK, %esp # initialize stack pointer
433		435
434	jmpl $selector(KTEXT_DES), $vesa_meeting_point	436	jmpl $selector(KTEXT_DES), $vesa_meeting_point
435		437
436	.align 4	438	.align 4
437	e_vesa_init:	439	e_vesa_init:
438	#endif	440	#endif
439		441
440	.section K_DATA_START, "aw", @progbits	442	.section K_DATA_START, "aw", @progbits
441		443
442	.align 4096	444	.align 4096
443	page_directory:	445	page_directory:
444	.space 4096, 0	446	.space 4096, 0
445		447
446	grub_eax:	448	grub_eax:
447	.long 0	449	.long 0
448		450
449	grub_ebx:	451	grub_ebx:
450	.long 0	452	.long 0
451		453
452	pse_msg:	454	pse_msg:
453	.asciz "Page Size Extension not supported. System halted."	455	.asciz "Page Size Extension not supported. System halted."
454		456

Subversion Repositories HelenOS

(root)/branches/dynload/kernel/arch/ia32/src/boot/boot.S – Rev 4344 → 4345