WebSVN – HelenOS – Diff – /trunk/kernel/arch/amd64/src/boot/boot.S


#
# Copyright (c) 2005 Ondrej Palkovsky
# Copyright (c) 2006 Martin Decky
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
#
# - Redistributions of source code must retain the above copyright
#   notice, this list of conditions and the following disclaimer.
# - Redistributions in binary form must reproduce the above copyright
#   notice, this list of conditions and the following disclaimer in the
#   documentation and/or other materials provided with the distribution.
# - The name of the author may not be used to endorse or promote products
#   derived from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
#
 
#include <arch/boot/boot.h>
#include <arch/boot/memmap.h>
#include <arch/mm/page.h>	
#include <arch/mm/ptl.h>
#include <arch/pm.h>
#include <arch/cpu.h>
#include <arch/cpuid.h>
 
#define START_STACK	(BOOT_OFFSET - BOOT_STACK_SIZE)
	
.section K_TEXT_START, "ax"
 
.code32
.align 4
.global multiboot_image_start
multiboot_header:
	.long MULTIBOOT_HEADER_MAGIC
	.long MULTIBOOT_HEADER_FLAGS
	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS)	# checksum
	.long multiboot_header
	.long unmapped_ktext_start
	.long 0
	.long 0
	.long multiboot_image_start
 
multiboot_image_start:
	movl $START_STACK, %esp			# initialize stack pointer
	lgdt bootstrap_gdtr				# initialize Global Descriptor Table register
 
	movw $gdtselector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %ds							# kernel data + stack
	movw %cx, %ss
	# Simics seems to remove hidden part of GS on entering user mode
	#  when _visible_ part of GS does not point to user-mode segment
	movw $gdtselector(UDATA_DES), %cx
	movw %cx, %fs
	movw %cx, %gs
	
	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point
	multiboot_meeting_point:
	
	movl %eax, grub_eax							# save parameters from GRUB
	movl %ebx, grub_ebx
	
	# Protected 32-bit. We want to reuse the code-seg descriptor,
	# the Default operand size must not be 1 when entering long mode
	
	movl $0x80000000, %eax  
 	cpuid
 	cmp $0x80000000, %eax						# any function > 80000000h?
	jbe long_mode_unsupported
	movl $(AMD_CPUID_EXTENDED), %eax			# Extended function code 80000001
	cpuid
	bt $29, %edx								# Test if long mode is supported.
 	jc long_mode_supported
 
	long_mode_unsupported:
		movl $long_mode_msg, %esi
		jmp error_halt
	
	long_mode_supported:
	
#ifdef CONFIG_FB
	mov $vesa_init, %esi
	mov $VESA_INIT_SEGMENT << 4, %edi
	mov $e_vesa_init - vesa_init, %ecx
	cld
	rep movsb
 
	mov $VESA_INIT_SEGMENT << 4, %edi
	jmpl *%edi
	
	vesa_meeting_point:
	
	mov %esi, KA2PA(vesa_ph_addr)
	mov %di, KA2PA(vesa_height)
	shr $16, %edi
	mov %di, KA2PA(vesa_width)
	mov %bx, KA2PA(vesa_scanline)
	shr $16, %ebx
	mov %bx, KA2PA(vesa_bpp)
#endif	
	
	# Enable 64-bit page transaltion entries - CR4.PAE = 1.
	# Paging is not enabled until after long mode is enabled
	
	movl %cr4, %eax
	btsl $5, %eax
	movl %eax, %cr4
 
	# Set up paging tables
	
	leal ptl_0, %eax
	movl %eax, %cr3
	
	# Enable long mode
	
	movl $EFER_MSR_NUM, %ecx	# EFER MSR number
	rdmsr						# Read EFER
	btsl $AMD_LME_FLAG, %eax	# Set LME=1
	wrmsr						# Write EFER
	
	# Enable paging to activate long mode (set CR0.PG=1)
	
	movl %cr0, %eax
	btsl $31, %eax
	movl %eax, %cr0
	
	# At this point we are in compatibility mode
	
	jmpl $gdtselector(KTEXT_DES), $start64
 
.code64
start64:
	movq $(PA2KA(START_STACK)), %rsp
	movl grub_eax, %eax
	movl grub_ebx, %ebx
	
	cmpl $MULTIBOOT_LOADER_MAGIC, %eax				# compare GRUB signature
	je valid_boot
		
		xorl %ecx, %ecx							# no memory size or map available
		movl %ecx, e801memorysize
		movl %ecx, e820counter
		
		jmp invalid_boot
		
	valid_boot:
		
		movl (%ebx), %eax						# ebx = physical address of struct multiboot_info
		
		bt $0, %eax								# mbi->flags[0] (mem_lower, mem_upper valid)
		jc mem_valid
			
			xorl %ecx, %ecx
			jmp mem_invalid
			
		mem_valid:
		movl 4(%ebx), %ecx						# mbi->mem_lower
		addl 8(%ebx), %ecx						# mbi->mem_upper
		
		mem_invalid:
		movl %ecx, e801memorysize
		
		bt $3, %eax								# mbi->flags[3] (mods_count, mods_addr valid)
		jc mods_valid
			
			xorq %rcx, %rcx
			movq %rcx, init
			jmp mods_end
		
		mods_valid:
		
		xorq %rcx, %rcx
		movl 20(%ebx), %ecx						# mbi->mods_count
		movq %rcx, init
		
		cmpl $0, %ecx
		je mods_end
		
		movl 24(%ebx), %esi						# mbi->mods_addr
		movq $init, %rdi
		
		mods_loop:
			
			xorq %rdx, %rdx
			movl 0(%esi), %edx					# mods->mod_start
			movq $0xffff800000000000, %r10
			addq %r10, %rdx
			movq %rdx, 8(%rdi)
			
			xorq %rdx, %rdx
			movl 4(%esi), %edx
			subl 0(%esi), %edx					# mods->mod_end - mods->mod_start
			movq %rdx, 16(%rdi)
			
			addl $16, %esi
			addq $16, %rdi
			
			loop mods_loop
			
		mods_end:
		
		bt $6, %eax								# mbi->flags[6] (mmap_length, mmap_addr valid)	
		jc mmap_valid
			
			xorl %edx, %edx
			jmp mmap_invalid
			
		mmap_valid:
		movl 44(%ebx), %ecx						# mbi->mmap_length
		movl 48(%ebx), %esi						# mbi->mmap_addr
		movq $e820table, %rdi
		xorl %edx, %edx
		
		mmap_loop:
			cmpl $0, %ecx
			jle mmap_end
			
			movl 4(%esi), %eax					# mmap->base_addr_low
			movl %eax, (%rdi)
			
			movl 8(%esi), %eax					# mmap->base_addr_high
			movl %eax, 4(%rdi)
			
			movl 12(%esi), %eax					# mmap->length_low
			movl %eax, 8(%rdi)
			
			movl 16(%esi), %eax					# mmap->length_high
			movl %eax, 12(%rdi)
			
			movl 20(%esi), %eax					# mmap->type
			movl %eax, 16(%rdi)
			
			movl (%esi), %eax					# mmap->size
			addl $0x4, %eax
			addl %eax, %esi
			subl %eax, %ecx
			addq $MEMMAP_E820_RECORD_SIZE, %rdi
			incl %edx
			jmp mmap_loop
		
		mmap_end:
		
		mmap_invalid:
		movl %edx, e820counter
		
	invalid_boot:
	
#ifdef CONFIG_SMP
	
	# copy AP bootstrap routines below 1 MB
	
	movq $BOOT_OFFSET, %rsi
	movq $AP_BOOT_OFFSET, %rdi
	movq $_hardcoded_unmapped_size, %rcx
	cld
	rep movsb
	
#endif
	
	call main_bsp   # never returns
	
	cli
	hlt
 
#ifdef CONFIG_FB
.code32
vesa_init:
	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init
	
.code16
vesa_init_real:
	
	mov %cr0, %eax
	and $~1, %eax
	mov %eax, %cr0
	
	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
	
vesa_init_real2:
	
	mov $VESA_INIT_SEGMENT, %bx
	
	mov %bx, %es
	mov %bx, %fs
	mov %bx, %gs
	mov %bx, %ds
	mov %bx, %ss
	
	movl $0x0000fffc, %esp
    movl $0x0000fffc, %ebp
	
#define VESA_INFO_SIZE 1024
 
#define VESA_MODE_LIST_PTR_OFFSET 14
#define VESA_MODE_WIDTH_OFFSET 18
#define VESA_MODE_HEIGHT_OFFSET 20
#define VESA_MODE_BPP_OFFSET 25
#define VESA_MODE_SCANLINE_OFFSET 16
#define VESA_MODE_PHADDR_OFFSET 40
 
#define VESA_END_OF_MODES 0xffff
 
#define VESA_OK 0x4f
 
#define VESA_GET_INFO 0x4f00
#define VESA_GET_MODE_INFO 0x4f01
#define VESA_SET_MODE 0x4f02
 
#define CONFIG_VESA_BPP_a 255
 
#if CONFIG_VESA_BPP == 24
#undef CONFIG_VESA_BPP_a
#define CONFIG_VESA_BPP_a 32
#endif
	
	mov $VESA_GET_INFO, %ax
	mov $e_vesa_init - vesa_init, %di
	push %di
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
	
	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
	mov %si, %gs
	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
	
	add $VESA_INFO_SIZE, %di
	
1:# Try next mode
	mov %gs:(%si), %cx
	cmp $VESA_END_OF_MODES, %cx
	jz 0f
	
	inc %si
	inc %si
	push %cx
	push %di
	push %si
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %si
	pop %di
	pop %cx
	cmp $VESA_OK, %al
	jnz 0f
	
	mov $CONFIG_VESA_WIDTH, %ax
	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_HEIGHT, %ax
	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_BPP, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
	jz 2f
	
	mov $CONFIG_VESA_BPP_a, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
	jnz 1b
	
2:
	
	mov %cx, %bx
	or $0xc000, %bx
	push %di
	mov $VESA_SET_MODE, %ax
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
	
	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
	shl $16, %eax
	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
	mov VESA_MODE_BPP_OFFSET(%di), %bl
	xor %bh, %bh
	shl $16, %ebx
	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
	mov %eax, %edi
	
8:
	
	mov %cr0, %eax
	or $1, %eax
	mov %eax, %cr0
	
	jmp 9f
9:
	
	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
	
0:# No prefered mode found
	mov $0x111, %cx
	push %di
	push %cx
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %cx
	pop %di
	cmp $VESA_OK, %al
	jnz 1f
	jz 2b						# Force relative jump
 
1:
	mov $0x0003, %ax
	int $0x10
	mov $0xffffffff, %edi		# EGA text mode used, because of problems with VESA
	xor %ax, %ax
	jz 8b						# Force relative jump
	
	
.code32
vesa_init_protect:
	movw $gdtselector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %ds							# kernel data + stack
	movw %cx, %ss
	# Simics seems to remove hidden part of GS on entering user mode
	#  when _visible_ part of GS does not point to user-mode segment
	movw $gdtselector(UDATA_DES), %cx
	movw %cx, %fs
	movw %cx, %gs
	
	movl $START_STACK, %esp			# initialize stack pointer
	
	jmpl $gdtselector(KTEXT32_DES), $vesa_meeting_point
	
.align 4
e_vesa_init:
#endif
 
# Print string from %esi to EGA display (in red) and halt
error_halt:
	movl $0xb8000, %edi						# base of EGA text mode memory
	xorl %eax, %eax
	
	movw $0x3d4, %dx						# read bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	shl $8, %ax
	
	movw $0x3d4, %dx						# read bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	
	cmp $1920, %ax
	jbe cursor_ok
		movw $1920, %ax						# sanity check for the cursor on the last line
	cursor_ok:
	
	movw %ax, %bx
	shl $1, %eax
	addl %eax, %edi
	
	movw $0x0c00, %ax						# black background, light red foreground
	cld
	
	ploop:
		lodsb
		cmp $0, %al
		je ploop_end
		stosw
		inc %bx	
		jmp ploop
	ploop_end:
	
	movw $0x3d4, %dx						# write bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bh, %al
	outb %al, %dx
	
	movw $0x3d4, %dx						# write bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bl, %al
	outb %al, %dx
		
	cli
	hlt
				
.section K_DATA_START, "aw", @progbits
.align 4096
 
# Identical mapping of first 64MB and the same of -2GB -> 0	
.global ptl_2
ptl_2:	
	.quad 0x0 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0xa00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0xc00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0xe00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1000000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1a00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1c00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1e00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2000000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2a00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2c00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2e00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3000000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3a00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3c00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3e00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	
.align 4096
.global ptl_1
ptl_1:
	.quad ptl_2 + (PTL_WRITABLE | PTL_PRESENT)
	.fill 509,8,0
	.quad ptl_2 + (PTL_WRITABLE | PTL_PRESENT)
	.fill 1,8,0
	
.align 4096
.global ptl_0
ptl_0:
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
	.fill 255,8,0
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
	.fill 254,8,0
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
 
.global bootstrap_gdtr
bootstrap_gdtr:
	.word gdtselector(GDT_ITEMS)
	.long KA2PA(gdt)
 
grub_eax:
	.long 0
 
grub_ebx:
	.long 0
 
long_mode_msg:
	.ascii "64 bit long mode not supported. System halted.\0"
 

Rev 2219	Rev 2222
1	#	1	#
2	# Copyright (c) 2005 Ondrej Palkovsky	2	# Copyright (c) 2005 Ondrej Palkovsky
3	# Copyright (c) 2006 Martin Decky	3	# Copyright (c) 2006 Martin Decky
4	# All rights reserved.	4	# All rights reserved.
5	#	5	#
6	# Redistribution and use in source and binary forms, with or without	6	# Redistribution and use in source and binary forms, with or without
7	# modification, are permitted provided that the following conditions	7	# modification, are permitted provided that the following conditions
8	# are met:	8	# are met:
9	#	9	#
10	# - Redistributions of source code must retain the above copyright	10	# - Redistributions of source code must retain the above copyright
11	# notice, this list of conditions and the following disclaimer.	11	# notice, this list of conditions and the following disclaimer.
12	# - Redistributions in binary form must reproduce the above copyright	12	# - Redistributions in binary form must reproduce the above copyright
13	# notice, this list of conditions and the following disclaimer in the	13	# notice, this list of conditions and the following disclaimer in the
14	# documentation and/or other materials provided with the distribution.	14	# documentation and/or other materials provided with the distribution.
15	# - The name of the author may not be used to endorse or promote products	15	# - The name of the author may not be used to endorse or promote products
16	# derived from this software without specific prior written permission.	16	# derived from this software without specific prior written permission.
17	#	17	#
18	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR	18	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
19	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES	19	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
20	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.	20	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
21	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,	21	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
22	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT	22	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
23	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,	23	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY	24	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT	25	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF	26	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
27	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.	27	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28	#	28	#
29		29
30	#include <arch/boot/boot.h>	30	#include <arch/boot/boot.h>
31	#include <arch/boot/memmap.h>	31	#include <arch/boot/memmap.h>
32	#include <arch/mm/page.h>	32	#include <arch/mm/page.h>
33	#include <arch/mm/ptl.h>	33	#include <arch/mm/ptl.h>
34	#include <arch/pm.h>	34	#include <arch/pm.h>
35	#include <arch/cpu.h>	35	#include <arch/cpu.h>
36	#include <arch/cpuid.h>	36	#include <arch/cpuid.h>
37		37
38	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)	38	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
39		39
40	.section K_TEXT_START, "ax"	40	.section K_TEXT_START, "ax"
41		41
42	.code32	42	.code32
43	.align 4	43	.align 4
44	.global multiboot_image_start	44	.global multiboot_image_start
45	multiboot_header:	45	multiboot_header:
46	.long MULTIBOOT_HEADER_MAGIC	46	.long MULTIBOOT_HEADER_MAGIC
47	.long MULTIBOOT_HEADER_FLAGS	47	.long MULTIBOOT_HEADER_FLAGS
48	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum	48	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum
49	.long multiboot_header	49	.long multiboot_header
50	.long unmapped_ktext_start	50	.long unmapped_ktext_start
51	.long 0	51	.long 0
52	.long 0	52	.long 0
53	.long multiboot_image_start	53	.long multiboot_image_start
54		54
55	multiboot_image_start:	55	multiboot_image_start:
56	movl $START_STACK, %esp # initialize stack pointer	56	movl $START_STACK, %esp # initialize stack pointer
57	lgdt bootstrap_gdtr # initialize Global Descriptor Table register	57	lgdt bootstrap_gdtr # initialize Global Descriptor Table register
58		58
59	movw $gdtselector(KDATA_DES), %cx	59	movw $gdtselector(KDATA_DES), %cx
60	movw %cx, %es	60	movw %cx, %es
61	movw %cx, %ds # kernel data + stack	61	movw %cx, %ds # kernel data + stack
62	movw %cx, %ss	62	movw %cx, %ss
63	# Simics seems to remove hidden part of GS on entering user mode	63	# Simics seems to remove hidden part of GS on entering user mode
64	# when _visible_ part of GS does not point to user-mode segment	64	# when _visible_ part of GS does not point to user-mode segment
65	movw $gdtselector(UDATA_DES), %cx	65	movw $gdtselector(UDATA_DES), %cx
66	movw %cx, %fs	66	movw %cx, %fs
67	movw %cx, %gs	67	movw %cx, %gs
68		68
69	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point	69	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point
70	multiboot_meeting_point:	70	multiboot_meeting_point:
71		71
72	movl %eax, grub_eax # save parameters from GRUB	72	movl %eax, grub_eax # save parameters from GRUB
73	movl %ebx, grub_ebx	73	movl %ebx, grub_ebx
74		74
75	# Protected 32-bit. We want to reuse the code-seg descriptor,	75	# Protected 32-bit. We want to reuse the code-seg descriptor,
76	# the Default operand size must not be 1 when entering long mode	76	# the Default operand size must not be 1 when entering long mode
77		77
78	movl $0x80000000, %eax	78	movl $0x80000000, %eax
79	cpuid	79	cpuid
80	cmp $0x80000000, %eax # any function > 80000000h?	80	cmp $0x80000000, %eax # any function > 80000000h?
81	jbe long_mode_unsupported	81	jbe long_mode_unsupported
82	movl $(AMD_CPUID_EXTENDED), %eax # Extended function code 80000001	82	movl $(AMD_CPUID_EXTENDED), %eax # Extended function code 80000001
83	cpuid	83	cpuid
84	bt $29, %edx # Test if long mode is supported.	84	bt $29, %edx # Test if long mode is supported.
85	jc long_mode_supported	85	jc long_mode_supported
86		86
87	long_mode_unsupported:	87	long_mode_unsupported:
88	movl $long_mode_msg, %esi	88	movl $long_mode_msg, %esi
89	jmp error_halt	89	jmp error_halt
90		90
91	long_mode_supported:	91	long_mode_supported:
92		92
93	#ifdef CONFIG_FB	93	#ifdef CONFIG_FB
94	mov $vesa_init, %esi	94	mov $vesa_init, %esi
95	mov $VESA_INIT_SEGMENT << 4, %edi	95	mov $VESA_INIT_SEGMENT << 4, %edi
96	mov $e_vesa_init - vesa_init, %ecx	96	mov $e_vesa_init - vesa_init, %ecx
97	cld	97	cld
98	rep movsb	98	rep movsb
99		99
100	mov $VESA_INIT_SEGMENT << 4, %edi	100	mov $VESA_INIT_SEGMENT << 4, %edi
101	jmpl *%edi	101	jmpl *%edi
102		102
103	vesa_meeting_point:	103	vesa_meeting_point:
104		104
105	mov %esi, KA2PA(vesa_ph_addr)	105	mov %esi, KA2PA(vesa_ph_addr)
106	mov %di, KA2PA(vesa_height)	106	mov %di, KA2PA(vesa_height)
107	shr $16, %edi	107	shr $16, %edi
108	mov %di, KA2PA(vesa_width)	108	mov %di, KA2PA(vesa_width)
109	mov %bx, KA2PA(vesa_scanline)	109	mov %bx, KA2PA(vesa_scanline)
110	shr $16, %ebx	110	shr $16, %ebx
111	mov %bx, KA2PA(vesa_bpp)	111	mov %bx, KA2PA(vesa_bpp)
112	#endif	112	#endif
113		113
114	# Enable 64-bit page transaltion entries - CR4.PAE = 1.	114	# Enable 64-bit page transaltion entries - CR4.PAE = 1.
115	# Paging is not enabled until after long mode is enabled	115	# Paging is not enabled until after long mode is enabled
116		116
117	movl %cr4, %eax	117	movl %cr4, %eax
118	btsl $5, %eax	118	btsl $5, %eax
119	movl %eax, %cr4	119	movl %eax, %cr4
120		120
121	# Set up paging tables	121	# Set up paging tables
122		122
123	leal ptl_0, %eax	123	leal ptl_0, %eax
124	movl %eax, %cr3	124	movl %eax, %cr3
125		125
126	# Enable long mode	126	# Enable long mode
127		127
128	movl $EFER_MSR_NUM, %ecx # EFER MSR number	128	movl $EFER_MSR_NUM, %ecx # EFER MSR number
129	rdmsr # Read EFER	129	rdmsr # Read EFER
130	btsl $AMD_LME_FLAG, %eax # Set LME=1	130	btsl $AMD_LME_FLAG, %eax # Set LME=1
131	wrmsr # Write EFER	131	wrmsr # Write EFER
132		132
133	# Enable paging to activate long mode (set CR0.PG=1)	133	# Enable paging to activate long mode (set CR0.PG=1)
134		134
135	movl %cr0, %eax	135	movl %cr0, %eax
136	btsl $31, %eax	136	btsl $31, %eax
137	movl %eax, %cr0	137	movl %eax, %cr0
138		138
139	# At this point we are in compatibility mode	139	# At this point we are in compatibility mode
140		140
141	jmpl $gdtselector(KTEXT_DES), $start64	141	jmpl $gdtselector(KTEXT_DES), $start64
142		142
143	.code64	143	.code64
144	start64:	144	start64:
145	movq $(PA2KA(START_STACK)), %rsp	145	movq $(PA2KA(START_STACK)), %rsp
146	movl grub_eax, %eax	146	movl grub_eax, %eax
147	movl grub_ebx, %ebx	147	movl grub_ebx, %ebx
148		148
149	cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature	149	cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature
150	je valid_boot	150	je valid_boot
151		151
152	xorl %ecx, %ecx # no memory size or map available	152	xorl %ecx, %ecx # no memory size or map available
153	movl %ecx, e801memorysize	153	movl %ecx, e801memorysize
154	movl %ecx, e820counter	154	movl %ecx, e820counter
155		155
156	jmp invalid_boot	156	jmp invalid_boot
157		157
158	valid_boot:	158	valid_boot:
159		159
160	movl (%ebx), %eax # ebx = physical address of struct multiboot_info	160	movl (%ebx), %eax # ebx = physical address of struct multiboot_info
161		161
162	bt $0, %eax # mbi->flags[0] (mem_lower, mem_upper valid)	162	bt $0, %eax # mbi->flags[0] (mem_lower, mem_upper valid)
163	jc mem_valid	163	jc mem_valid
164		164
165	xorl %ecx, %ecx	165	xorl %ecx, %ecx
166	jmp mem_invalid	166	jmp mem_invalid
167		167
168	mem_valid:	168	mem_valid:
169	movl 4(%ebx), %ecx # mbi->mem_lower	169	movl 4(%ebx), %ecx # mbi->mem_lower
170	addl 8(%ebx), %ecx # mbi->mem_upper	170	addl 8(%ebx), %ecx # mbi->mem_upper
171		171
172	mem_invalid:	172	mem_invalid:
173	movl %ecx, e801memorysize	173	movl %ecx, e801memorysize
174		174
175	bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)	175	bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)
176	jc mods_valid	176	jc mods_valid
177		177
178	xorq %rcx, %rcx	178	xorq %rcx, %rcx
179	movq %rcx, init	179	movq %rcx, init
180	jmp mods_end	180	jmp mods_end
181		181
182	mods_valid:	182	mods_valid:
183		183
184	xorq %rcx, %rcx	184	xorq %rcx, %rcx
185	movl 20(%ebx), %ecx # mbi->mods_count	185	movl 20(%ebx), %ecx # mbi->mods_count
186	movq %rcx, init	186	movq %rcx, init
187		187
188	cmpl $0, %ecx	188	cmpl $0, %ecx
189	je mods_end	189	je mods_end
190		190
191	movl 24(%ebx), %esi # mbi->mods_addr	191	movl 24(%ebx), %esi # mbi->mods_addr
192	movq $init, %rdi	192	movq $init, %rdi
193		193
194	mods_loop:	194	mods_loop:
195		195
196	xorq %rdx, %rdx	196	xorq %rdx, %rdx
197	movl 0(%esi), %edx # mods->mod_start	197	movl 0(%esi), %edx # mods->mod_start
198	movq $0xffff800000000000, %r10	198	movq $0xffff800000000000, %r10
199	addq %r10, %rdx	199	addq %r10, %rdx
200	movq %rdx, 8(%rdi)	200	movq %rdx, 8(%rdi)
201		201
202	xorq %rdx, %rdx	202	xorq %rdx, %rdx
203	movl 4(%esi), %edx	203	movl 4(%esi), %edx
204	subl 0(%esi), %edx # mods->mod_end - mods->mod_start	204	subl 0(%esi), %edx # mods->mod_end - mods->mod_start
205	movq %rdx, 16(%rdi)	205	movq %rdx, 16(%rdi)
206		206
207	addl $16, %esi	207	addl $16, %esi
208	addq $16, %rdi	208	addq $16, %rdi
209		209
210	loop mods_loop	210	loop mods_loop
211		211
212	mods_end:	212	mods_end:
213		213
214	bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)	214	bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)
215	jc mmap_valid	215	jc mmap_valid
216		216
217	xorl %edx, %edx	217	xorl %edx, %edx
218	jmp mmap_invalid	218	jmp mmap_invalid
219		219
220	mmap_valid:	220	mmap_valid:
221	movl 44(%ebx), %ecx # mbi->mmap_length	221	movl 44(%ebx), %ecx # mbi->mmap_length
222	movl 48(%ebx), %esi # mbi->mmap_addr	222	movl 48(%ebx), %esi # mbi->mmap_addr
223	movq $e820table, %rdi	223	movq $e820table, %rdi
224	xorl %edx, %edx	224	xorl %edx, %edx
225		225
226	mmap_loop:	226	mmap_loop:
227	cmpl $0, %ecx	227	cmpl $0, %ecx
228	jle mmap_end	228	jle mmap_end
229		229
230	movl 4(%esi), %eax # mmap->base_addr_low	230	movl 4(%esi), %eax # mmap->base_addr_low
231	movl %eax, (%rdi)	231	movl %eax, (%rdi)
232		232
233	movl 8(%esi), %eax # mmap->base_addr_high	233	movl 8(%esi), %eax # mmap->base_addr_high
234	movl %eax, 4(%rdi)	234	movl %eax, 4(%rdi)
235		235
236	movl 12(%esi), %eax # mmap->length_low	236	movl 12(%esi), %eax # mmap->length_low
237	movl %eax, 8(%rdi)	237	movl %eax, 8(%rdi)
238		238
239	movl 16(%esi), %eax # mmap->length_high	239	movl 16(%esi), %eax # mmap->length_high
240	movl %eax, 12(%rdi)	240	movl %eax, 12(%rdi)
241		241
242	movl 20(%esi), %eax # mmap->type	242	movl 20(%esi), %eax # mmap->type
243	movl %eax, 16(%rdi)	243	movl %eax, 16(%rdi)
244		244
245	movl (%esi), %eax # mmap->size	245	movl (%esi), %eax # mmap->size
246	addl $0x4, %eax	246	addl $0x4, %eax
247	addl %eax, %esi	247	addl %eax, %esi
248	subl %eax, %ecx	248	subl %eax, %ecx
249	addq $MEMMAP_E820_RECORD_SIZE, %rdi	249	addq $MEMMAP_E820_RECORD_SIZE, %rdi
250	incl %edx	250	incl %edx
251	jmp mmap_loop	251	jmp mmap_loop
252		252
253	mmap_end:	253	mmap_end:
254		254
255	mmap_invalid:	255	mmap_invalid:
256	movl %edx, e820counter	256	movl %edx, e820counter
257		257
258	invalid_boot:	258	invalid_boot:
259		259
260	#ifdef CONFIG_SMP	260	#ifdef CONFIG_SMP
261		261
262	# copy AP bootstrap routines below 1 MB	262	# copy AP bootstrap routines below 1 MB
263		263
264	movq $BOOT_OFFSET, %rsi	264	movq $BOOT_OFFSET, %rsi
265	movq $AP_BOOT_OFFSET, %rdi	265	movq $AP_BOOT_OFFSET, %rdi
266	movq $_hardcoded_unmapped_size, %rcx	266	movq $_hardcoded_unmapped_size, %rcx
267	cld	267	cld
268	rep movsb	268	rep movsb
269		269
270	#endif	270	#endif
271		271
272	call main_bsp # never returns	272	call main_bsp # never returns
273		273
274	cli	274	cli
275	hlt	275	hlt
276		276
277	#ifdef CONFIG_FB	277	#ifdef CONFIG_FB
278	.code32	278	.code32
279	vesa_init:	279	vesa_init:
280	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init	280	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init
281		281
282	.code16	282	.code16
283	vesa_init_real:	283	vesa_init_real:
284		284
285	mov %cr0, %eax	285	mov %cr0, %eax
286	and $~1, %eax	286	and $~1, %eax
287	mov %eax, %cr0	287	mov %eax, %cr0
288		288
289	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init	289	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
290		290
291	vesa_init_real2:	291	vesa_init_real2:
292		292
293	mov $VESA_INIT_SEGMENT, %bx	293	mov $VESA_INIT_SEGMENT, %bx
294		294
295	mov %bx, %es	295	mov %bx, %es
296	mov %bx, %fs	296	mov %bx, %fs
297	mov %bx, %gs	297	mov %bx, %gs
298	mov %bx, %ds	298	mov %bx, %ds
299	mov %bx, %ss	299	mov %bx, %ss
300		300
301	movl $0x0000fffc, %esp	301	movl $0x0000fffc, %esp
302	movl $0x0000fffc, %ebp	302	movl $0x0000fffc, %ebp
303		303
304	#define VESA_INFO_SIZE 1024	304	#define VESA_INFO_SIZE 1024
305		305
306	#define VESA_MODE_LIST_PTR_OFFSET 14	306	#define VESA_MODE_LIST_PTR_OFFSET 14
307	#define VESA_MODE_WIDTH_OFFSET 18	307	#define VESA_MODE_WIDTH_OFFSET 18
308	#define VESA_MODE_HEIGHT_OFFSET 20	308	#define VESA_MODE_HEIGHT_OFFSET 20
309	#define VESA_MODE_BPP_OFFSET 25	309	#define VESA_MODE_BPP_OFFSET 25
310	#define VESA_MODE_SCANLINE_OFFSET 16	310	#define VESA_MODE_SCANLINE_OFFSET 16
311	#define VESA_MODE_PHADDR_OFFSET 40	311	#define VESA_MODE_PHADDR_OFFSET 40
312		312
313	#define VESA_END_OF_MODES 0xffff	313	#define VESA_END_OF_MODES 0xffff
314		314
315	#define VESA_OK 0x4f	315	#define VESA_OK 0x4f
316		316
317	#define VESA_GET_INFO 0x4f00	317	#define VESA_GET_INFO 0x4f00
318	#define VESA_GET_MODE_INFO 0x4f01	318	#define VESA_GET_MODE_INFO 0x4f01
319	#define VESA_SET_MODE 0x4f02	319	#define VESA_SET_MODE 0x4f02
320		320
321	#define CONFIG_VESA_BPP_a 255	321	#define CONFIG_VESA_BPP_a 255
322		322
323	#if CONFIG_VESA_BPP == 24	323	#if CONFIG_VESA_BPP == 24
324	#undef CONFIG_VESA_BPP_a	324	#undef CONFIG_VESA_BPP_a
325	#define CONFIG_VESA_BPP_a 32	325	#define CONFIG_VESA_BPP_a 32
326	#endif	326	#endif
327		327
328	mov $VESA_GET_INFO, %ax	328	mov $VESA_GET_INFO, %ax
329	mov $e_vesa_init - vesa_init, %di	329	mov $e_vesa_init - vesa_init, %di
330	push %di	330	push %di
331	int $0x10	331	int $0x10
332		332
333	pop %di	333	pop %di
334	cmp $VESA_OK, %al	334	cmp $VESA_OK, %al
335	jnz 0f	335	jnz 0f
336		336
337	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si	337	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
338	mov %si, %gs	338	mov %si, %gs
339	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si	339	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
340		340
341	add $VESA_INFO_SIZE, %di	341	add $VESA_INFO_SIZE, %di
342		342
343	1:# Try next mode	343	1:# Try next mode
344	mov %gs:(%si), %cx	344	mov %gs:(%si), %cx
345	cmp $VESA_END_OF_MODES, %cx	345	cmp $VESA_END_OF_MODES, %cx
346	jz 0f	346	jz 0f
347		347
348	inc %si	348	inc %si
349	inc %si	349	inc %si
350	push %cx	350	push %cx
351	push %di	351	push %di
352	push %si	352	push %si
353	mov $VESA_GET_MODE_INFO, %ax	353	mov $VESA_GET_MODE_INFO, %ax
354	int $0x10	354	int $0x10
355		355
356	pop %si	356	pop %si
357	pop %di	357	pop %di
358	pop %cx	358	pop %cx
359	cmp $VESA_OK, %al	359	cmp $VESA_OK, %al
360	jnz 0f	360	jnz 0f
361		361
362	mov $CONFIG_VESA_WIDTH, %ax	362	mov $CONFIG_VESA_WIDTH, %ax
363	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax	363	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
364	jnz 1b	364	jnz 1b
365		365
366	mov $CONFIG_VESA_HEIGHT, %ax	366	mov $CONFIG_VESA_HEIGHT, %ax
367	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax	367	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
368	jnz 1b	368	jnz 1b
369		369
370	mov $CONFIG_VESA_BPP, %al	370	mov $CONFIG_VESA_BPP, %al
371	cmp VESA_MODE_BPP_OFFSET(%di), %al	371	cmp VESA_MODE_BPP_OFFSET(%di), %al
372	jz 2f	372	jz 2f
373		373
374	mov $CONFIG_VESA_BPP_a, %al	374	mov $CONFIG_VESA_BPP_a, %al
375	cmp VESA_MODE_BPP_OFFSET(%di), %al	375	cmp VESA_MODE_BPP_OFFSET(%di), %al
376	jnz 1b	376	jnz 1b
377		377
378	2:	378	2:
379		379
380	mov %cx, %bx	380	mov %cx, %bx
381	or $0xc000, %bx	381	or $0xc000, %bx
382	push %di	382	push %di
383	mov $VESA_SET_MODE, %ax	383	mov $VESA_SET_MODE, %ax
384	int $0x10	384	int $0x10
385		385
386	pop %di	386	pop %di
387	cmp $VESA_OK, %al	387	cmp $VESA_OK, %al
388	jnz 0f	388	jnz 0f
389		389
390	mov VESA_MODE_PHADDR_OFFSET(%di), %esi	390	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
391	mov VESA_MODE_WIDTH_OFFSET(%di), %ax	391	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
392	shl $16, %eax	392	shl $16, %eax
393	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax	393	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
394	mov VESA_MODE_BPP_OFFSET(%di), %bl	394	mov VESA_MODE_BPP_OFFSET(%di), %bl
395	xor %bh, %bh	395	xor %bh, %bh
396	shl $16, %ebx	396	shl $16, %ebx
397	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx	397	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
398	mov %eax, %edi	398	mov %eax, %edi
399		399
400	8:	400	8:
401		401
402	mov %cr0, %eax	402	mov %cr0, %eax
403	or $1, %eax	403	or $1, %eax
404	mov %eax, %cr0	404	mov %eax, %cr0
405		405
406	jmp 9f	406	jmp 9f
407	9:	407	9:
408		408
409	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)	409	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
410		410
411	0:# No prefered mode found	411	0:# No prefered mode found
412	mov $0x111, %cx	412	mov $0x111, %cx
413	push %di	413	push %di
414	push %cx	414	push %cx
415	mov $VESA_GET_MODE_INFO, %ax	415	mov $VESA_GET_MODE_INFO, %ax
416	int $0x10	416	int $0x10
417		417
418	pop %cx	418	pop %cx
419	pop %di	419	pop %di
420	cmp $VESA_OK, %al	420	cmp $VESA_OK, %al
421	jnz 1f	421	jnz 1f
422	jz 2b # Force relative jump	422	jz 2b # Force relative jump
423		423
424	1:	424	1:
425	mov $0x0003, %ax	425	mov $0x0003, %ax
426	int $0x10	426	int $0x10
427	mov $0xffffffff, %edi # EGA text mode used, because of problems with VESA	427	mov $0xffffffff, %edi # EGA text mode used, because of problems with VESA
428	xor %ax, %ax	428	xor %ax, %ax
429	jz 8b # Force relative jump	429	jz 8b # Force relative jump
430		430
431		431
432	.code32	432	.code32
433	vesa_init_protect:	433	vesa_init_protect:
434	movw $gdtselector(KDATA_DES), %cx	434	movw $gdtselector(KDATA_DES), %cx
435	movw %cx, %es	435	movw %cx, %es
436	movw %cx, %ds # kernel data + stack	436	movw %cx, %ds # kernel data + stack
437	movw %cx, %ss	437	movw %cx, %ss
438	# Simics seems to remove hidden part of GS on entering user mode	438	# Simics seems to remove hidden part of GS on entering user mode
439	# when _visible_ part of GS does not point to user-mode segment	439	# when _visible_ part of GS does not point to user-mode segment
440	movw $gdtselector(UDATA_DES), %cx	440	movw $gdtselector(UDATA_DES), %cx
441	movw %cx, %fs	441	movw %cx, %fs
442	movw %cx, %gs	442	movw %cx, %gs
443		443
-		444	movl $START_STACK, %esp # initialize stack pointer
-		445
444	jmpl $gdtselector(KTEXT32_DES), $vesa_meeting_point	446	jmpl $gdtselector(KTEXT32_DES), $vesa_meeting_point
445		447
446	.align 4	448	.align 4
447	e_vesa_init:	449	e_vesa_init:
448	#endif	450	#endif
449		451
450	# Print string from %esi to EGA display (in red) and halt	452	# Print string from %esi to EGA display (in red) and halt
451	error_halt:	453	error_halt:
452	movl $0xb8000, %edi # base of EGA text mode memory	454	movl $0xb8000, %edi # base of EGA text mode memory
453	xorl %eax, %eax	455	xorl %eax, %eax
454		456
455	movw $0x3d4, %dx # read bits 8 - 15 of the cursor address	457	movw $0x3d4, %dx # read bits 8 - 15 of the cursor address
456	movb $0xe, %al	458	movb $0xe, %al
457	outb %al, %dx	459	outb %al, %dx
458		460
459	movw $0x3d5, %dx	461	movw $0x3d5, %dx
460	inb %dx, %al	462	inb %dx, %al
461	shl $8, %ax	463	shl $8, %ax
462		464
463	movw $0x3d4, %dx # read bits 0 - 7 of the cursor address	465	movw $0x3d4, %dx # read bits 0 - 7 of the cursor address
464	movb $0xf, %al	466	movb $0xf, %al
465	outb %al, %dx	467	outb %al, %dx
466		468
467	movw $0x3d5, %dx	469	movw $0x3d5, %dx
468	inb %dx, %al	470	inb %dx, %al
469		471
470	cmp $1920, %ax	472	cmp $1920, %ax
471	jbe cursor_ok	473	jbe cursor_ok
472	movw $1920, %ax # sanity check for the cursor on the last line	474	movw $1920, %ax # sanity check for the cursor on the last line
473	cursor_ok:	475	cursor_ok:
474		476
475	movw %ax, %bx	477	movw %ax, %bx
476	shl $1, %eax	478	shl $1, %eax
477	addl %eax, %edi	479	addl %eax, %edi
478		480
479	movw $0x0c00, %ax # black background, light red foreground	481	movw $0x0c00, %ax # black background, light red foreground
480	cld	482	cld
481		483
482	ploop:	484	ploop:
483	lodsb	485	lodsb
484	cmp $0, %al	486	cmp $0, %al
485	je ploop_end	487	je ploop_end
486	stosw	488	stosw
487	inc %bx	489	inc %bx
488	jmp ploop	490	jmp ploop
489	ploop_end:	491	ploop_end:
490		492
491	movw $0x3d4, %dx # write bits 8 - 15 of the cursor address	493	movw $0x3d4, %dx # write bits 8 - 15 of the cursor address
492	movb $0xe, %al	494	movb $0xe, %al
493	outb %al, %dx	495	outb %al, %dx
494		496
495	movw $0x3d5, %dx	497	movw $0x3d5, %dx
496	movb %bh, %al	498	movb %bh, %al
497	outb %al, %dx	499	outb %al, %dx
498		500

Subversion Repositories HelenOS

(root)/trunk/kernel/arch/amd64/src/boot/boot.S – Rev 2219 → 2222