WebSVN – HelenOS – Diff – /trunk/kernel/arch/ia32/src/boot/boot.S


#
# Copyright (c) 2001-2004 Jakub Jermar
# Copyright (c) 2005-2006 Martin Decky
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
#
# - Redistributions of source code must retain the above copyright
#   notice, this list of conditions and the following disclaimer.
# - Redistributions in binary form must reproduce the above copyright
#   notice, this list of conditions and the following disclaimer in the
#   documentation and/or other materials provided with the distribution.
# - The name of the author may not be used to endorse or promote products
#   derived from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
#
 
#include <arch/boot/boot.h>
#include <arch/boot/memmap.h>
#include <arch/mm/page.h>
#include <arch/pm.h>
 
#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
 
.section K_TEXT_START, "ax"
 
.code32
.align 4
.global multiboot_image_start
multiboot_header:
	.long MULTIBOOT_HEADER_MAGIC
	.long MULTIBOOT_HEADER_FLAGS
	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS)	# checksum
	.long multiboot_header
	.long unmapped_ktext_start
	.long 0
	.long 0
	.long multiboot_image_start
	
multiboot_image_start:
	cld
	movl $START_STACK, %esp			# initialize stack pointer
	lgdt KA2PA(bootstrap_gdtr)		# initialize Global Descriptor Table register
 
	movw $selector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %fs
	movw %cx, %gs
	movw %cx, %ds					# kernel data + stack
	movw %cx, %ss
	
	jmpl $selector(KTEXT_DES), $multiboot_meeting_point
	multiboot_meeting_point:
	
	movl %eax, grub_eax					# save parameters from GRUB
	movl %ebx, grub_ebx
	
	xorl %eax, %eax  
 	cpuid
 	cmp $0x0, %eax						# any function > 0?
	jbe pse_unsupported
	movl $0x1, %eax						# Basic function code 1
	cpuid
	bt $3, %edx							# Test if PSE is supported
	jc pse_supported
 
	pse_unsupported:
		movl $pse_msg, %esi
		jmp error_halt
	
	pse_supported:
	
#ifdef CONFIG_FB
	mov $vesa_init, %esi
	mov $VESA_INIT_SEGMENT << 4, %edi
	mov $e_vesa_init - vesa_init, %ecx
 
	rep movsb
 
	mov $VESA_INIT_SEGMENT << 4, %edi
	jmpl *%edi
	
	vesa_meeting_point:
	
	mov %esi, KA2PA(vesa_ph_addr)
	mov %di, KA2PA(vesa_height)
	shr $16, %edi
	mov %di, KA2PA(vesa_width)
	mov %bx, KA2PA(vesa_scanline)
	shr $16, %ebx
	mov %bx, KA2PA(vesa_bpp)
#endif	
	
	call map_kernel							# map kernel and turn paging on
	
	movl grub_eax, %eax
	movl grub_ebx, %ebx
	cmpl $MULTIBOOT_LOADER_MAGIC, %eax				# compare GRUB signature
	je valid_boot
		
		xorl %ecx, %ecx							# no memory map available
		movl %ecx, e820counter
		
		jmp invalid_boot
		
	valid_boot:
		
		movl (%ebx), %eax						# ebx = physical address of struct multiboot_info
		
		bt $3, %eax								# mbi->flags[3] (mods_count, mods_addr valid)
		jc mods_valid
			
			xorl %ecx, %ecx
			movl %ecx, init
			jmp mods_end
		
		mods_valid:
		
		movl 20(%ebx), %ecx						# mbi->mods_count
		movl %ecx, init
		
		cmpl $0, %ecx
		je mods_end
		
		movl 24(%ebx), %esi						# mbi->mods_addr
		movl $init, %edi
		
		mods_loop:
		
			movl 0(%esi), %edx					# mods->mod_start
			addl $0x80000000, %edx
			movl %edx, 4(%edi)
			
			movl 4(%esi), %edx
			subl 0(%esi), %edx					# mods->mod_end - mods->mod_start
			movl %edx, 8(%edi)
			
			addl $16, %esi
			addl $8	, %edi
			
			loop mods_loop
			
		mods_end:
		
		bt $6, %eax								# mbi->flags[6] (mmap_length, mmap_addr valid)	
		jc mmap_valid
			
			xorl %edx, %edx
			jmp mmap_invalid
			
		mmap_valid:
		movl 44(%ebx), %ecx						# mbi->mmap_length
		movl 48(%ebx), %esi						# mbi->mmap_addr
		movl $e820table, %edi
		xorl %edx, %edx
		
		mmap_loop:
			cmpl $0, %ecx
			jle mmap_end
			
			movl 4(%esi), %eax					# mmap->base_addr_low
			movl %eax, (%edi)
			
			movl 8(%esi), %eax					# mmap->base_addr_high
			movl %eax, 4(%edi)
			
			movl 12(%esi), %eax					# mmap->length_low
			movl %eax, 8(%edi)
			
			movl 16(%esi), %eax					# mmap->length_high
			movl %eax, 12(%edi)
			
			movl 20(%esi), %eax					# mmap->type
			movl %eax, 16(%edi)
			
			movl (%esi), %eax					# mmap->size
			addl $0x4, %eax
			addl %eax, %esi
			subl %eax, %ecx
			addl $MEMMAP_E820_RECORD_SIZE, %edi
			incl %edx
			jmp mmap_loop
		
		mmap_end:
		
		mmap_invalid:
		movl %edx, e820counter
		
	invalid_boot:
	
#ifdef CONFIG_SMP
	
	# copy AP bootstrap routines below 1 MB
	
	movl $BOOT_OFFSET, %esi
	movl $AP_BOOT_OFFSET, %edi
	movl $_hardcoded_unmapped_size, %ecx
 
	rep movsb
	
#endif
 
	call main_bsp								# never returns
 
	cli
	hlt
 
.global map_kernel
map_kernel:
	#
	# Here we setup mapping for both the unmapped and mapped sections of the kernel.
	# For simplicity, we map the entire 4G space.
	#
	movl %cr4, %ecx
	orl $(1 << 4), %ecx							# turn PSE on
	andl $(~(1 << 5)), %ecx						# turn PAE off
	movl %ecx, %cr4
	
	movl $(page_directory + 0), %esi
	movl $(page_directory + 2048), %edi
	xorl %ecx, %ecx
	xorl %ebx, %ebx
0:
	movl $((1 << 7) | (1 << 1) | (1 << 0)), %eax
	orl %ebx, %eax
	movl %eax, (%esi, %ecx, 4)					# mapping 0x00000000 + %ecx * 4M => 0x00000000 + %ecx * 4M
	movl %eax, (%edi, %ecx, 4)					# mapping 0x80000000 + %ecx * 4M => 0x00000000 + %ecx * 4M
	addl $(4 * 1024 * 1024), %ebx
 
	incl %ecx
	cmpl $512, %ecx
	jl 0b
 
	movl %esi, %cr3
	
	movl %cr0, %ebx
	orl $(1 << 31), %ebx						# turn paging on
	movl %ebx, %cr0
	ret
 
# Print string from %esi to EGA display (in red) and halt
error_halt:
	movl $0xb8000, %edi						# base of EGA text mode memory
	xorl %eax, %eax
	
	movw $0x3d4, %dx						# read bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	shl $8, %ax
	
	movw $0x3d4, %dx						# read bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	
	cmp $1920, %ax
	jbe cursor_ok
		movw $1920, %ax						# sanity check for the cursor on the last line
	cursor_ok:
	
	movw %ax, %bx
	shl $1, %eax
	addl %eax, %edi
	
	movw $0x0c00, %ax						# black background, light red foreground
 
	
	ploop:
		lodsb
		cmp $0, %al
		je ploop_end
		stosw
		inc %bx	
		jmp ploop
	ploop_end:
	
	movw $0x3d4, %dx						# write bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bh, %al
	outb %al, %dx
	
	movw $0x3d4, %dx						# write bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bl, %al
	outb %al, %dx
		
	cli
	hlt
 
#ifdef CONFIG_FB
vesa_init:
	jmp $selector(VESA_INIT_DES), $vesa_init_real - vesa_init
	
.code16
vesa_init_real:
	
	mov %cr0, %eax
	and $~1, %eax
	mov %eax, %cr0
	
	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
	
vesa_init_real2:
	
	mov $VESA_INIT_SEGMENT, %bx
	
	mov %bx, %es
	mov %bx, %fs
	mov %bx, %gs
	mov %bx, %ds
	mov %bx, %ss
	
	movl %esp, %eax
	movl $0x0000fffc, %esp
	movl $0x0000fffc, %ebp
	pushl %eax
	
#define VESA_INFO_SIZE 1024
 
#define VESA_MODE_ATTRIBUTES_OFFSET 0
#define VESA_MODE_LIST_PTR_OFFSET 14
#define VESA_MODE_SCANLINE_OFFSET 16
#define VESA_MODE_WIDTH_OFFSET 18
#define VESA_MODE_HEIGHT_OFFSET 20
#define VESA_MODE_BPP_OFFSET 25
#define VESA_MODE_PHADDR_OFFSET 40
 
#define VESA_END_OF_MODES 0xffff
 
#define VESA_OK 0x4f
 
#define VESA_GET_INFO 0x4f00
#define VESA_GET_MODE_INFO 0x4f01
#define VESA_SET_MODE 0x4f02
#define VESA_SET_PALETTE 0x4f09
 
#if CONFIG_VESA_BPP == 24
#define CONFIG_VESA_BPP_VARIANT 32
#endif
 
	mov $VESA_GET_INFO, %ax
	mov $e_vesa_init - vesa_init, %di
	push %di
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
	
	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
	mov %si, %gs
	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
	
	add $VESA_INFO_SIZE, %di
 
1:# Try next mode
	mov %gs:(%si), %cx
	cmp $VESA_END_OF_MODES, %cx
	jz 0f
	
	inc %si
	inc %si
	push %cx
	push %di
	push %si
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %si
	pop %di
	pop %cx
	cmp $VESA_OK, %al
	jnz 0f
	
	mov $CONFIG_VESA_WIDTH, %ax
	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_HEIGHT, %ax
	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_BPP, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
 
#ifdef CONFIG_VESA_BPP_VARIANT
	jz 2f
	
	mov $CONFIG_VESA_BPP_VARIANT, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
#endif
	jnz 1b
 
2:
	
	mov %cx, %bx
	or $0xc000, %bx
	push %di
	mov $VESA_SET_MODE, %ax
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
 
#if CONFIG_VESA_BPP == 8
	
	# Set 3:2:3 VGA palette
	
	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax
	push %di
	mov $vga323 - vesa_init, %di
	mov $0x100, %ecx
	
	bt $5, %ax							# Test if VGA compatible registers are present
	jnc vga_compat
		
		# Try VESA routine to set palette
		
		mov $VESA_SET_PALETTE, %ax
		xor %bl, %bl
		xor %dx, %dx
		int $0x10
		
		jmp vga_not_compat
	
	vga_compat:
		
		# Try VGA registers to set palette
		
		movw $0x3c6, %dx						# Set palette mask
		movb $0xff, %al
		outb %al, %dx
		
		movw $0x3c8, %dx						# First index to set
		xor %al, %al
		outb %al, %dx
		
		movw $0x3c9, %dx						# Data port
		vga_loop:
			movb %es:2(%di), %al
			outb %al, %dx
			
			movb %es:1(%di), %al
			outb %al, %dx
			
			movb %es:(%di), %al
			outb %al, %dx
			
			addw $4, %di
			loop vga_loop
		
	vga_not_compat:
	
	pop %di
	
#endif
	
	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
	shl $16, %eax
	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
	mov VESA_MODE_BPP_OFFSET(%di), %bl
	xor %bh, %bh
	shl $16, %ebx
	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
	mov %eax, %edi
	
8:	
	
	mov %cr0, %eax
	or $1, %eax
	mov %eax, %cr0
	
	jmp 9f
9:
	
	ljmpl $selector(KTEXT_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
 
0:# No prefered mode found
	mov $0x111, %cx
	push %di
	push %cx
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %cx
	pop %di
	cmp $VESA_OK, %al
	jnz 1f
	jz 2b						# Force relative jump
	
1:
	mov $0x0003, %ax
	int $0x10
	mov $0xffffffff, %edi		# EGA text mode used, because of problems with VESA
	xor %ax, %ax
	jz 8b						# Force relative jump
 
vga323:
#include "vga323.pal"
 
.code32
vesa_init_protect:
	movw $selector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %fs
	movw %cx, %gs
	movw %cx, %ds					# kernel data + stack
	movw %cx, %ss
	
	movl $START_STACK, %esp			# initialize stack pointer
 
	jmpl $selector(KTEXT_DES), $vesa_meeting_point
 
.align 4
e_vesa_init:
#endif	
 
.section K_DATA_START, "aw", @progbits
 
.align 4096
page_directory:
	.space 4096, 0
 
grub_eax:
	.long 0
 
grub_ebx:
	.long 0
 
pse_msg:
	.asciz "Page Size Extension not supported. System halted."
 

Rev 2725	Rev 2784
1	#	1	#
2	# Copyright (c) 2001-2004 Jakub Jermar	2	# Copyright (c) 2001-2004 Jakub Jermar
3	# Copyright (c) 2005-2006 Martin Decky	3	# Copyright (c) 2005-2006 Martin Decky
4	# All rights reserved.	4	# All rights reserved.
5	#	5	#
6	# Redistribution and use in source and binary forms, with or without	6	# Redistribution and use in source and binary forms, with or without
7	# modification, are permitted provided that the following conditions	7	# modification, are permitted provided that the following conditions
8	# are met:	8	# are met:
9	#	9	#
10	# - Redistributions of source code must retain the above copyright	10	# - Redistributions of source code must retain the above copyright
11	# notice, this list of conditions and the following disclaimer.	11	# notice, this list of conditions and the following disclaimer.
12	# - Redistributions in binary form must reproduce the above copyright	12	# - Redistributions in binary form must reproduce the above copyright
13	# notice, this list of conditions and the following disclaimer in the	13	# notice, this list of conditions and the following disclaimer in the
14	# documentation and/or other materials provided with the distribution.	14	# documentation and/or other materials provided with the distribution.
15	# - The name of the author may not be used to endorse or promote products	15	# - The name of the author may not be used to endorse or promote products
16	# derived from this software without specific prior written permission.	16	# derived from this software without specific prior written permission.
17	#	17	#
18	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR	18	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
19	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES	19	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
20	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.	20	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
21	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,	21	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
22	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT	22	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
23	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,	23	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY	24	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT	25	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF	26	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
27	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.	27	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28	#	28	#
29		29
30	#include <arch/boot/boot.h>	30	#include <arch/boot/boot.h>
31	#include <arch/boot/memmap.h>	31	#include <arch/boot/memmap.h>
32	#include <arch/mm/page.h>	32	#include <arch/mm/page.h>
33	#include <arch/pm.h>	33	#include <arch/pm.h>
34		34
35	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)	35	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
36		36
37	.section K_TEXT_START, "ax"	37	.section K_TEXT_START, "ax"
38		38
39	.code32	39	.code32
40	.align 4	40	.align 4
41	.global multiboot_image_start	41	.global multiboot_image_start
42	multiboot_header:	42	multiboot_header:
43	.long MULTIBOOT_HEADER_MAGIC	43	.long MULTIBOOT_HEADER_MAGIC
44	.long MULTIBOOT_HEADER_FLAGS	44	.long MULTIBOOT_HEADER_FLAGS
45	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum	45	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum
46	.long multiboot_header	46	.long multiboot_header
47	.long unmapped_ktext_start	47	.long unmapped_ktext_start
48	.long 0	48	.long 0
49	.long 0	49	.long 0
50	.long multiboot_image_start	50	.long multiboot_image_start
51		51
52	multiboot_image_start:	52	multiboot_image_start:
-		53	cld
53	movl $START_STACK, %esp # initialize stack pointer	54	movl $START_STACK, %esp # initialize stack pointer
54	lgdt KA2PA(bootstrap_gdtr) # initialize Global Descriptor Table register	55	lgdt KA2PA(bootstrap_gdtr) # initialize Global Descriptor Table register
55		56
56	movw $selector(KDATA_DES), %cx	57	movw $selector(KDATA_DES), %cx
57	movw %cx, %es	58	movw %cx, %es
58	movw %cx, %fs	59	movw %cx, %fs
59	movw %cx, %gs	60	movw %cx, %gs
60	movw %cx, %ds # kernel data + stack	61	movw %cx, %ds # kernel data + stack
61	movw %cx, %ss	62	movw %cx, %ss
62		63
63	jmpl $selector(KTEXT_DES), $multiboot_meeting_point	64	jmpl $selector(KTEXT_DES), $multiboot_meeting_point
64	multiboot_meeting_point:	65	multiboot_meeting_point:
65		66
66	movl %eax, grub_eax # save parameters from GRUB	67	movl %eax, grub_eax # save parameters from GRUB
67	movl %ebx, grub_ebx	68	movl %ebx, grub_ebx
68		69
69	xorl %eax, %eax	70	xorl %eax, %eax
70	cpuid	71	cpuid
71	cmp $0x0, %eax # any function > 0?	72	cmp $0x0, %eax # any function > 0?
72	jbe pse_unsupported	73	jbe pse_unsupported
73	movl $0x1, %eax # Basic function code 1	74	movl $0x1, %eax # Basic function code 1
74	cpuid	75	cpuid
75	bt $3, %edx # Test if PSE is supported	76	bt $3, %edx # Test if PSE is supported
76	jc pse_supported	77	jc pse_supported
77		78
78	pse_unsupported:	79	pse_unsupported:
79	movl $pse_msg, %esi	80	movl $pse_msg, %esi
80	jmp error_halt	81	jmp error_halt
81		82
82	pse_supported:	83	pse_supported:
83		84
84	#ifdef CONFIG_FB	85	#ifdef CONFIG_FB
85	mov $vesa_init, %esi	86	mov $vesa_init, %esi
86	mov $VESA_INIT_SEGMENT << 4, %edi	87	mov $VESA_INIT_SEGMENT << 4, %edi
87	mov $e_vesa_init - vesa_init, %ecx	88	mov $e_vesa_init - vesa_init, %ecx
88	cld	-
89	rep movsb	89	rep movsb
90		90
91	mov $VESA_INIT_SEGMENT << 4, %edi	91	mov $VESA_INIT_SEGMENT << 4, %edi
92	jmpl *%edi	92	jmpl *%edi
93		93
94	vesa_meeting_point:	94	vesa_meeting_point:
95		95
96	mov %esi, KA2PA(vesa_ph_addr)	96	mov %esi, KA2PA(vesa_ph_addr)
97	mov %di, KA2PA(vesa_height)	97	mov %di, KA2PA(vesa_height)
98	shr $16, %edi	98	shr $16, %edi
99	mov %di, KA2PA(vesa_width)	99	mov %di, KA2PA(vesa_width)
100	mov %bx, KA2PA(vesa_scanline)	100	mov %bx, KA2PA(vesa_scanline)
101	shr $16, %ebx	101	shr $16, %ebx
102	mov %bx, KA2PA(vesa_bpp)	102	mov %bx, KA2PA(vesa_bpp)
103	#endif	103	#endif
104		104
105	call map_kernel # map kernel and turn paging on	105	call map_kernel # map kernel and turn paging on
106		106
107	movl grub_eax, %eax	107	movl grub_eax, %eax
108	movl grub_ebx, %ebx	108	movl grub_ebx, %ebx
109	cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature	109	cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature
110	je valid_boot	110	je valid_boot
111		111
112	xorl %ecx, %ecx # no memory map available	112	xorl %ecx, %ecx # no memory map available
113	movl %ecx, e820counter	113	movl %ecx, e820counter
114		114
115	jmp invalid_boot	115	jmp invalid_boot
116		116
117	valid_boot:	117	valid_boot:
118		118
119	movl (%ebx), %eax # ebx = physical address of struct multiboot_info	119	movl (%ebx), %eax # ebx = physical address of struct multiboot_info
120		120
121	bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)	121	bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)
122	jc mods_valid	122	jc mods_valid
123		123
124	xorl %ecx, %ecx	124	xorl %ecx, %ecx
125	movl %ecx, init	125	movl %ecx, init
126	jmp mods_end	126	jmp mods_end
127		127
128	mods_valid:	128	mods_valid:
129		129
130	movl 20(%ebx), %ecx # mbi->mods_count	130	movl 20(%ebx), %ecx # mbi->mods_count
131	movl %ecx, init	131	movl %ecx, init
132		132
133	cmpl $0, %ecx	133	cmpl $0, %ecx
134	je mods_end	134	je mods_end
135		135
136	movl 24(%ebx), %esi # mbi->mods_addr	136	movl 24(%ebx), %esi # mbi->mods_addr
137	movl $init, %edi	137	movl $init, %edi
138		138
139	mods_loop:	139	mods_loop:
140		140
141	movl 0(%esi), %edx # mods->mod_start	141	movl 0(%esi), %edx # mods->mod_start
142	addl $0x80000000, %edx	142	addl $0x80000000, %edx
143	movl %edx, 4(%edi)	143	movl %edx, 4(%edi)
144		144
145	movl 4(%esi), %edx	145	movl 4(%esi), %edx
146	subl 0(%esi), %edx # mods->mod_end - mods->mod_start	146	subl 0(%esi), %edx # mods->mod_end - mods->mod_start
147	movl %edx, 8(%edi)	147	movl %edx, 8(%edi)
148		148
149	addl $16, %esi	149	addl $16, %esi
150	addl $8 , %edi	150	addl $8 , %edi
151		151
152	loop mods_loop	152	loop mods_loop
153		153
154	mods_end:	154	mods_end:
155		155
156	bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)	156	bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)
157	jc mmap_valid	157	jc mmap_valid
158		158
159	xorl %edx, %edx	159	xorl %edx, %edx
160	jmp mmap_invalid	160	jmp mmap_invalid
161		161
162	mmap_valid:	162	mmap_valid:
163	movl 44(%ebx), %ecx # mbi->mmap_length	163	movl 44(%ebx), %ecx # mbi->mmap_length
164	movl 48(%ebx), %esi # mbi->mmap_addr	164	movl 48(%ebx), %esi # mbi->mmap_addr
165	movl $e820table, %edi	165	movl $e820table, %edi
166	xorl %edx, %edx	166	xorl %edx, %edx
167		167
168	mmap_loop:	168	mmap_loop:
169	cmpl $0, %ecx	169	cmpl $0, %ecx
170	jle mmap_end	170	jle mmap_end
171		171
172	movl 4(%esi), %eax # mmap->base_addr_low	172	movl 4(%esi), %eax # mmap->base_addr_low
173	movl %eax, (%edi)	173	movl %eax, (%edi)
174		174
175	movl 8(%esi), %eax # mmap->base_addr_high	175	movl 8(%esi), %eax # mmap->base_addr_high
176	movl %eax, 4(%edi)	176	movl %eax, 4(%edi)
177		177
178	movl 12(%esi), %eax # mmap->length_low	178	movl 12(%esi), %eax # mmap->length_low
179	movl %eax, 8(%edi)	179	movl %eax, 8(%edi)
180		180
181	movl 16(%esi), %eax # mmap->length_high	181	movl 16(%esi), %eax # mmap->length_high
182	movl %eax, 12(%edi)	182	movl %eax, 12(%edi)
183		183
184	movl 20(%esi), %eax # mmap->type	184	movl 20(%esi), %eax # mmap->type
185	movl %eax, 16(%edi)	185	movl %eax, 16(%edi)
186		186
187	movl (%esi), %eax # mmap->size	187	movl (%esi), %eax # mmap->size
188	addl $0x4, %eax	188	addl $0x4, %eax
189	addl %eax, %esi	189	addl %eax, %esi
190	subl %eax, %ecx	190	subl %eax, %ecx
191	addl $MEMMAP_E820_RECORD_SIZE, %edi	191	addl $MEMMAP_E820_RECORD_SIZE, %edi
192	incl %edx	192	incl %edx
193	jmp mmap_loop	193	jmp mmap_loop
194		194
195	mmap_end:	195	mmap_end:
196		196
197	mmap_invalid:	197	mmap_invalid:
198	movl %edx, e820counter	198	movl %edx, e820counter
199		199
200	invalid_boot:	200	invalid_boot:
201		201
202	#ifdef CONFIG_SMP	202	#ifdef CONFIG_SMP
203		203
204	# copy AP bootstrap routines below 1 MB	204	# copy AP bootstrap routines below 1 MB
205		205
206	movl $BOOT_OFFSET, %esi	206	movl $BOOT_OFFSET, %esi
207	movl $AP_BOOT_OFFSET, %edi	207	movl $AP_BOOT_OFFSET, %edi
208	movl $_hardcoded_unmapped_size, %ecx	208	movl $_hardcoded_unmapped_size, %ecx
209	cld	-
210	rep movsb	209	rep movsb
211		210
212	#endif	211	#endif
213		212
214	call main_bsp # never returns	213	call main_bsp # never returns
215		214
216	cli	215	cli
217	hlt	216	hlt
218		217
219	.global map_kernel	218	.global map_kernel
220	map_kernel:	219	map_kernel:
221	#	220	#
222	# Here we setup mapping for both the unmapped and mapped sections of the kernel.	221	# Here we setup mapping for both the unmapped and mapped sections of the kernel.
223	# For simplicity, we map the entire 4G space.	222	# For simplicity, we map the entire 4G space.
224	#	223	#
225	movl %cr4, %ecx	224	movl %cr4, %ecx
226	orl $(1 << 4), %ecx # turn PSE on	225	orl $(1 << 4), %ecx # turn PSE on
227	andl $(~(1 << 5)), %ecx # turn PAE off	226	andl $(~(1 << 5)), %ecx # turn PAE off
228	movl %ecx, %cr4	227	movl %ecx, %cr4
229		228
230	movl $(page_directory + 0), %esi	229	movl $(page_directory + 0), %esi
231	movl $(page_directory + 2048), %edi	230	movl $(page_directory + 2048), %edi
232	xorl %ecx, %ecx	231	xorl %ecx, %ecx
233	xorl %ebx, %ebx	232	xorl %ebx, %ebx
234	0:	233	0:
235	movl $((1 << 7) \| (1 << 1) \| (1 << 0)), %eax	234	movl $((1 << 7) \| (1 << 1) \| (1 << 0)), %eax
236	orl %ebx, %eax	235	orl %ebx, %eax
237	movl %eax, (%esi, %ecx, 4) # mapping 0x00000000 + %ecx * 4M => 0x00000000 + %ecx * 4M	236	movl %eax, (%esi, %ecx, 4) # mapping 0x00000000 + %ecx * 4M => 0x00000000 + %ecx * 4M
238	movl %eax, (%edi, %ecx, 4) # mapping 0x80000000 + %ecx * 4M => 0x00000000 + %ecx * 4M	237	movl %eax, (%edi, %ecx, 4) # mapping 0x80000000 + %ecx * 4M => 0x00000000 + %ecx * 4M
239	addl $(4 * 1024 * 1024), %ebx	238	addl $(4 * 1024 * 1024), %ebx
240		239
241	incl %ecx	240	incl %ecx
242	cmpl $512, %ecx	241	cmpl $512, %ecx
243	jl 0b	242	jl 0b
244		243
245	movl %esi, %cr3	244	movl %esi, %cr3
246		245
247	movl %cr0, %ebx	246	movl %cr0, %ebx
248	orl $(1 << 31), %ebx # turn paging on	247	orl $(1 << 31), %ebx # turn paging on
249	movl %ebx, %cr0	248	movl %ebx, %cr0
250	ret	249	ret
251		250
252	# Print string from %esi to EGA display (in red) and halt	251	# Print string from %esi to EGA display (in red) and halt
253	error_halt:	252	error_halt:
254	movl $0xb8000, %edi # base of EGA text mode memory	253	movl $0xb8000, %edi # base of EGA text mode memory
255	xorl %eax, %eax	254	xorl %eax, %eax
256		255
257	movw $0x3d4, %dx # read bits 8 - 15 of the cursor address	256	movw $0x3d4, %dx # read bits 8 - 15 of the cursor address
258	movb $0xe, %al	257	movb $0xe, %al
259	outb %al, %dx	258	outb %al, %dx
260		259
261	movw $0x3d5, %dx	260	movw $0x3d5, %dx
262	inb %dx, %al	261	inb %dx, %al
263	shl $8, %ax	262	shl $8, %ax
264		263
265	movw $0x3d4, %dx # read bits 0 - 7 of the cursor address	264	movw $0x3d4, %dx # read bits 0 - 7 of the cursor address
266	movb $0xf, %al	265	movb $0xf, %al
267	outb %al, %dx	266	outb %al, %dx
268		267
269	movw $0x3d5, %dx	268	movw $0x3d5, %dx
270	inb %dx, %al	269	inb %dx, %al
271		270
272	cmp $1920, %ax	271	cmp $1920, %ax
273	jbe cursor_ok	272	jbe cursor_ok
274	movw $1920, %ax # sanity check for the cursor on the last line	273	movw $1920, %ax # sanity check for the cursor on the last line
275	cursor_ok:	274	cursor_ok:
276		275
277	movw %ax, %bx	276	movw %ax, %bx
278	shl $1, %eax	277	shl $1, %eax
279	addl %eax, %edi	278	addl %eax, %edi
280		279
281	movw $0x0c00, %ax # black background, light red foreground	280	movw $0x0c00, %ax # black background, light red foreground
282	cld	-
283		281
284	ploop:	282	ploop:
285	lodsb	283	lodsb
286	cmp $0, %al	284	cmp $0, %al
287	je ploop_end	285	je ploop_end
288	stosw	286	stosw
289	inc %bx	287	inc %bx
290	jmp ploop	288	jmp ploop
291	ploop_end:	289	ploop_end:
292		290
293	movw $0x3d4, %dx # write bits 8 - 15 of the cursor address	291	movw $0x3d4, %dx # write bits 8 - 15 of the cursor address
294	movb $0xe, %al	292	movb $0xe, %al
295	outb %al, %dx	293	outb %al, %dx
296		294
297	movw $0x3d5, %dx	295	movw $0x3d5, %dx
298	movb %bh, %al	296	movb %bh, %al
299	outb %al, %dx	297	outb %al, %dx
300		298
301	movw $0x3d4, %dx # write bits 0 - 7 of the cursor address	299	movw $0x3d4, %dx # write bits 0 - 7 of the cursor address
302	movb $0xf, %al	300	movb $0xf, %al
303	outb %al, %dx	301	outb %al, %dx
304		302
305	movw $0x3d5, %dx	303	movw $0x3d5, %dx
306	movb %bl, %al	304	movb %bl, %al
307	outb %al, %dx	305	outb %al, %dx
308		306
309	cli	307	cli
310	hlt	308	hlt
311		309
312	#ifdef CONFIG_FB	310	#ifdef CONFIG_FB
313	vesa_init:	311	vesa_init:
314	jmp $selector(VESA_INIT_DES), $vesa_init_real - vesa_init	312	jmp $selector(VESA_INIT_DES), $vesa_init_real - vesa_init
315		313
316	.code16	314	.code16
317	vesa_init_real:	315	vesa_init_real:
318		316
319	mov %cr0, %eax	317	mov %cr0, %eax
320	and $~1, %eax	318	and $~1, %eax
321	mov %eax, %cr0	319	mov %eax, %cr0
322		320
323	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init	321	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
324		322
325	vesa_init_real2:	323	vesa_init_real2:
326		324
327	mov $VESA_INIT_SEGMENT, %bx	325	mov $VESA_INIT_SEGMENT, %bx
328		326
329	mov %bx, %es	327	mov %bx, %es
330	mov %bx, %fs	328	mov %bx, %fs
331	mov %bx, %gs	329	mov %bx, %gs
332	mov %bx, %ds	330	mov %bx, %ds
333	mov %bx, %ss	331	mov %bx, %ss
334		332
335	movl %esp, %eax	333	movl %esp, %eax
336	movl $0x0000fffc, %esp	334	movl $0x0000fffc, %esp
337	movl $0x0000fffc, %ebp	335	movl $0x0000fffc, %ebp
338	pushl %eax	336	pushl %eax
339		337
340	#define VESA_INFO_SIZE 1024	338	#define VESA_INFO_SIZE 1024
341		339
342	#define VESA_MODE_ATTRIBUTES_OFFSET 0	340	#define VESA_MODE_ATTRIBUTES_OFFSET 0
343	#define VESA_MODE_LIST_PTR_OFFSET 14	341	#define VESA_MODE_LIST_PTR_OFFSET 14
344	#define VESA_MODE_SCANLINE_OFFSET 16	342	#define VESA_MODE_SCANLINE_OFFSET 16
345	#define VESA_MODE_WIDTH_OFFSET 18	343	#define VESA_MODE_WIDTH_OFFSET 18
346	#define VESA_MODE_HEIGHT_OFFSET 20	344	#define VESA_MODE_HEIGHT_OFFSET 20
347	#define VESA_MODE_BPP_OFFSET 25	345	#define VESA_MODE_BPP_OFFSET 25
348	#define VESA_MODE_PHADDR_OFFSET 40	346	#define VESA_MODE_PHADDR_OFFSET 40
349		347
350	#define VESA_END_OF_MODES 0xffff	348	#define VESA_END_OF_MODES 0xffff
351		349
352	#define VESA_OK 0x4f	350	#define VESA_OK 0x4f
353		351
354	#define VESA_GET_INFO 0x4f00	352	#define VESA_GET_INFO 0x4f00
355	#define VESA_GET_MODE_INFO 0x4f01	353	#define VESA_GET_MODE_INFO 0x4f01
356	#define VESA_SET_MODE 0x4f02	354	#define VESA_SET_MODE 0x4f02
357	#define VESA_SET_PALETTE 0x4f09	355	#define VESA_SET_PALETTE 0x4f09
358		356
359	#if CONFIG_VESA_BPP == 24	357	#if CONFIG_VESA_BPP == 24
360	#define CONFIG_VESA_BPP_VARIANT 32	358	#define CONFIG_VESA_BPP_VARIANT 32
361	#endif	359	#endif
362		360
363	mov $VESA_GET_INFO, %ax	361	mov $VESA_GET_INFO, %ax
364	mov $e_vesa_init - vesa_init, %di	362	mov $e_vesa_init - vesa_init, %di
365	push %di	363	push %di
366	int $0x10	364	int $0x10
367		365
368	pop %di	366	pop %di
369	cmp $VESA_OK, %al	367	cmp $VESA_OK, %al
370	jnz 0f	368	jnz 0f
371		369
372	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si	370	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
373	mov %si, %gs	371	mov %si, %gs
374	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si	372	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
375		373
376	add $VESA_INFO_SIZE, %di	374	add $VESA_INFO_SIZE, %di
377		375
378	1:# Try next mode	376	1:# Try next mode
379	mov %gs:(%si), %cx	377	mov %gs:(%si), %cx
380	cmp $VESA_END_OF_MODES, %cx	378	cmp $VESA_END_OF_MODES, %cx
381	jz 0f	379	jz 0f
382		380
383	inc %si	381	inc %si
384	inc %si	382	inc %si
385	push %cx	383	push %cx
386	push %di	384	push %di
387	push %si	385	push %si
388	mov $VESA_GET_MODE_INFO, %ax	386	mov $VESA_GET_MODE_INFO, %ax
389	int $0x10	387	int $0x10
390		388
391	pop %si	389	pop %si
392	pop %di	390	pop %di
393	pop %cx	391	pop %cx
394	cmp $VESA_OK, %al	392	cmp $VESA_OK, %al
395	jnz 0f	393	jnz 0f
396		394
397	mov $CONFIG_VESA_WIDTH, %ax	395	mov $CONFIG_VESA_WIDTH, %ax
398	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax	396	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
399	jnz 1b	397	jnz 1b
400		398
401	mov $CONFIG_VESA_HEIGHT, %ax	399	mov $CONFIG_VESA_HEIGHT, %ax
402	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax	400	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
403	jnz 1b	401	jnz 1b
404		402
405	mov $CONFIG_VESA_BPP, %al	403	mov $CONFIG_VESA_BPP, %al
406	cmp VESA_MODE_BPP_OFFSET(%di), %al	404	cmp VESA_MODE_BPP_OFFSET(%di), %al
407		405
408	#ifdef CONFIG_VESA_BPP_VARIANT	406	#ifdef CONFIG_VESA_BPP_VARIANT
409	jz 2f	407	jz 2f
410		408
411	mov $CONFIG_VESA_BPP_VARIANT, %al	409	mov $CONFIG_VESA_BPP_VARIANT, %al
412	cmp VESA_MODE_BPP_OFFSET(%di), %al	410	cmp VESA_MODE_BPP_OFFSET(%di), %al
413	#endif	411	#endif
414	jnz 1b	412	jnz 1b
415		413
416	2:	414	2:
417		415
418	mov %cx, %bx	416	mov %cx, %bx
419	or $0xc000, %bx	417	or $0xc000, %bx
420	push %di	418	push %di
421	mov $VESA_SET_MODE, %ax	419	mov $VESA_SET_MODE, %ax
422	int $0x10	420	int $0x10
423		421
424	pop %di	422	pop %di
425	cmp $VESA_OK, %al	423	cmp $VESA_OK, %al
426	jnz 0f	424	jnz 0f
427		425
428	#if CONFIG_VESA_BPP == 8	426	#if CONFIG_VESA_BPP == 8
429		427
430	# Set 3:2:3 VGA palette	428	# Set 3:2:3 VGA palette
431		429
432	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax	430	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax
433	push %di	431	push %di
434	mov $vga323 - vesa_init, %di	432	mov $vga323 - vesa_init, %di
435	mov $0x100, %ecx	433	mov $0x100, %ecx
436		434
437	bt $5, %ax # Test if VGA compatible registers are present	435	bt $5, %ax # Test if VGA compatible registers are present
438	jnc vga_compat	436	jnc vga_compat
439		437
440	# Try VESA routine to set palette	438	# Try VESA routine to set palette
441		439
442	mov $VESA_SET_PALETTE, %ax	440	mov $VESA_SET_PALETTE, %ax
443	xor %bl, %bl	441	xor %bl, %bl
444	xor %dx, %dx	442	xor %dx, %dx
445	int $0x10	443	int $0x10
446		444
447	jmp vga_not_compat	445	jmp vga_not_compat
448		446
449	vga_compat:	447	vga_compat:
450		448
451	# Try VGA registers to set palette	449	# Try VGA registers to set palette
452		450
453	movw $0x3c6, %dx # Set palette mask	451	movw $0x3c6, %dx # Set palette mask
454	movb $0xff, %al	452	movb $0xff, %al
455	outb %al, %dx	453	outb %al, %dx
456		454
457	movw $0x3c8, %dx # First index to set	455	movw $0x3c8, %dx # First index to set
458	xor %al, %al	456	xor %al, %al
459	outb %al, %dx	457	outb %al, %dx
460		458
461	movw $0x3c9, %dx # Data port	459	movw $0x3c9, %dx # Data port
462	vga_loop:	460	vga_loop:
463	movb %es:2(%di), %al	461	movb %es:2(%di), %al
464	outb %al, %dx	462	outb %al, %dx
465		463
466	movb %es:1(%di), %al	464	movb %es:1(%di), %al
467	outb %al, %dx	465	outb %al, %dx
468		466
469	movb %es:(%di), %al	467	movb %es:(%di), %al
470	outb %al, %dx	468	outb %al, %dx
471		469
472	addw $4, %di	470	addw $4, %di
473	loop vga_loop	471	loop vga_loop
474		472
475	vga_not_compat:	473	vga_not_compat:
476		474
477	pop %di	475	pop %di
478		476
479	#endif	477	#endif
480		478
481	mov VESA_MODE_PHADDR_OFFSET(%di), %esi	479	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
482	mov VESA_MODE_WIDTH_OFFSET(%di), %ax	480	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
483	shl $16, %eax	481	shl $16, %eax
484	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax	482	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
485	mov VESA_MODE_BPP_OFFSET(%di), %bl	483	mov VESA_MODE_BPP_OFFSET(%di), %bl
486	xor %bh, %bh	484	xor %bh, %bh
487	shl $16, %ebx	485	shl $16, %ebx
488	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx	486	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
489	mov %eax, %edi	487	mov %eax, %edi
490		488
491	8:	489	8:
492		490
493	mov %cr0, %eax	491	mov %cr0, %eax
494	or $1, %eax	492	or $1, %eax
495	mov %eax, %cr0	493	mov %eax, %cr0
496		494
497	jmp 9f	495	jmp 9f
498	9:	496	9:
499		497

Subversion Repositories HelenOS

(root)/trunk/kernel/arch/ia32/src/boot/boot.S @ 4346 – Rev 2725 → 2784