WebSVN – HelenOS – Diff – /trunk/kernel/arch/amd64/src/boot/boot.S


 
# Copyright (c) 2005 Ondrej Palkovsky
# Copyright (c) 2006 Martin Decky
# Copyright (c) 2008 Jakub Jermar
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
#
# - Redistributions of source code must retain the above copyright
#   notice, this list of conditions and the following disclaimer.
# - Redistributions in binary form must reproduce the above copyright
#   notice, this list of conditions and the following disclaimer in the
#   documentation and/or other materials provided with the distribution.
# - The name of the author may not be used to endorse or promote products
#   derived from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
#
 
#include <arch/boot/boot.h>
#include <arch/boot/memmap.h>
#include <arch/mm/page.h>	
#include <arch/mm/ptl.h>
#include <arch/pm.h>
#include <arch/cpu.h>
#include <arch/cpuid.h>
 
#define START_STACK	(BOOT_OFFSET - BOOT_STACK_SIZE)
	
.section K_TEXT_START, "ax"
 
.code32
.align 4
.global multiboot_image_start
multiboot_header:
	.long MULTIBOOT_HEADER_MAGIC
	.long MULTIBOOT_HEADER_FLAGS
	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS)	# checksum
	.long multiboot_header
	.long unmapped_ktext_start
	.long 0
	.long 0
	.long multiboot_image_start
 
multiboot_image_start:
	cld
	movl $START_STACK, %esp			# initialize stack pointer
	lgdtl bootstrap_gdtr			# initialize Global Descriptor Table register
 
	movw $gdtselector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %ds							# kernel data + stack
	movw %cx, %ss
	# Simics seems to remove hidden part of GS on entering user mode
	#  when _visible_ part of GS does not point to user-mode segment
	movw $gdtselector(UDATA_DES), %cx
	movw %cx, %fs
	movw %cx, %gs
	
	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point
	multiboot_meeting_point:
	
	movl %eax, grub_eax						# save parameters from GRUB
	movl %ebx, grub_ebx
	
	# Protected 32-bit. We want to reuse the code-seg descriptor,
	# the Default operand size must not be 1 when entering long mode
	
	movl $(INTEL_CPUID_EXTENDED), %eax  
 	cpuid
 	cmp $(INTEL_CPUID_EXTENDED), %eax
	ja extended_cpuid_supported
		
		movl $extended_cpuid_msg, %esi
		jmp error_halt
	
	extended_cpuid_supported:
	
	movl $(AMD_CPUID_EXTENDED), %eax
	cpuid
	bt $(AMD_EXT_LONG_MODE), %edx
 	jc long_mode_supported
		
		movl $long_mode_msg, %esi
		jmp error_halt
 
	long_mode_supported:
	
	bt $(AMD_EXT_NOEXECUTE), %edx
	jc noexecute_supported
	
		movl $noexecute_msg, %esi
		jmp error_halt
	
	noexecute_supported:
	
	movl $(INTEL_CPUID_STANDARD), %eax
	cpuid
	bt $(INTEL_FXSAVE), %edx
 	jc fx_supported
	
		movl $fx_msg, %esi
		jmp error_halt
	
	fx_supported:
	
	bt $(INTEL_SSE2), %edx
 	jc sse2_supported
	
		movl $sse2_msg, %esi
		jmp error_halt
	
	sse2_supported:
	
#ifdef CONFIG_FB
	mov $vesa_init, %esi
	mov $VESA_INIT_SEGMENT << 4, %edi
	mov $e_vesa_init - vesa_init, %ecx
 
	rep movsb
 
	mov $VESA_INIT_SEGMENT << 4, %edi
	jmpl *%edi
	
	vesa_meeting_point:
	
	mov %esi, KA2PA(vesa_ph_addr)
	mov %di, KA2PA(vesa_height)
	shr $16, %edi
	mov %di, KA2PA(vesa_width)
	mov %bx, KA2PA(vesa_scanline)
	shr $16, %ebx
	mov %bx, KA2PA(vesa_bpp)
#endif	
	
	# Enable 64-bit page translation entries - CR4.PAE = 1.
	# Paging is not enabled until after long mode is enabled
	
	movl %cr4, %eax
	btsl $5, %eax
	movl %eax, %cr4
 
	# Set up paging tables
	
	leal ptl_0, %eax
	movl %eax, %cr3
	
	# Enable long mode
	
	movl $EFER_MSR_NUM, %ecx			# EFER MSR number
	rdmsr						# Read EFER
	btsl $AMD_LME_FLAG, %eax			# Set LME = 1
	wrmsr						# Write EFER
	
	# Enable paging to activate long mode (set CR0.PG = 1)
	
	movl %cr0, %eax
	btsl $31, %eax
	movl %eax, %cr0
	
	# At this point we are in compatibility mode
	
	jmpl $gdtselector(KTEXT_DES), $start64
 
.code64
start64:
	movq $(PA2KA(START_STACK)), %rsp
	movl grub_eax, %eax
	movl grub_ebx, %ebx
	
	cmpl $MULTIBOOT_LOADER_MAGIC, %eax			# compare GRUB signature
	je valid_boot
		
		xorl %ecx, %ecx					# no memory size or map available
		movl %ecx, e820counter
		
		jmp invalid_boot
		
	valid_boot:
		
		movl (%ebx), %eax				# ebx = physical address of struct multiboot_info
		
		bt $3, %eax					# mbi->flags[3] (mods_count, mods_addr valid)
		jc mods_valid
			
			xorq %rcx, %rcx
			movq %rcx, init
			jmp mods_end
		
		mods_valid:
		
		xorq %rcx, %rcx
		movl 20(%ebx), %ecx				# mbi->mods_count
		movq %rcx, init
		
		cmpl $0, %ecx
		je mods_end
		
		movl 24(%ebx), %esi				# mbi->mods_addr
		movq $init, %rdi
		
		mods_loop:
			
			xorq %rdx, %rdx
			movl 0(%esi), %edx			# mods->mod_start
			movq $0xffff800000000000, %r10
			addq %r10, %rdx
			movq %rdx, 8(%rdi)
			
			xorq %rdx, %rdx
			movl 4(%esi), %edx
			subl 0(%esi), %edx			# mods->mod_end - mods->mod_start
			movq %rdx, 16(%rdi)
			
			addl $16, %esi
			addq $16, %rdi
			
			loop mods_loop
			
		mods_end:
		
		bt $6, %eax					# mbi->flags[6] (mmap_length, mmap_addr valid)	
		jc mmap_valid
			
			xorl %edx, %edx
			jmp mmap_invalid
			
		mmap_valid:
		movl 44(%ebx), %ecx				# mbi->mmap_length
		movl 48(%ebx), %esi				# mbi->mmap_addr
		movq $e820table, %rdi
		xorl %edx, %edx
		
		mmap_loop:
			cmpl $0, %ecx
			jle mmap_end
			
			movl 4(%esi), %eax			# mmap->base_addr_low
			movl %eax, (%rdi)
			
			movl 8(%esi), %eax			# mmap->base_addr_high
			movl %eax, 4(%rdi)
			
			movl 12(%esi), %eax			# mmap->length_low
			movl %eax, 8(%rdi)
			
			movl 16(%esi), %eax			# mmap->length_high
			movl %eax, 12(%rdi)
			
			movl 20(%esi), %eax			# mmap->type
			movl %eax, 16(%rdi)
			
			movl (%esi), %eax			# mmap->size
			addl $0x4, %eax
			addl %eax, %esi
			subl %eax, %ecx
			addq $MEMMAP_E820_RECORD_SIZE, %rdi
			incl %edx
			jmp mmap_loop
		
		mmap_end:
		
		mmap_invalid:
		movl %edx, e820counter
		
	invalid_boot:
	
#ifdef CONFIG_SMP
	
	# copy AP bootstrap routines below 1 MB
	
	movq $BOOT_OFFSET, %rsi
	movq $AP_BOOT_OFFSET, %rdi
	movq $_hardcoded_unmapped_size, %rcx
 
	rep movsb
	
#endif
	
	call main_bsp   # never returns
	
	cli
	hlt
 
#ifdef CONFIG_FB
.code32
vesa_init:
	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init
	
.code16
vesa_init_real:
	
	mov %cr0, %eax
	and $~1, %eax
	mov %eax, %cr0
	
	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
	
vesa_init_real2:
	
	mov $VESA_INIT_SEGMENT, %bx
	
	mov %bx, %es
	mov %bx, %fs
	mov %bx, %gs
	mov %bx, %ds
	mov %bx, %ss
	
	movl $0x0000fffc, %esp
	movl $0x0000fffc, %ebp
	
#define VESA_INFO_SIZE 1024
 
#define VESA_MODE_ATTRIBUTES_OFFSET 0
#define VESA_MODE_LIST_PTR_OFFSET 14
#define VESA_MODE_SCANLINE_OFFSET 16
#define VESA_MODE_WIDTH_OFFSET 18
#define VESA_MODE_HEIGHT_OFFSET 20
#define VESA_MODE_BPP_OFFSET 25
#define VESA_MODE_PHADDR_OFFSET 40
 
#define VESA_END_OF_MODES 0xffff
 
#define VESA_OK 0x4f
 
#define VESA_GET_INFO 0x4f00
#define VESA_GET_MODE_INFO 0x4f01
#define VESA_SET_MODE 0x4f02
#define VESA_SET_PALETTE 0x4f09
 
#define CONFIG_VESA_BPP_a 255
 
#if CONFIG_VESA_BPP == 24
#define CONFIG_VESA_BPP_VARIANT 32
#endif
 
	mov $VESA_GET_INFO, %ax
	mov $e_vesa_init - vesa_init, %di
	push %di
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
	
	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
	mov %si, %gs
	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
	
	add $VESA_INFO_SIZE, %di
 
1:# Try next mode
	mov %gs:(%si), %cx
	cmp $VESA_END_OF_MODES, %cx
	jz 0f
	
	inc %si
	inc %si
	push %cx
	push %di
	push %si
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %si
	pop %di
	pop %cx
	cmp $VESA_OK, %al
	jnz 0f
	
	mov $CONFIG_VESA_WIDTH, %ax
	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_HEIGHT, %ax
	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_BPP, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
 
#ifdef CONFIG_VESA_BPP_VARIANT
	jz 2f
	
	mov $CONFIG_VESA_BPP_VARIANT, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
#endif
	jnz 1b
	
2:
	
	mov %cx, %bx
	or $0xc000, %bx
	push %di
	mov $VESA_SET_MODE, %ax
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
 
#if CONFIG_VESA_BPP == 8
	
	# Set 3:2:3 VGA palette
	
	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax
	push %di
	mov $vga323 - vesa_init, %di
	mov $0x100, %ecx
	
	bt $5, %ax						# Test if VGA compatible registers are present
	jnc vga_compat
		
		# Try VESA routine to set palette
		
		mov $VESA_SET_PALETTE, %ax
		xor %bl, %bl
		xor %dx, %dx
		int $0x10
		
		jmp vga_not_compat
	
	vga_compat:
		
		# Try VGA registers to set palette
		
		movw $0x3c6, %dx				# Set palette mask
		movb $0xff, %al
		outb %al, %dx
		
		movw $0x3c8, %dx				# First index to set
		xor %al, %al
		outb %al, %dx
		
		movw $0x3c9, %dx				# Data port
		vga_loop:
			movb %es:2(%di), %al
			outb %al, %dx
			
			movb %es:1(%di), %al
			outb %al, %dx
			
			movb %es:(%di), %al
			outb %al, %dx
			
			addw $4, %di
			loop vga_loop
		
	vga_not_compat:
	
	pop %di
	
#endif
	
	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
	shl $16, %eax
	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
	mov VESA_MODE_BPP_OFFSET(%di), %bl
	xor %bh, %bh
	shl $16, %ebx
	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
	mov %eax, %edi
	
8:
	
	mov %cr0, %eax
	or $1, %eax
	mov %eax, %cr0
	
	jmp 9f
9:
	
	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
	
0:# No prefered mode found
	mov $0x111, %cx
	push %di
	push %cx
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %cx
	pop %di
	cmp $VESA_OK, %al
	jnz 1f
	jz 2b						# Force relative jump
 
1:
	mov $0x0003, %ax
	int $0x10
	mov $0xffffffff, %edi				# EGA text mode used, because of problems with VESA
	xor %ax, %ax
	jz 8b						# Force relative jump
 
vga323:
#include "vga323.pal"	
	
.code32
vesa_init_protect:
	movw $gdtselector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %ds					# kernel data + stack
	movw %cx, %ss
	# Simics seems to remove hidden part of GS on entering user mode
	#  when _visible_ part of GS does not point to user-mode segment
	movw $gdtselector(UDATA_DES), %cx
	movw %cx, %fs
	movw %cx, %gs
	
	movl $START_STACK, %esp				# initialize stack pointer
	
	jmpl $gdtselector(KTEXT32_DES), $vesa_meeting_point
	
.align 4
e_vesa_init:
#endif
 
# Print string from %esi to EGA display (in red) and halt
error_halt:
	movl $0xb8000, %edi				# base of EGA text mode memory
	xorl %eax, %eax
	
	movw $0x3d4, %dx				# read bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	shl $8, %ax
	
	movw $0x3d4, %dx				# read bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	
	cmp $1920, %ax
	jbe cursor_ok
		movw $1920, %ax				# sanity check for the cursor on the last line
	cursor_ok:
	
	movw %ax, %bx
	shl $1, %eax
	addl %eax, %edi
	
	movw $0x0c00, %ax				# black background, light red foreground
 
	
	ploop:
		lodsb
		cmp $0, %al
		je ploop_end
		stosw
		inc %bx	
		jmp ploop
	ploop_end:
	
	movw $0x3d4, %dx				# write bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bh, %al
	outb %al, %dx
	
	movw $0x3d4, %dx				# write bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bl, %al
	outb %al, %dx
		
	cli
	hlt
				
 
.section K_INI_PTLS, "aw", @progbits
 
#
# Macro for generating initial page table contents.
# @param cnt	Number of entries to generat. Must be multiple of 8.
# @param g	Number of GB that will be added to the mapping.
#
.macro ptl2gen cnt g 
.if \cnt
	ptl2gen "\cnt - 8" \g 
	.quad ((\cnt - 8) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 7) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 6) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 5) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 4) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 3) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 2) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 1) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
.endif
.endm
 
# Page table for pages in the first gigabyte.
.align 4096
.global ptl_2_0g
ptl_2_0g:	
	ptl2gen 512 0
 
# Page table for pages in the second gigabyte.
.align 4096
.global ptl_2_1g
ptl_2_1g:
	ptl2gen 512 1
 
# Page table for pages in the third gigabyte.
.align 4096
.global ptl_2_2g
ptl_2_2g:
	ptl2gen 512 2
 
# Page table for pages in the fourth gigabyte.
.align 4096
.global ptl_2_3g
ptl_2_3g:
	ptl2gen 512 3
 
.align 4096
.global ptl_1
ptl_1:
	# Identity mapping for [0; 4G)
	.quad ptl_2_0g + (PTL_WRITABLE | PTL_PRESENT)
	.quad ptl_2_1g + (PTL_WRITABLE | PTL_PRESENT) 
	.quad ptl_2_2g + (PTL_WRITABLE | PTL_PRESENT)
	.quad ptl_2_3g + (PTL_WRITABLE | PTL_PRESENT)
	.fill 506, 8, 0
	# Mapping of [0; 1G) at -2G
	.quad ptl_2_0g + (PTL_WRITABLE | PTL_PRESENT)
	.fill 1, 8, 0
	
.align 4096
.global ptl_0
ptl_0:
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
	.fill 255,8,0
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
	.fill 254,8,0
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
 
.section K_DATA_START, "aw", @progbits
 
.global bootstrap_gdtr
bootstrap_gdtr:
	.word gdtselector(GDT_ITEMS)
	.long KA2PA(gdt)
 
grub_eax:
	.long 0
 
grub_ebx:
	.long 0
 
extended_cpuid_msg:
	.asciz "Extended CPUID not supported. System halted."
long_mode_msg:
	.asciz "64 bit long mode not supported. System halted."
noexecute_msg:
	.asciz "No-execute pages not supported. System halted."
fx_msg:
	.asciz "FXSAVE/FXRESTORE instructions not supported. System halted."
sse2_msg:
	.asciz "SSE2 instructions not supported. System halted."
 

Rev 2725	Rev 2784
1		1
2	# Copyright (c) 2005 Ondrej Palkovsky	2	# Copyright (c) 2005 Ondrej Palkovsky
3	# Copyright (c) 2006 Martin Decky	3	# Copyright (c) 2006 Martin Decky
4	# Copyright (c) 2008 Jakub Jermar	4	# Copyright (c) 2008 Jakub Jermar
5	# All rights reserved.	5	# All rights reserved.
6	#	6	#
7	# Redistribution and use in source and binary forms, with or without	7	# Redistribution and use in source and binary forms, with or without
8	# modification, are permitted provided that the following conditions	8	# modification, are permitted provided that the following conditions
9	# are met:	9	# are met:
10	#	10	#
11	# - Redistributions of source code must retain the above copyright	11	# - Redistributions of source code must retain the above copyright
12	# notice, this list of conditions and the following disclaimer.	12	# notice, this list of conditions and the following disclaimer.
13	# - Redistributions in binary form must reproduce the above copyright	13	# - Redistributions in binary form must reproduce the above copyright
14	# notice, this list of conditions and the following disclaimer in the	14	# notice, this list of conditions and the following disclaimer in the
15	# documentation and/or other materials provided with the distribution.	15	# documentation and/or other materials provided with the distribution.
16	# - The name of the author may not be used to endorse or promote products	16	# - The name of the author may not be used to endorse or promote products
17	# derived from this software without specific prior written permission.	17	# derived from this software without specific prior written permission.
18	#	18	#
19	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR	19	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
20	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES	20	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
21	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.	21	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
22	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,	22	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
23	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT	23	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
24	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,	24	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
25	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY	25	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
26	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT	26	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF	27	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.	28	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29	#	29	#
30		30
31	#include <arch/boot/boot.h>	31	#include <arch/boot/boot.h>
32	#include <arch/boot/memmap.h>	32	#include <arch/boot/memmap.h>
33	#include <arch/mm/page.h>	33	#include <arch/mm/page.h>
34	#include <arch/mm/ptl.h>	34	#include <arch/mm/ptl.h>
35	#include <arch/pm.h>	35	#include <arch/pm.h>
36	#include <arch/cpu.h>	36	#include <arch/cpu.h>
37	#include <arch/cpuid.h>	37	#include <arch/cpuid.h>
38		38
39	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)	39	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
40		40
41	.section K_TEXT_START, "ax"	41	.section K_TEXT_START, "ax"
42		42
43	.code32	43	.code32
44	.align 4	44	.align 4
45	.global multiboot_image_start	45	.global multiboot_image_start
46	multiboot_header:	46	multiboot_header:
47	.long MULTIBOOT_HEADER_MAGIC	47	.long MULTIBOOT_HEADER_MAGIC
48	.long MULTIBOOT_HEADER_FLAGS	48	.long MULTIBOOT_HEADER_FLAGS
49	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum	49	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum
50	.long multiboot_header	50	.long multiboot_header
51	.long unmapped_ktext_start	51	.long unmapped_ktext_start
52	.long 0	52	.long 0
53	.long 0	53	.long 0
54	.long multiboot_image_start	54	.long multiboot_image_start
55		55
56	multiboot_image_start:	56	multiboot_image_start:
-		57	cld
57	movl $START_STACK, %esp # initialize stack pointer	58	movl $START_STACK, %esp # initialize stack pointer
58	lgdtl bootstrap_gdtr # initialize Global Descriptor Table register	59	lgdtl bootstrap_gdtr # initialize Global Descriptor Table register
59		60
60	movw $gdtselector(KDATA_DES), %cx	61	movw $gdtselector(KDATA_DES), %cx
61	movw %cx, %es	62	movw %cx, %es
62	movw %cx, %ds # kernel data + stack	63	movw %cx, %ds # kernel data + stack
63	movw %cx, %ss	64	movw %cx, %ss
64	# Simics seems to remove hidden part of GS on entering user mode	65	# Simics seems to remove hidden part of GS on entering user mode
65	# when _visible_ part of GS does not point to user-mode segment	66	# when _visible_ part of GS does not point to user-mode segment
66	movw $gdtselector(UDATA_DES), %cx	67	movw $gdtselector(UDATA_DES), %cx
67	movw %cx, %fs	68	movw %cx, %fs
68	movw %cx, %gs	69	movw %cx, %gs
69		70
70	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point	71	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point
71	multiboot_meeting_point:	72	multiboot_meeting_point:
72		73
73	movl %eax, grub_eax # save parameters from GRUB	74	movl %eax, grub_eax # save parameters from GRUB
74	movl %ebx, grub_ebx	75	movl %ebx, grub_ebx
75		76
76	# Protected 32-bit. We want to reuse the code-seg descriptor,	77	# Protected 32-bit. We want to reuse the code-seg descriptor,
77	# the Default operand size must not be 1 when entering long mode	78	# the Default operand size must not be 1 when entering long mode
78		79
79	movl $(INTEL_CPUID_EXTENDED), %eax	80	movl $(INTEL_CPUID_EXTENDED), %eax
80	cpuid	81	cpuid
81	cmp $(INTEL_CPUID_EXTENDED), %eax	82	cmp $(INTEL_CPUID_EXTENDED), %eax
82	ja extended_cpuid_supported	83	ja extended_cpuid_supported
83		84
84	movl $extended_cpuid_msg, %esi	85	movl $extended_cpuid_msg, %esi
85	jmp error_halt	86	jmp error_halt
86		87
87	extended_cpuid_supported:	88	extended_cpuid_supported:
88		89
89	movl $(AMD_CPUID_EXTENDED), %eax	90	movl $(AMD_CPUID_EXTENDED), %eax
90	cpuid	91	cpuid
91	bt $(AMD_EXT_LONG_MODE), %edx	92	bt $(AMD_EXT_LONG_MODE), %edx
92	jc long_mode_supported	93	jc long_mode_supported
93		94
94	movl $long_mode_msg, %esi	95	movl $long_mode_msg, %esi
95	jmp error_halt	96	jmp error_halt
96		97
97	long_mode_supported:	98	long_mode_supported:
98		99
99	bt $(AMD_EXT_NOEXECUTE), %edx	100	bt $(AMD_EXT_NOEXECUTE), %edx
100	jc noexecute_supported	101	jc noexecute_supported
101		102
102	movl $noexecute_msg, %esi	103	movl $noexecute_msg, %esi
103	jmp error_halt	104	jmp error_halt
104		105
105	noexecute_supported:	106	noexecute_supported:
106		107
107	movl $(INTEL_CPUID_STANDARD), %eax	108	movl $(INTEL_CPUID_STANDARD), %eax
108	cpuid	109	cpuid
109	bt $(INTEL_FXSAVE), %edx	110	bt $(INTEL_FXSAVE), %edx
110	jc fx_supported	111	jc fx_supported
111		112
112	movl $fx_msg, %esi	113	movl $fx_msg, %esi
113	jmp error_halt	114	jmp error_halt
114		115
115	fx_supported:	116	fx_supported:
116		117
117	bt $(INTEL_SSE2), %edx	118	bt $(INTEL_SSE2), %edx
118	jc sse2_supported	119	jc sse2_supported
119		120
120	movl $sse2_msg, %esi	121	movl $sse2_msg, %esi
121	jmp error_halt	122	jmp error_halt
122		123
123	sse2_supported:	124	sse2_supported:
124		125
125	#ifdef CONFIG_FB	126	#ifdef CONFIG_FB
126	mov $vesa_init, %esi	127	mov $vesa_init, %esi
127	mov $VESA_INIT_SEGMENT << 4, %edi	128	mov $VESA_INIT_SEGMENT << 4, %edi
128	mov $e_vesa_init - vesa_init, %ecx	129	mov $e_vesa_init - vesa_init, %ecx
129	cld	-
130	rep movsb	130	rep movsb
131		131
132	mov $VESA_INIT_SEGMENT << 4, %edi	132	mov $VESA_INIT_SEGMENT << 4, %edi
133	jmpl *%edi	133	jmpl *%edi
134		134
135	vesa_meeting_point:	135	vesa_meeting_point:
136		136
137	mov %esi, KA2PA(vesa_ph_addr)	137	mov %esi, KA2PA(vesa_ph_addr)
138	mov %di, KA2PA(vesa_height)	138	mov %di, KA2PA(vesa_height)
139	shr $16, %edi	139	shr $16, %edi
140	mov %di, KA2PA(vesa_width)	140	mov %di, KA2PA(vesa_width)
141	mov %bx, KA2PA(vesa_scanline)	141	mov %bx, KA2PA(vesa_scanline)
142	shr $16, %ebx	142	shr $16, %ebx
143	mov %bx, KA2PA(vesa_bpp)	143	mov %bx, KA2PA(vesa_bpp)
144	#endif	144	#endif
145		145
146	# Enable 64-bit page translation entries - CR4.PAE = 1.	146	# Enable 64-bit page translation entries - CR4.PAE = 1.
147	# Paging is not enabled until after long mode is enabled	147	# Paging is not enabled until after long mode is enabled
148		148
149	movl %cr4, %eax	149	movl %cr4, %eax
150	btsl $5, %eax	150	btsl $5, %eax
151	movl %eax, %cr4	151	movl %eax, %cr4
152		152
153	# Set up paging tables	153	# Set up paging tables
154		154
155	leal ptl_0, %eax	155	leal ptl_0, %eax
156	movl %eax, %cr3	156	movl %eax, %cr3
157		157
158	# Enable long mode	158	# Enable long mode
159		159
160	movl $EFER_MSR_NUM, %ecx # EFER MSR number	160	movl $EFER_MSR_NUM, %ecx # EFER MSR number
161	rdmsr # Read EFER	161	rdmsr # Read EFER
162	btsl $AMD_LME_FLAG, %eax # Set LME = 1	162	btsl $AMD_LME_FLAG, %eax # Set LME = 1
163	wrmsr # Write EFER	163	wrmsr # Write EFER
164		164
165	# Enable paging to activate long mode (set CR0.PG = 1)	165	# Enable paging to activate long mode (set CR0.PG = 1)
166		166
167	movl %cr0, %eax	167	movl %cr0, %eax
168	btsl $31, %eax	168	btsl $31, %eax
169	movl %eax, %cr0	169	movl %eax, %cr0
170		170
171	# At this point we are in compatibility mode	171	# At this point we are in compatibility mode
172		172
173	jmpl $gdtselector(KTEXT_DES), $start64	173	jmpl $gdtselector(KTEXT_DES), $start64
174		174
175	.code64	175	.code64
176	start64:	176	start64:
177	movq $(PA2KA(START_STACK)), %rsp	177	movq $(PA2KA(START_STACK)), %rsp
178	movl grub_eax, %eax	178	movl grub_eax, %eax
179	movl grub_ebx, %ebx	179	movl grub_ebx, %ebx
180		180
181	cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature	181	cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature
182	je valid_boot	182	je valid_boot
183		183
184	xorl %ecx, %ecx # no memory size or map available	184	xorl %ecx, %ecx # no memory size or map available
185	movl %ecx, e820counter	185	movl %ecx, e820counter
186		186
187	jmp invalid_boot	187	jmp invalid_boot
188		188
189	valid_boot:	189	valid_boot:
190		190
191	movl (%ebx), %eax # ebx = physical address of struct multiboot_info	191	movl (%ebx), %eax # ebx = physical address of struct multiboot_info
192		192
193	bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)	193	bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)
194	jc mods_valid	194	jc mods_valid
195		195
196	xorq %rcx, %rcx	196	xorq %rcx, %rcx
197	movq %rcx, init	197	movq %rcx, init
198	jmp mods_end	198	jmp mods_end
199		199
200	mods_valid:	200	mods_valid:
201		201
202	xorq %rcx, %rcx	202	xorq %rcx, %rcx
203	movl 20(%ebx), %ecx # mbi->mods_count	203	movl 20(%ebx), %ecx # mbi->mods_count
204	movq %rcx, init	204	movq %rcx, init
205		205
206	cmpl $0, %ecx	206	cmpl $0, %ecx
207	je mods_end	207	je mods_end
208		208
209	movl 24(%ebx), %esi # mbi->mods_addr	209	movl 24(%ebx), %esi # mbi->mods_addr
210	movq $init, %rdi	210	movq $init, %rdi
211		211
212	mods_loop:	212	mods_loop:
213		213
214	xorq %rdx, %rdx	214	xorq %rdx, %rdx
215	movl 0(%esi), %edx # mods->mod_start	215	movl 0(%esi), %edx # mods->mod_start
216	movq $0xffff800000000000, %r10	216	movq $0xffff800000000000, %r10
217	addq %r10, %rdx	217	addq %r10, %rdx
218	movq %rdx, 8(%rdi)	218	movq %rdx, 8(%rdi)
219		219
220	xorq %rdx, %rdx	220	xorq %rdx, %rdx
221	movl 4(%esi), %edx	221	movl 4(%esi), %edx
222	subl 0(%esi), %edx # mods->mod_end - mods->mod_start	222	subl 0(%esi), %edx # mods->mod_end - mods->mod_start
223	movq %rdx, 16(%rdi)	223	movq %rdx, 16(%rdi)
224		224
225	addl $16, %esi	225	addl $16, %esi
226	addq $16, %rdi	226	addq $16, %rdi
227		227
228	loop mods_loop	228	loop mods_loop
229		229
230	mods_end:	230	mods_end:
231		231
232	bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)	232	bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)
233	jc mmap_valid	233	jc mmap_valid
234		234
235	xorl %edx, %edx	235	xorl %edx, %edx
236	jmp mmap_invalid	236	jmp mmap_invalid
237		237
238	mmap_valid:	238	mmap_valid:
239	movl 44(%ebx), %ecx # mbi->mmap_length	239	movl 44(%ebx), %ecx # mbi->mmap_length
240	movl 48(%ebx), %esi # mbi->mmap_addr	240	movl 48(%ebx), %esi # mbi->mmap_addr
241	movq $e820table, %rdi	241	movq $e820table, %rdi
242	xorl %edx, %edx	242	xorl %edx, %edx
243		243
244	mmap_loop:	244	mmap_loop:
245	cmpl $0, %ecx	245	cmpl $0, %ecx
246	jle mmap_end	246	jle mmap_end
247		247
248	movl 4(%esi), %eax # mmap->base_addr_low	248	movl 4(%esi), %eax # mmap->base_addr_low
249	movl %eax, (%rdi)	249	movl %eax, (%rdi)
250		250
251	movl 8(%esi), %eax # mmap->base_addr_high	251	movl 8(%esi), %eax # mmap->base_addr_high
252	movl %eax, 4(%rdi)	252	movl %eax, 4(%rdi)
253		253
254	movl 12(%esi), %eax # mmap->length_low	254	movl 12(%esi), %eax # mmap->length_low
255	movl %eax, 8(%rdi)	255	movl %eax, 8(%rdi)
256		256
257	movl 16(%esi), %eax # mmap->length_high	257	movl 16(%esi), %eax # mmap->length_high
258	movl %eax, 12(%rdi)	258	movl %eax, 12(%rdi)
259		259
260	movl 20(%esi), %eax # mmap->type	260	movl 20(%esi), %eax # mmap->type
261	movl %eax, 16(%rdi)	261	movl %eax, 16(%rdi)
262		262
263	movl (%esi), %eax # mmap->size	263	movl (%esi), %eax # mmap->size
264	addl $0x4, %eax	264	addl $0x4, %eax
265	addl %eax, %esi	265	addl %eax, %esi
266	subl %eax, %ecx	266	subl %eax, %ecx
267	addq $MEMMAP_E820_RECORD_SIZE, %rdi	267	addq $MEMMAP_E820_RECORD_SIZE, %rdi
268	incl %edx	268	incl %edx
269	jmp mmap_loop	269	jmp mmap_loop
270		270
271	mmap_end:	271	mmap_end:
272		272
273	mmap_invalid:	273	mmap_invalid:
274	movl %edx, e820counter	274	movl %edx, e820counter
275		275
276	invalid_boot:	276	invalid_boot:
277		277
278	#ifdef CONFIG_SMP	278	#ifdef CONFIG_SMP
279		279
280	# copy AP bootstrap routines below 1 MB	280	# copy AP bootstrap routines below 1 MB
281		281
282	movq $BOOT_OFFSET, %rsi	282	movq $BOOT_OFFSET, %rsi
283	movq $AP_BOOT_OFFSET, %rdi	283	movq $AP_BOOT_OFFSET, %rdi
284	movq $_hardcoded_unmapped_size, %rcx	284	movq $_hardcoded_unmapped_size, %rcx
285	cld	-
286	rep movsb	285	rep movsb
287		286
288	#endif	287	#endif
289		288
290	call main_bsp # never returns	289	call main_bsp # never returns
291		290
292	cli	291	cli
293	hlt	292	hlt
294		293
295	#ifdef CONFIG_FB	294	#ifdef CONFIG_FB
296	.code32	295	.code32
297	vesa_init:	296	vesa_init:
298	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init	297	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init
299		298
300	.code16	299	.code16
301	vesa_init_real:	300	vesa_init_real:
302		301
303	mov %cr0, %eax	302	mov %cr0, %eax
304	and $~1, %eax	303	and $~1, %eax
305	mov %eax, %cr0	304	mov %eax, %cr0
306		305
307	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init	306	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
308		307
309	vesa_init_real2:	308	vesa_init_real2:
310		309
311	mov $VESA_INIT_SEGMENT, %bx	310	mov $VESA_INIT_SEGMENT, %bx
312		311
313	mov %bx, %es	312	mov %bx, %es
314	mov %bx, %fs	313	mov %bx, %fs
315	mov %bx, %gs	314	mov %bx, %gs
316	mov %bx, %ds	315	mov %bx, %ds
317	mov %bx, %ss	316	mov %bx, %ss
318		317
319	movl $0x0000fffc, %esp	318	movl $0x0000fffc, %esp
320	movl $0x0000fffc, %ebp	319	movl $0x0000fffc, %ebp
321		320
322	#define VESA_INFO_SIZE 1024	321	#define VESA_INFO_SIZE 1024
323		322
324	#define VESA_MODE_ATTRIBUTES_OFFSET 0	323	#define VESA_MODE_ATTRIBUTES_OFFSET 0
325	#define VESA_MODE_LIST_PTR_OFFSET 14	324	#define VESA_MODE_LIST_PTR_OFFSET 14
326	#define VESA_MODE_SCANLINE_OFFSET 16	325	#define VESA_MODE_SCANLINE_OFFSET 16
327	#define VESA_MODE_WIDTH_OFFSET 18	326	#define VESA_MODE_WIDTH_OFFSET 18
328	#define VESA_MODE_HEIGHT_OFFSET 20	327	#define VESA_MODE_HEIGHT_OFFSET 20
329	#define VESA_MODE_BPP_OFFSET 25	328	#define VESA_MODE_BPP_OFFSET 25
330	#define VESA_MODE_PHADDR_OFFSET 40	329	#define VESA_MODE_PHADDR_OFFSET 40
331		330
332	#define VESA_END_OF_MODES 0xffff	331	#define VESA_END_OF_MODES 0xffff
333		332
334	#define VESA_OK 0x4f	333	#define VESA_OK 0x4f
335		334
336	#define VESA_GET_INFO 0x4f00	335	#define VESA_GET_INFO 0x4f00
337	#define VESA_GET_MODE_INFO 0x4f01	336	#define VESA_GET_MODE_INFO 0x4f01
338	#define VESA_SET_MODE 0x4f02	337	#define VESA_SET_MODE 0x4f02
339	#define VESA_SET_PALETTE 0x4f09	338	#define VESA_SET_PALETTE 0x4f09
340		339
341	#define CONFIG_VESA_BPP_a 255	340	#define CONFIG_VESA_BPP_a 255
342		341
343	#if CONFIG_VESA_BPP == 24	342	#if CONFIG_VESA_BPP == 24
344	#define CONFIG_VESA_BPP_VARIANT 32	343	#define CONFIG_VESA_BPP_VARIANT 32
345	#endif	344	#endif
346		345
347	mov $VESA_GET_INFO, %ax	346	mov $VESA_GET_INFO, %ax
348	mov $e_vesa_init - vesa_init, %di	347	mov $e_vesa_init - vesa_init, %di
349	push %di	348	push %di
350	int $0x10	349	int $0x10
351		350
352	pop %di	351	pop %di
353	cmp $VESA_OK, %al	352	cmp $VESA_OK, %al
354	jnz 0f	353	jnz 0f
355		354
356	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si	355	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
357	mov %si, %gs	356	mov %si, %gs
358	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si	357	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
359		358
360	add $VESA_INFO_SIZE, %di	359	add $VESA_INFO_SIZE, %di
361		360
362	1:# Try next mode	361	1:# Try next mode
363	mov %gs:(%si), %cx	362	mov %gs:(%si), %cx
364	cmp $VESA_END_OF_MODES, %cx	363	cmp $VESA_END_OF_MODES, %cx
365	jz 0f	364	jz 0f
366		365
367	inc %si	366	inc %si
368	inc %si	367	inc %si
369	push %cx	368	push %cx
370	push %di	369	push %di
371	push %si	370	push %si
372	mov $VESA_GET_MODE_INFO, %ax	371	mov $VESA_GET_MODE_INFO, %ax
373	int $0x10	372	int $0x10
374		373
375	pop %si	374	pop %si
376	pop %di	375	pop %di
377	pop %cx	376	pop %cx
378	cmp $VESA_OK, %al	377	cmp $VESA_OK, %al
379	jnz 0f	378	jnz 0f
380		379
381	mov $CONFIG_VESA_WIDTH, %ax	380	mov $CONFIG_VESA_WIDTH, %ax
382	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax	381	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
383	jnz 1b	382	jnz 1b
384		383
385	mov $CONFIG_VESA_HEIGHT, %ax	384	mov $CONFIG_VESA_HEIGHT, %ax
386	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax	385	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
387	jnz 1b	386	jnz 1b
388		387
389	mov $CONFIG_VESA_BPP, %al	388	mov $CONFIG_VESA_BPP, %al
390	cmp VESA_MODE_BPP_OFFSET(%di), %al	389	cmp VESA_MODE_BPP_OFFSET(%di), %al
391		390
392	#ifdef CONFIG_VESA_BPP_VARIANT	391	#ifdef CONFIG_VESA_BPP_VARIANT
393	jz 2f	392	jz 2f
394		393
395	mov $CONFIG_VESA_BPP_VARIANT, %al	394	mov $CONFIG_VESA_BPP_VARIANT, %al
396	cmp VESA_MODE_BPP_OFFSET(%di), %al	395	cmp VESA_MODE_BPP_OFFSET(%di), %al
397	#endif	396	#endif
398	jnz 1b	397	jnz 1b
399		398
400	2:	399	2:
401		400
402	mov %cx, %bx	401	mov %cx, %bx
403	or $0xc000, %bx	402	or $0xc000, %bx
404	push %di	403	push %di
405	mov $VESA_SET_MODE, %ax	404	mov $VESA_SET_MODE, %ax
406	int $0x10	405	int $0x10
407		406
408	pop %di	407	pop %di
409	cmp $VESA_OK, %al	408	cmp $VESA_OK, %al
410	jnz 0f	409	jnz 0f
411		410
412	#if CONFIG_VESA_BPP == 8	411	#if CONFIG_VESA_BPP == 8
413		412
414	# Set 3:2:3 VGA palette	413	# Set 3:2:3 VGA palette
415		414
416	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax	415	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax
417	push %di	416	push %di
418	mov $vga323 - vesa_init, %di	417	mov $vga323 - vesa_init, %di
419	mov $0x100, %ecx	418	mov $0x100, %ecx
420		419
421	bt $5, %ax # Test if VGA compatible registers are present	420	bt $5, %ax # Test if VGA compatible registers are present
422	jnc vga_compat	421	jnc vga_compat
423		422
424	# Try VESA routine to set palette	423	# Try VESA routine to set palette
425		424
426	mov $VESA_SET_PALETTE, %ax	425	mov $VESA_SET_PALETTE, %ax
427	xor %bl, %bl	426	xor %bl, %bl
428	xor %dx, %dx	427	xor %dx, %dx
429	int $0x10	428	int $0x10
430		429
431	jmp vga_not_compat	430	jmp vga_not_compat
432		431
433	vga_compat:	432	vga_compat:
434		433
435	# Try VGA registers to set palette	434	# Try VGA registers to set palette
436		435
437	movw $0x3c6, %dx # Set palette mask	436	movw $0x3c6, %dx # Set palette mask
438	movb $0xff, %al	437	movb $0xff, %al
439	outb %al, %dx	438	outb %al, %dx
440		439
441	movw $0x3c8, %dx # First index to set	440	movw $0x3c8, %dx # First index to set
442	xor %al, %al	441	xor %al, %al
443	outb %al, %dx	442	outb %al, %dx
444		443
445	movw $0x3c9, %dx # Data port	444	movw $0x3c9, %dx # Data port
446	vga_loop:	445	vga_loop:
447	movb %es:2(%di), %al	446	movb %es:2(%di), %al
448	outb %al, %dx	447	outb %al, %dx
449		448
450	movb %es:1(%di), %al	449	movb %es:1(%di), %al
451	outb %al, %dx	450	outb %al, %dx
452		451
453	movb %es:(%di), %al	452	movb %es:(%di), %al
454	outb %al, %dx	453	outb %al, %dx
455		454
456	addw $4, %di	455	addw $4, %di
457	loop vga_loop	456	loop vga_loop
458		457
459	vga_not_compat:	458	vga_not_compat:
460		459
461	pop %di	460	pop %di
462		461
463	#endif	462	#endif
464		463
465	mov VESA_MODE_PHADDR_OFFSET(%di), %esi	464	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
466	mov VESA_MODE_WIDTH_OFFSET(%di), %ax	465	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
467	shl $16, %eax	466	shl $16, %eax
468	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax	467	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
469	mov VESA_MODE_BPP_OFFSET(%di), %bl	468	mov VESA_MODE_BPP_OFFSET(%di), %bl
470	xor %bh, %bh	469	xor %bh, %bh
471	shl $16, %ebx	470	shl $16, %ebx
472	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx	471	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
473	mov %eax, %edi	472	mov %eax, %edi
474		473
475	8:	474	8:
476		475
477	mov %cr0, %eax	476	mov %cr0, %eax
478	or $1, %eax	477	or $1, %eax
479	mov %eax, %cr0	478	mov %eax, %cr0
480		479
481	jmp 9f	480	jmp 9f
482	9:	481	9:
483		482
484	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)	483	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
485		484
486	0:# No prefered mode found	485	0:# No prefered mode found
487	mov $0x111, %cx	486	mov $0x111, %cx
488	push %di	487	push %di
489	push %cx	488	push %cx
490	mov $VESA_GET_MODE_INFO, %ax	489	mov $VESA_GET_MODE_INFO, %ax
491	int $0x10	490	int $0x10
492		491
493	pop %cx	492	pop %cx
494	pop %di	493	pop %di
495	cmp $VESA_OK, %al	494	cmp $VESA_OK, %al
496	jnz 1f	495	jnz 1f
497	jz 2b # Force relative jump	496	jz 2b # Force relative jump
498		497
499	1:	498	1:

Subversion Repositories HelenOS

(root)/trunk/kernel/arch/amd64/src/boot/boot.S – Rev 2725 → 2784