WebSVN – HelenOS – Diff – /trunk/kernel/arch/ia32/src/boot/boot.S


#
# Copyright (c) 2001-2004 Jakub Jermar
# Copyright (c) 2005-2006 Martin Decky
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
#
# - Redistributions of source code must retain the above copyright
#   notice, this list of conditions and the following disclaimer.
# - Redistributions in binary form must reproduce the above copyright
#   notice, this list of conditions and the following disclaimer in the
#   documentation and/or other materials provided with the distribution.
# - The name of the author may not be used to endorse or promote products
#   derived from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
#
 
#include <arch/boot/boot.h>
#include <arch/boot/memmap.h>
#include <arch/mm/page.h>
#include <arch/pm.h>
 
#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
 
.section K_TEXT_START, "ax"
 
.code32
.align 4
.global multiboot_image_start
multiboot_header:
	.long MULTIBOOT_HEADER_MAGIC
	.long MULTIBOOT_HEADER_FLAGS
	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS)	# checksum
	.long multiboot_header
	.long unmapped_ktext_start
	.long 0
	.long 0
	.long multiboot_image_start
	
multiboot_image_start:
	movl $START_STACK, %esp			# initialize stack pointer
	lgdt KA2PA(bootstrap_gdtr)		# initialize Global Descriptor Table register
 
	movw $selector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %fs
	movw %cx, %gs
	movw %cx, %ds					# kernel data + stack
	movw %cx, %ss
	
	jmpl $selector(KTEXT_DES), $multiboot_meeting_point
	multiboot_meeting_point:
	
	movl %eax, grub_eax					# save parameters from GRUB
	movl %ebx, grub_ebx
	
	xorl %eax, %eax  
 	cpuid
 	cmp $0x0, %eax						# any function > 0?
	jbe pse_unsupported
	movl $0x1, %eax						# Basic function code 1
	cpuid
	bt $3, %edx							# Test if PSE is supported
	jc pse_supported
 
	pse_unsupported:
		movl $pse_msg, %esi
		jmp error_halt
	
	pse_supported:
	
#ifdef CONFIG_FB
	mov $vesa_init, %esi
	mov $VESA_INIT_SEGMENT << 4, %edi
	mov $e_vesa_init - vesa_init, %ecx
	cld
	rep movsb
 
	mov $VESA_INIT_SEGMENT << 4, %edi
	jmpl *%edi
	
	vesa_meeting_point:
	
	mov %esi, KA2PA(vesa_ph_addr)
	mov %di, KA2PA(vesa_height)
	shr $16, %edi
	mov %di, KA2PA(vesa_width)
	mov %bx, KA2PA(vesa_scanline)
	shr $16, %ebx
	mov %bx, KA2PA(vesa_bpp)
#endif	
	
	call map_kernel							# map kernel and turn paging on
	
	movl grub_eax, %eax
	movl grub_ebx, %ebx
	cmpl $MULTIBOOT_LOADER_MAGIC, %eax				# compare GRUB signature
	je valid_boot
		
		xorl %ecx, %ecx							# no memory size or map available
		movl %ecx, e801memorysize
		movl %ecx, e820counter
		
		jmp invalid_boot
		
	valid_boot:
		
		movl (%ebx), %eax						# ebx = physical address of struct multiboot_info
		
		bt $0, %eax								# mbi->flags[0] (mem_lower, mem_upper valid)
		jc mem_valid
			
			xorl %ecx, %ecx
			jmp mem_invalid
			
		mem_valid:
		movl 4(%ebx), %ecx						# mbi->mem_lower
		addl 8(%ebx), %ecx						# mbi->mem_upper
		
		mem_invalid:
		movl %ecx, e801memorysize
		
		bt $3, %eax								# mbi->flags[3] (mods_count, mods_addr valid)
		jc mods_valid
			
			xorl %ecx, %ecx
			movl %ecx, init
			jmp mods_end
		
		mods_valid:
		
		movl 20(%ebx), %ecx						# mbi->mods_count
		movl %ecx, init
		
		cmpl $0, %ecx
		je mods_end
		
		movl 24(%ebx), %esi						# mbi->mods_addr
		movl $init, %edi
		
		mods_loop:
		
			movl 0(%esi), %edx					# mods->mod_start
			addl $0x80000000, %edx
			movl %edx, 4(%edi)
			
			movl 4(%esi), %edx
			subl 0(%esi), %edx					# mods->mod_end - mods->mod_start
			movl %edx, 8(%edi)
			
			addl $16, %esi
			addl $8	, %edi
			
			loop mods_loop
			
		mods_end:
		
		bt $6, %eax								# mbi->flags[6] (mmap_length, mmap_addr valid)	
		jc mmap_valid
			
			xorl %edx, %edx
			jmp mmap_invalid
			
		mmap_valid:
		movl 44(%ebx), %ecx						# mbi->mmap_length
		movl 48(%ebx), %esi						# mbi->mmap_addr
		movl $e820table, %edi
		xorl %edx, %edx
		
		mmap_loop:
			cmpl $0, %ecx
			jle mmap_end
			
			movl 4(%esi), %eax					# mmap->base_addr_low
			movl %eax, (%edi)
			
			movl 8(%esi), %eax					# mmap->base_addr_high
			movl %eax, 4(%edi)
			
			movl 12(%esi), %eax					# mmap->length_low
			movl %eax, 8(%edi)
			
			movl 16(%esi), %eax					# mmap->length_high
			movl %eax, 12(%edi)
			
			movl 20(%esi), %eax					# mmap->type
			movl %eax, 16(%edi)
			
			movl (%esi), %eax					# mmap->size
			addl $0x4, %eax
			addl %eax, %esi
			subl %eax, %ecx
			addl $MEMMAP_E820_RECORD_SIZE, %edi
			incl %edx
			jmp mmap_loop
		
		mmap_end:
		
		mmap_invalid:
		movl %edx, e820counter
		
	invalid_boot:
	
#ifdef CONFIG_SMP
	
	# copy AP bootstrap routines below 1 MB
	
	movl $BOOT_OFFSET, %esi
	movl $AP_BOOT_OFFSET, %edi
	movl $_hardcoded_unmapped_size, %ecx
	cld
	rep movsb
	
#endif
 
	call main_bsp								# never returns
 
	cli
	hlt
 
.global map_kernel
map_kernel:
	#
	# Here we setup mapping for both the unmapped and mapped sections of the kernel.
	# For simplicity, we map the entire 4G space.
	#
	movl %cr4, %ecx
	orl $(1 << 4), %ecx							# turn PSE on
	andl $(~(1 << 5)), %ecx						# turn PAE off
	movl %ecx, %cr4
	
	movl $(page_directory + 0), %esi
	movl $(page_directory + 2048), %edi
	xorl %ecx, %ecx
	xorl %ebx, %ebx
0:
	movl $((1 << 7) | (1 << 1) | (1 << 0)), %eax
	orl %ebx, %eax
	movl %eax, (%esi, %ecx, 4)					# mapping 0x00000000 + %ecx * 4M => 0x00000000 + %ecx * 4M
	movl %eax, (%edi, %ecx, 4)					# mapping 0x80000000 + %ecx * 4M => 0x00000000 + %ecx * 4M
	addl $(4 * 1024 * 1024), %ebx
 
	incl %ecx
	cmpl $512, %ecx
	jl 0b
 
	movl %esi, %cr3
	
	movl %cr0, %ebx
	orl $(1 << 31), %ebx						# turn paging on
	movl %ebx, %cr0
	ret
 
# Print string from %esi to EGA display (in red) and halt
error_halt:
	movl $0xb8000, %edi						# base of EGA text mode memory
	xorl %eax, %eax
	
	movw $0x3d4, %dx						# read bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	shl $8, %ax
	
	movw $0x3d4, %dx						# read bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	
	cmp $1920, %ax
	jbe cursor_ok
		movw $1920, %ax						# sanity check for the cursor on the last line
	cursor_ok:
	
	movw %ax, %bx
	shl $1, %eax
	addl %eax, %edi
	
	movw $0x0c00, %ax						# black background, light red foreground
	cld
	
	ploop:
		lodsb
		cmp $0, %al
		je ploop_end
		stosw
		inc %bx	
		jmp ploop
	ploop_end:
	
	movw $0x3d4, %dx						# write bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bh, %al
	outb %al, %dx
	
	movw $0x3d4, %dx						# write bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bl, %al
	outb %al, %dx
		
	cli
	hlt
 
#ifdef CONFIG_FB
vesa_init:
	jmp $selector(VESA_INIT_DES), $vesa_init_real - vesa_init
	
.code16
vesa_init_real:
	
	mov %cr0, %eax
	and $~1, %eax
	mov %eax, %cr0
	
	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
	
vesa_init_real2:
	
	mov $VESA_INIT_SEGMENT, %bx
	
	mov %bx, %es
	mov %bx, %fs
	mov %bx, %gs
	mov %bx, %ds
	mov %bx, %ss
	
	movl %esp, %eax
	movl $0x0000fffc, %esp
	movl $0x0000fffc, %ebp
	pushl %eax
	
#define VESA_INFO_SIZE 1024
 
#define VESA_MODE_LIST_PTR_OFFSET 14
#define VESA_MODE_WIDTH_OFFSET 18
#define VESA_MODE_HEIGHT_OFFSET 20
#define VESA_MODE_BPP_OFFSET 25
#define VESA_MODE_SCANLINE_OFFSET 16
#define VESA_MODE_PHADDR_OFFSET 40
 
#define VESA_END_OF_MODES 0xffff
 
#define VESA_OK 0x4f
 
#define VESA_GET_INFO 0x4f00
#define VESA_GET_MODE_INFO 0x4f01
#define VESA_SET_MODE 0x4f02
 
#define CONFIG_VESA_BPP_a 255
 
#if CONFIG_VESA_BPP == 24
#undef CONFIG_VESA_BPP_a
#define CONFIG_VESA_BPP_a 32
#endif
 
	mov $VESA_GET_INFO, %ax
	mov $e_vesa_init - vesa_init, %di
	push %di
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
	
	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
	mov %si, %gs
	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
	
	add $VESA_INFO_SIZE, %di
 
1:# Try next mode
	mov %gs:(%si), %cx
	cmp $VESA_END_OF_MODES, %cx
	jz 0f
	
	inc %si
	inc %si
	push %cx
	push %di
	push %si
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %si
	pop %di
	pop %cx
	cmp $VESA_OK, %al
	jnz 0f
	
	mov $CONFIG_VESA_WIDTH, %ax
	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_HEIGHT,%ax
	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_BPP, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
	jz 2f
	
	mov $CONFIG_VESA_BPP_a, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
	jnz 1b
	
2:
	
	mov %cx, %bx
	or $0xc000, %bx
	push %di
	mov $VESA_SET_MODE, %ax
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
	
	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
	shl $16, %eax
	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
	mov VESA_MODE_BPP_OFFSET(%di), %bl
	xor %bh, %bh
	shl $16, %ebx
	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
	mov %eax, %edi
	
8:	
	
	mov %cr0, %eax
	or $1, %eax
	mov %eax, %cr0
	
	jmp 9f
9:
	
	ljmpl $selector(KTEXT_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
 
0:# No prefered mode found
	mov $0x111, %cx
	push %di
	push %cx
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %cx
	pop %di
	cmp $VESA_OK, %al
	jnz 1f
	jz 2b						# Force relative jump
	
1:
	mov $0x0003, %ax
	int $0x10
	mov $0xffffffff, %edi		# EGA text mode used, because of problems with VESA
	xor %ax, %ax
	jz 8b						# Force relative jump
	
 
.code32
vesa_init_protect:
 
 
	movw $selector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %fs
	movw %cx, %gs
	movw %cx, %ds					# kernel data + stack
	movw %cx, %ss
	
	movl $START_STACK, %esp			# initialize stack pointer
 
	jmpl $selector(KTEXT_DES), $vesa_meeting_point
 
.align 4
e_vesa_init:
#endif	
 
.section K_DATA_START, "aw", @progbits
 
.align 4096
page_directory:
	.space 4096, 0
 
grub_eax:
	.long 0
 
grub_ebx:
	.long 0
 
pse_msg:
	.ascii "Page Size Extension not supported. System halted.\0"
 

Rev 2221	Rev 2222
1	#	1	#
2	# Copyright (c) 2001-2004 Jakub Jermar	2	# Copyright (c) 2001-2004 Jakub Jermar
3	# Copyright (c) 2005-2006 Martin Decky	3	# Copyright (c) 2005-2006 Martin Decky
4	# All rights reserved.	4	# All rights reserved.
5	#	5	#
6	# Redistribution and use in source and binary forms, with or without	6	# Redistribution and use in source and binary forms, with or without
7	# modification, are permitted provided that the following conditions	7	# modification, are permitted provided that the following conditions
8	# are met:	8	# are met:
9	#	9	#
10	# - Redistributions of source code must retain the above copyright	10	# - Redistributions of source code must retain the above copyright
11	# notice, this list of conditions and the following disclaimer.	11	# notice, this list of conditions and the following disclaimer.
12	# - Redistributions in binary form must reproduce the above copyright	12	# - Redistributions in binary form must reproduce the above copyright
13	# notice, this list of conditions and the following disclaimer in the	13	# notice, this list of conditions and the following disclaimer in the
14	# documentation and/or other materials provided with the distribution.	14	# documentation and/or other materials provided with the distribution.
15	# - The name of the author may not be used to endorse or promote products	15	# - The name of the author may not be used to endorse or promote products
16	# derived from this software without specific prior written permission.	16	# derived from this software without specific prior written permission.
17	#	17	#
18	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR	18	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
19	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES	19	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
20	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.	20	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
21	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,	21	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
22	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT	22	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
23	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,	23	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY	24	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT	25	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF	26	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
27	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.	27	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28	#	28	#
29		29
30	#include <arch/boot/boot.h>	30	#include <arch/boot/boot.h>
31	#include <arch/boot/memmap.h>	31	#include <arch/boot/memmap.h>
32	#include <arch/mm/page.h>	32	#include <arch/mm/page.h>
33	#include <arch/pm.h>	33	#include <arch/pm.h>
34		34
35	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)	35	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
36		36
37	.section K_TEXT_START, "ax"	37	.section K_TEXT_START, "ax"
38		38
39	.code32	39	.code32
40	.align 4	40	.align 4
41	.global multiboot_image_start	41	.global multiboot_image_start
42	multiboot_header:	42	multiboot_header:
43	.long MULTIBOOT_HEADER_MAGIC	43	.long MULTIBOOT_HEADER_MAGIC
44	.long MULTIBOOT_HEADER_FLAGS	44	.long MULTIBOOT_HEADER_FLAGS
45	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum	45	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum
46	.long multiboot_header	46	.long multiboot_header
47	.long unmapped_ktext_start	47	.long unmapped_ktext_start
48	.long 0	48	.long 0
49	.long 0	49	.long 0
50	.long multiboot_image_start	50	.long multiboot_image_start
51		51
52	multiboot_image_start:	52	multiboot_image_start:
53	movl $START_STACK, %esp # initialize stack pointer	53	movl $START_STACK, %esp # initialize stack pointer
54	lgdt KA2PA(bootstrap_gdtr) # initialize Global Descriptor Table register	54	lgdt KA2PA(bootstrap_gdtr) # initialize Global Descriptor Table register
55		55
56	movw $selector(KDATA_DES), %cx	56	movw $selector(KDATA_DES), %cx
57	movw %cx, %es	57	movw %cx, %es
58	movw %cx, %fs	58	movw %cx, %fs
59	movw %cx, %gs	59	movw %cx, %gs
60	movw %cx, %ds # kernel data + stack	60	movw %cx, %ds # kernel data + stack
61	movw %cx, %ss	61	movw %cx, %ss
62		62
63	jmpl $selector(KTEXT_DES), $multiboot_meeting_point	63	jmpl $selector(KTEXT_DES), $multiboot_meeting_point
64	multiboot_meeting_point:	64	multiboot_meeting_point:
65		65
66	pushl %ebx # save parameters from GRUB	66	movl %eax, grub_eax # save parameters from GRUB
67	pushl %eax	67	movl %ebx, grub_ebx
68		68
69	xorl %eax, %eax	69	xorl %eax, %eax
70	cpuid	70	cpuid
71	cmp $0x0, %eax # any function > 0?	71	cmp $0x0, %eax # any function > 0?
72	jbe pse_unsupported	72	jbe pse_unsupported
73	movl $0x1, %eax # Basic function code 1	73	movl $0x1, %eax # Basic function code 1
74	cpuid	74	cpuid
75	bt $3, %edx # Test if PSE is supported	75	bt $3, %edx # Test if PSE is supported
76	jc pse_supported	76	jc pse_supported
77		77
78	pse_unsupported:	78	pse_unsupported:
79	movl $pse_msg, %esi	79	movl $pse_msg, %esi
80	jmp error_halt	80	jmp error_halt
81		81
82	pse_supported:	82	pse_supported:
83		83
84	#ifdef CONFIG_FB	84	#ifdef CONFIG_FB
85	mov $vesa_init, %esi	85	mov $vesa_init, %esi
86	mov $VESA_INIT_SEGMENT << 4, %edi	86	mov $VESA_INIT_SEGMENT << 4, %edi
87	mov $e_vesa_init - vesa_init, %ecx	87	mov $e_vesa_init - vesa_init, %ecx
88	cld	88	cld
89	rep movsb	89	rep movsb
90		90
91	mov $VESA_INIT_SEGMENT << 4, %edi	91	mov $VESA_INIT_SEGMENT << 4, %edi
92	jmpl *%edi	92	jmpl *%edi
93		93
94	vesa_meeting_point:	94	vesa_meeting_point:
95		95
96	mov %esi, KA2PA(vesa_ph_addr)	96	mov %esi, KA2PA(vesa_ph_addr)
97	mov %di, KA2PA(vesa_height)	97	mov %di, KA2PA(vesa_height)
98	shr $16, %edi	98	shr $16, %edi
99	mov %di, KA2PA(vesa_width)	99	mov %di, KA2PA(vesa_width)
100	mov %bx, KA2PA(vesa_scanline)	100	mov %bx, KA2PA(vesa_scanline)
101	shr $16, %ebx	101	shr $16, %ebx
102	mov %bx, KA2PA(vesa_bpp)	102	mov %bx, KA2PA(vesa_bpp)
103	#endif	103	#endif
104		104
105	call map_kernel # map kernel and turn paging on	105	call map_kernel # map kernel and turn paging on
106		106
107	popl %eax	107	movl grub_eax, %eax
108	popl %ebx	108	movl grub_ebx, %ebx
109	cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature	109	cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature
110	je valid_boot	110	je valid_boot
111		111
112	xorl %ecx, %ecx # no memory size or map available	112	xorl %ecx, %ecx # no memory size or map available
113	movl %ecx, e801memorysize	113	movl %ecx, e801memorysize
114	movl %ecx, e820counter	114	movl %ecx, e820counter
115		115
116	jmp invalid_boot	116	jmp invalid_boot
117		117
118	valid_boot:	118	valid_boot:
119		119
120	movl (%ebx), %eax # ebx = physical address of struct multiboot_info	120	movl (%ebx), %eax # ebx = physical address of struct multiboot_info
121		121
122	bt $0, %eax # mbi->flags[0] (mem_lower, mem_upper valid)	122	bt $0, %eax # mbi->flags[0] (mem_lower, mem_upper valid)
123	jc mem_valid	123	jc mem_valid
124		124
125	xorl %ecx, %ecx	125	xorl %ecx, %ecx
126	jmp mem_invalid	126	jmp mem_invalid
127		127
128	mem_valid:	128	mem_valid:
129	movl 4(%ebx), %ecx # mbi->mem_lower	129	movl 4(%ebx), %ecx # mbi->mem_lower
130	addl 8(%ebx), %ecx # mbi->mem_upper	130	addl 8(%ebx), %ecx # mbi->mem_upper
131		131
132	mem_invalid:	132	mem_invalid:
133	movl %ecx, e801memorysize	133	movl %ecx, e801memorysize
134		134
135	bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)	135	bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)
136	jc mods_valid	136	jc mods_valid
137		137
138	xorl %ecx, %ecx	138	xorl %ecx, %ecx
139	movl %ecx, init	139	movl %ecx, init
140	jmp mods_end	140	jmp mods_end
141		141
142	mods_valid:	142	mods_valid:
143		143
144	movl 20(%ebx), %ecx # mbi->mods_count	144	movl 20(%ebx), %ecx # mbi->mods_count
145	movl %ecx, init	145	movl %ecx, init
146		146
147	cmpl $0, %ecx	147	cmpl $0, %ecx
148	je mods_end	148	je mods_end
149		149
150	movl 24(%ebx), %esi # mbi->mods_addr	150	movl 24(%ebx), %esi # mbi->mods_addr
151	movl $init, %edi	151	movl $init, %edi
152		152
153	mods_loop:	153	mods_loop:
154		154
155	movl 0(%esi), %edx # mods->mod_start	155	movl 0(%esi), %edx # mods->mod_start
156	addl $0x80000000, %edx	156	addl $0x80000000, %edx
157	movl %edx, 4(%edi)	157	movl %edx, 4(%edi)
158		158
159	movl 4(%esi), %edx	159	movl 4(%esi), %edx
160	subl 0(%esi), %edx # mods->mod_end - mods->mod_start	160	subl 0(%esi), %edx # mods->mod_end - mods->mod_start
161	movl %edx, 8(%edi)	161	movl %edx, 8(%edi)
162		162
163	addl $16, %esi	163	addl $16, %esi
164	addl $8 , %edi	164	addl $8 , %edi
165		165
166	loop mods_loop	166	loop mods_loop
167		167
168	mods_end:	168	mods_end:
169		169
170	bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)	170	bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)
171	jc mmap_valid	171	jc mmap_valid
172		172
173	xorl %edx, %edx	173	xorl %edx, %edx
174	jmp mmap_invalid	174	jmp mmap_invalid
175		175
176	mmap_valid:	176	mmap_valid:
177	movl 44(%ebx), %ecx # mbi->mmap_length	177	movl 44(%ebx), %ecx # mbi->mmap_length
178	movl 48(%ebx), %esi # mbi->mmap_addr	178	movl 48(%ebx), %esi # mbi->mmap_addr
179	movl $e820table, %edi	179	movl $e820table, %edi
180	xorl %edx, %edx	180	xorl %edx, %edx
181		181
182	mmap_loop:	182	mmap_loop:
183	cmpl $0, %ecx	183	cmpl $0, %ecx
184	jle mmap_end	184	jle mmap_end
185		185
186	movl 4(%esi), %eax # mmap->base_addr_low	186	movl 4(%esi), %eax # mmap->base_addr_low
187	movl %eax, (%edi)	187	movl %eax, (%edi)
188		188
189	movl 8(%esi), %eax # mmap->base_addr_high	189	movl 8(%esi), %eax # mmap->base_addr_high
190	movl %eax, 4(%edi)	190	movl %eax, 4(%edi)
191		191
192	movl 12(%esi), %eax # mmap->length_low	192	movl 12(%esi), %eax # mmap->length_low
193	movl %eax, 8(%edi)	193	movl %eax, 8(%edi)
194		194
195	movl 16(%esi), %eax # mmap->length_high	195	movl 16(%esi), %eax # mmap->length_high
196	movl %eax, 12(%edi)	196	movl %eax, 12(%edi)
197		197
198	movl 20(%esi), %eax # mmap->type	198	movl 20(%esi), %eax # mmap->type
199	movl %eax, 16(%edi)	199	movl %eax, 16(%edi)
200		200
201	movl (%esi), %eax # mmap->size	201	movl (%esi), %eax # mmap->size
202	addl $0x4, %eax	202	addl $0x4, %eax
203	addl %eax, %esi	203	addl %eax, %esi
204	subl %eax, %ecx	204	subl %eax, %ecx
205	addl $MEMMAP_E820_RECORD_SIZE, %edi	205	addl $MEMMAP_E820_RECORD_SIZE, %edi
206	incl %edx	206	incl %edx
207	jmp mmap_loop	207	jmp mmap_loop
208		208
209	mmap_end:	209	mmap_end:
210		210
211	mmap_invalid:	211	mmap_invalid:
212	movl %edx, e820counter	212	movl %edx, e820counter
213		213
214	invalid_boot:	214	invalid_boot:
215		215
216	#ifdef CONFIG_SMP	216	#ifdef CONFIG_SMP
217		217
218	# copy AP bootstrap routines below 1 MB	218	# copy AP bootstrap routines below 1 MB
219		219
220	movl $BOOT_OFFSET, %esi	220	movl $BOOT_OFFSET, %esi
221	movl $AP_BOOT_OFFSET, %edi	221	movl $AP_BOOT_OFFSET, %edi
222	movl $_hardcoded_unmapped_size, %ecx	222	movl $_hardcoded_unmapped_size, %ecx
223	cld	223	cld
224	rep movsb	224	rep movsb
225		225
226	#endif	226	#endif
227		227
228	call main_bsp # never returns	228	call main_bsp # never returns
229		229
230	cli	230	cli
231	hlt	231	hlt
232		232
233	.global map_kernel	233	.global map_kernel
234	map_kernel:	234	map_kernel:
235	#	235	#
236	# Here we setup mapping for both the unmapped and mapped sections of the kernel.	236	# Here we setup mapping for both the unmapped and mapped sections of the kernel.
237	# For simplicity, we map the entire 4G space.	237	# For simplicity, we map the entire 4G space.
238	#	238	#
239	movl %cr4, %ecx	239	movl %cr4, %ecx
240	orl $(1 << 4), %ecx # turn PSE on	240	orl $(1 << 4), %ecx # turn PSE on
241	andl $(~(1 << 5)), %ecx # turn PAE off	241	andl $(~(1 << 5)), %ecx # turn PAE off
242	movl %ecx, %cr4	242	movl %ecx, %cr4
243		243
244	movl $(page_directory + 0), %esi	244	movl $(page_directory + 0), %esi
245	movl $(page_directory + 2048), %edi	245	movl $(page_directory + 2048), %edi
246	xorl %ecx, %ecx	246	xorl %ecx, %ecx
247	xorl %ebx, %ebx	247	xorl %ebx, %ebx
248	0:	248	0:
249	movl $((1 << 7) \| (1 << 1) \| (1 << 0)), %eax	249	movl $((1 << 7) \| (1 << 1) \| (1 << 0)), %eax
250	orl %ebx, %eax	250	orl %ebx, %eax
251	movl %eax, (%esi, %ecx, 4) # mapping 0x00000000 + %ecx * 4M => 0x00000000 + %ecx * 4M	251	movl %eax, (%esi, %ecx, 4) # mapping 0x00000000 + %ecx * 4M => 0x00000000 + %ecx * 4M
252	movl %eax, (%edi, %ecx, 4) # mapping 0x80000000 + %ecx * 4M => 0x00000000 + %ecx * 4M	252	movl %eax, (%edi, %ecx, 4) # mapping 0x80000000 + %ecx * 4M => 0x00000000 + %ecx * 4M
253	addl $(4 * 1024 * 1024), %ebx	253	addl $(4 * 1024 * 1024), %ebx
254		254
255	incl %ecx	255	incl %ecx
256	cmpl $512, %ecx	256	cmpl $512, %ecx
257	jl 0b	257	jl 0b
258		258
259	movl %esi, %cr3	259	movl %esi, %cr3
260		260
261	movl %cr0, %ebx	261	movl %cr0, %ebx
262	orl $(1 << 31), %ebx # turn paging on	262	orl $(1 << 31), %ebx # turn paging on
263	movl %ebx, %cr0	263	movl %ebx, %cr0
264	ret	264	ret
265		265
266	# Print string from %esi to EGA display (in red) and halt	266	# Print string from %esi to EGA display (in red) and halt
267	error_halt:	267	error_halt:
268	movl $0xb8000, %edi # base of EGA text mode memory	268	movl $0xb8000, %edi # base of EGA text mode memory
269	xorl %eax, %eax	269	xorl %eax, %eax
270		270
271	movw $0x3d4, %dx # read bits 8 - 15 of the cursor address	271	movw $0x3d4, %dx # read bits 8 - 15 of the cursor address
272	movb $0xe, %al	272	movb $0xe, %al
273	outb %al, %dx	273	outb %al, %dx
274		274
275	movw $0x3d5, %dx	275	movw $0x3d5, %dx
276	inb %dx, %al	276	inb %dx, %al
277	shl $8, %ax	277	shl $8, %ax
278		278
279	movw $0x3d4, %dx # read bits 0 - 7 of the cursor address	279	movw $0x3d4, %dx # read bits 0 - 7 of the cursor address
280	movb $0xf, %al	280	movb $0xf, %al
281	outb %al, %dx	281	outb %al, %dx
282		282
283	movw $0x3d5, %dx	283	movw $0x3d5, %dx
284	inb %dx, %al	284	inb %dx, %al
285		285
286	cmp $1920, %ax	286	cmp $1920, %ax
287	jbe cursor_ok	287	jbe cursor_ok
288	movw $1920, %ax # sanity check for the cursor on the last line	288	movw $1920, %ax # sanity check for the cursor on the last line
289	cursor_ok:	289	cursor_ok:
290		290
291	movw %ax, %bx	291	movw %ax, %bx
292	shl $1, %eax	292	shl $1, %eax
293	addl %eax, %edi	293	addl %eax, %edi
294		294
295	movw $0x0c00, %ax # black background, light red foreground	295	movw $0x0c00, %ax # black background, light red foreground
296	cld	296	cld
297		297
298	ploop:	298	ploop:
299	lodsb	299	lodsb
300	cmp $0, %al	300	cmp $0, %al
301	je ploop_end	301	je ploop_end
302	stosw	302	stosw
303	inc %bx	303	inc %bx
304	jmp ploop	304	jmp ploop
305	ploop_end:	305	ploop_end:
306		306
307	movw $0x3d4, %dx # write bits 8 - 15 of the cursor address	307	movw $0x3d4, %dx # write bits 8 - 15 of the cursor address
308	movb $0xe, %al	308	movb $0xe, %al
309	outb %al, %dx	309	outb %al, %dx
310		310
311	movw $0x3d5, %dx	311	movw $0x3d5, %dx
312	movb %bh, %al	312	movb %bh, %al
313	outb %al, %dx	313	outb %al, %dx
314		314
315	movw $0x3d4, %dx # write bits 0 - 7 of the cursor address	315	movw $0x3d4, %dx # write bits 0 - 7 of the cursor address
316	movb $0xf, %al	316	movb $0xf, %al
317	outb %al, %dx	317	outb %al, %dx
318		318
319	movw $0x3d5, %dx	319	movw $0x3d5, %dx
320	movb %bl, %al	320	movb %bl, %al
321	outb %al, %dx	321	outb %al, %dx
322		322
323	cli	323	cli
324	hlt	324	hlt
325		325
326	#ifdef CONFIG_FB	326	#ifdef CONFIG_FB
327	vesa_init:	327	vesa_init:
328	jmp $selector(VESA_INIT_DES), $vesa_init_real - vesa_init	328	jmp $selector(VESA_INIT_DES), $vesa_init_real - vesa_init
329		329
330	.code16	330	.code16
331	vesa_init_real:	331	vesa_init_real:
332		332
333	mov %cr0, %eax	333	mov %cr0, %eax
334	and $~1, %eax	334	and $~1, %eax
335	mov %eax, %cr0	335	mov %eax, %cr0
336		336
337	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init	337	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
338		338
339	vesa_init_real2:	339	vesa_init_real2:
340		340
341	mov $VESA_INIT_SEGMENT, %bx	341	mov $VESA_INIT_SEGMENT, %bx
342		342
343	mov %bx, %es	343	mov %bx, %es
344	mov %bx, %fs	344	mov %bx, %fs
345	mov %bx, %gs	345	mov %bx, %gs
346	mov %bx, %ds	346	mov %bx, %ds
347	mov %bx, %ss	347	mov %bx, %ss
348		348
349	movl %esp, %eax	349	movl %esp, %eax
350	movl $0x0000fffc, %esp	350	movl $0x0000fffc, %esp
351	movl $0x0000fffc, %ebp	351	movl $0x0000fffc, %ebp
352	pushl %eax	352	pushl %eax
353		353
354	#define VESA_INFO_SIZE 1024	354	#define VESA_INFO_SIZE 1024
355		355
356	#define VESA_MODE_LIST_PTR_OFFSET 14	356	#define VESA_MODE_LIST_PTR_OFFSET 14
357	#define VESA_MODE_WIDTH_OFFSET 18	357	#define VESA_MODE_WIDTH_OFFSET 18
358	#define VESA_MODE_HEIGHT_OFFSET 20	358	#define VESA_MODE_HEIGHT_OFFSET 20
359	#define VESA_MODE_BPP_OFFSET 25	359	#define VESA_MODE_BPP_OFFSET 25
360	#define VESA_MODE_SCANLINE_OFFSET 16	360	#define VESA_MODE_SCANLINE_OFFSET 16
361	#define VESA_MODE_PHADDR_OFFSET 40	361	#define VESA_MODE_PHADDR_OFFSET 40
362		362
363	#define VESA_END_OF_MODES 0xffff	363	#define VESA_END_OF_MODES 0xffff
364		364
365	#define VESA_OK 0x4f	365	#define VESA_OK 0x4f
366		366
367	#define VESA_GET_INFO 0x4f00	367	#define VESA_GET_INFO 0x4f00
368	#define VESA_GET_MODE_INFO 0x4f01	368	#define VESA_GET_MODE_INFO 0x4f01
369	#define VESA_SET_MODE 0x4f02	369	#define VESA_SET_MODE 0x4f02
370		370
371	#define CONFIG_VESA_BPP_a 255	371	#define CONFIG_VESA_BPP_a 255
372		372
373	#if CONFIG_VESA_BPP == 24	373	#if CONFIG_VESA_BPP == 24
374	#undef CONFIG_VESA_BPP_a	374	#undef CONFIG_VESA_BPP_a
375	#define CONFIG_VESA_BPP_a 32	375	#define CONFIG_VESA_BPP_a 32
376	#endif	376	#endif
377		377
378	mov $VESA_GET_INFO, %ax	378	mov $VESA_GET_INFO, %ax
379	mov $e_vesa_init - vesa_init, %di	379	mov $e_vesa_init - vesa_init, %di
380	push %di	380	push %di
381	int $0x10	381	int $0x10
382		382
383	pop %di	383	pop %di
384	cmp $VESA_OK, %al	384	cmp $VESA_OK, %al
385	jnz 0f	385	jnz 0f
386		386
387	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si	387	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
388	mov %si, %gs	388	mov %si, %gs
389	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si	389	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
390		390
391	add $VESA_INFO_SIZE, %di	391	add $VESA_INFO_SIZE, %di
392		392
393	1:# Try next mode	393	1:# Try next mode
394	mov %gs:(%si), %cx	394	mov %gs:(%si), %cx
395	cmp $VESA_END_OF_MODES, %cx	395	cmp $VESA_END_OF_MODES, %cx
396	jz 0f	396	jz 0f
397		397
398	inc %si	398	inc %si
399	inc %si	399	inc %si
400	push %cx	400	push %cx
401	push %di	401	push %di
402	push %si	402	push %si
403	mov $VESA_GET_MODE_INFO, %ax	403	mov $VESA_GET_MODE_INFO, %ax
404	int $0x10	404	int $0x10
405		405
406	pop %si	406	pop %si
407	pop %di	407	pop %di
408	pop %cx	408	pop %cx
409	cmp $VESA_OK, %al	409	cmp $VESA_OK, %al
410	jnz 0f	410	jnz 0f
411		411
412	mov $CONFIG_VESA_WIDTH, %ax	412	mov $CONFIG_VESA_WIDTH, %ax
413	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax	413	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
414	jnz 1b	414	jnz 1b
415		415
416	mov $CONFIG_VESA_HEIGHT,%ax	416	mov $CONFIG_VESA_HEIGHT,%ax
417	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax	417	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
418	jnz 1b	418	jnz 1b
419		419
420	mov $CONFIG_VESA_BPP, %al	420	mov $CONFIG_VESA_BPP, %al
421	cmp VESA_MODE_BPP_OFFSET(%di), %al	421	cmp VESA_MODE_BPP_OFFSET(%di), %al
422	jz 2f	422	jz 2f
423		423
424	mov $CONFIG_VESA_BPP_a, %al	424	mov $CONFIG_VESA_BPP_a, %al
425	cmp VESA_MODE_BPP_OFFSET(%di), %al	425	cmp VESA_MODE_BPP_OFFSET(%di), %al
426	jnz 1b	426	jnz 1b
427		427
428	2:	428	2:
429		429
430	mov %cx, %bx	430	mov %cx, %bx
431	or $0xc000, %bx	431	or $0xc000, %bx
432	push %di	432	push %di
433	mov $VESA_SET_MODE, %ax	433	mov $VESA_SET_MODE, %ax
434	int $0x10	434	int $0x10
435		435
436	pop %di	436	pop %di
437	cmp $VESA_OK, %al	437	cmp $VESA_OK, %al
438	jnz 0f	438	jnz 0f
439		439
440	mov VESA_MODE_PHADDR_OFFSET(%di), %esi	440	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
441	mov VESA_MODE_WIDTH_OFFSET(%di), %ax	441	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
442	shl $16, %eax	442	shl $16, %eax
443	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax	443	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
444	mov VESA_MODE_BPP_OFFSET(%di), %bl	444	mov VESA_MODE_BPP_OFFSET(%di), %bl
445	xor %bh, %bh	445	xor %bh, %bh
446	shl $16, %ebx	446	shl $16, %ebx
447	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx	447	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
448	mov %eax, %edi	448	mov %eax, %edi
449		449
450	8:	450	8:
451		451
452	mov %cr0, %eax	452	mov %cr0, %eax
453	or $1, %eax	453	or $1, %eax
454	mov %eax, %cr0	454	mov %eax, %cr0
455		455
456	jmp 9f	456	jmp 9f
457	9:	457	9:
458		458
459	ljmpl $selector(KTEXT_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)	459	ljmpl $selector(KTEXT_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
460		460
461	0:# No prefered mode found	461	0:# No prefered mode found
462	mov $0x111, %cx	462	mov $0x111, %cx
463	push %di	463	push %di
464	push %cx	464	push %cx
465	mov $VESA_GET_MODE_INFO, %ax	465	mov $VESA_GET_MODE_INFO, %ax
466	int $0x10	466	int $0x10
467		467
468	pop %cx	468	pop %cx
469	pop %di	469	pop %di
470	cmp $VESA_OK, %al	470	cmp $VESA_OK, %al
471	jnz 1f	471	jnz 1f
472	jz 2b # Force relative jump	472	jz 2b # Force relative jump
473		473
474	1:	474	1:
475	mov $0x0003, %ax	475	mov $0x0003, %ax
476	int $0x10	476	int $0x10
477	mov $0xffffffff, %edi # EGA text mode used, because of problems with VESA	477	mov $0xffffffff, %edi # EGA text mode used, because of problems with VESA
478	xor %ax, %ax	478	xor %ax, %ax
479	jz 8b # Force relative jump	479	jz 8b # Force relative jump
480		480
481		481
482	.code32	482	.code32
483	vesa_init_protect:	483	vesa_init_protect:
484	popl %esp	-
485		-
486	movw $selector(KDATA_DES), %cx	484	movw $selector(KDATA_DES), %cx
487	movw %cx, %es	485	movw %cx, %es
488	movw %cx, %fs	486	movw %cx, %fs
489	movw %cx, %gs	487	movw %cx, %gs
490	movw %cx, %ds # kernel data + stack	488	movw %cx, %ds # kernel data + stack
491	movw %cx, %ss	489	movw %cx, %ss
492		490
-		491	movl $START_STACK, %esp # initialize stack pointer
-		492
493	jmpl $selector(KTEXT_DES), $vesa_meeting_point	493	jmpl $selector(KTEXT_DES), $vesa_meeting_point
494		494
495	.align 4	495	.align 4
496	e_vesa_init:	496	e_vesa_init:
497	#endif	497	#endif
498		498

Subversion Repositories HelenOS

(root)/trunk/kernel/arch/ia32/src/boot/boot.S – Rev 2221 → 2222