WebSVN – HelenOS – Diff – /trunk/kernel/arch/amd64/src/boot/boot.S


#
# Copyright (c) 2005 Ondrej Palkovsky
# Copyright (c) 2006 Martin Decky
# Copyright (c) 2008 Jakub Jermar
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
#
# - Redistributions of source code must retain the above copyright
#   notice, this list of conditions and the following disclaimer.
# - Redistributions in binary form must reproduce the above copyright
#   notice, this list of conditions and the following disclaimer in the
#   documentation and/or other materials provided with the distribution.
# - The name of the author may not be used to endorse or promote products
#   derived from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
#
 
#include <arch/boot/boot.h>
#include <arch/boot/memmap.h>
#include <arch/mm/page.h>	
#include <arch/mm/ptl.h>
#include <arch/pm.h>
#include <arch/cpu.h>
#include <arch/cpuid.h>
 
#define START_STACK	(BOOT_OFFSET - BOOT_STACK_SIZE)
	
.section K_TEXT_START, "ax"
 
.code32
.align 4
.global multiboot_image_start
multiboot_header:
	.long MULTIBOOT_HEADER_MAGIC
	.long MULTIBOOT_HEADER_FLAGS
	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS)	# checksum
	.long multiboot_header
	.long unmapped_ktext_start
	.long 0
	.long 0
	.long multiboot_image_start
 
multiboot_image_start:
	cld
	movl $START_STACK, %esp			# initialize stack pointer
	lgdtl bootstrap_gdtr			# initialize Global Descriptor Table register
 
	movw $gdtselector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %ds							# kernel data + stack
	movw %cx, %ss
	# Simics seems to remove hidden part of GS on entering user mode
	#  when _visible_ part of GS does not point to user-mode segment
	movw $gdtselector(UDATA_DES), %cx
	movw %cx, %fs
	movw %cx, %gs
	
	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point
	multiboot_meeting_point:
	
	movl %eax, grub_eax						# save parameters from GRUB
	movl %ebx, grub_ebx
	
	# Protected 32-bit. We want to reuse the code-seg descriptor,
	# the Default operand size must not be 1 when entering long mode
	
	movl $(INTEL_CPUID_EXTENDED), %eax  
 	cpuid
 	cmp $(INTEL_CPUID_EXTENDED), %eax
	ja extended_cpuid_supported
		
		movl $extended_cpuid_msg, %esi
		jmp error_halt
	
	extended_cpuid_supported:
	
	movl $(AMD_CPUID_EXTENDED), %eax
	cpuid
	bt $(AMD_EXT_LONG_MODE), %edx
 	jc long_mode_supported
		
		movl $long_mode_msg, %esi
		jmp error_halt
 
	long_mode_supported:
	
	bt $(AMD_EXT_NOEXECUTE), %edx
	jc noexecute_supported
	
		movl $noexecute_msg, %esi
		jmp error_halt
	
	noexecute_supported:
	
	movl $(INTEL_CPUID_STANDARD), %eax
	cpuid
	bt $(INTEL_FXSAVE), %edx
 	jc fx_supported
	
		movl $fx_msg, %esi
		jmp error_halt
	
	fx_supported:
	
	bt $(INTEL_SSE2), %edx
 	jc sse2_supported
	
		movl $sse2_msg, %esi
		jmp error_halt
	
	sse2_supported:
	
#ifdef CONFIG_FB
	mov $vesa_init, %esi
	mov $VESA_INIT_SEGMENT << 4, %edi
	mov $e_vesa_init - vesa_init, %ecx
	rep movsb
 
	mov $VESA_INIT_SEGMENT << 4, %edi
	jmpl *%edi
	
	vesa_meeting_point:
	
	mov %esi, KA2PA(vesa_ph_addr)
	mov %di, KA2PA(vesa_height)
	shr $16, %edi
	mov %di, KA2PA(vesa_width)
	mov %bx, KA2PA(vesa_scanline)
	shr $16, %ebx
	mov %bx, KA2PA(vesa_bpp)
#endif	
	
	# Enable 64-bit page translation entries - CR4.PAE = 1.
	# Paging is not enabled until after long mode is enabled
	
	movl %cr4, %eax
	btsl $5, %eax
	movl %eax, %cr4
 
	# Set up paging tables
	
	leal ptl_0, %eax
	movl %eax, %cr3
	
	# Enable long mode
	
	movl $EFER_MSR_NUM, %ecx			# EFER MSR number
	rdmsr						# Read EFER
	btsl $AMD_LME_FLAG, %eax			# Set LME = 1
	wrmsr						# Write EFER
	
	# Enable paging to activate long mode (set CR0.PG = 1)
	
	movl %cr0, %eax
	btsl $31, %eax
	movl %eax, %cr0
	
	# At this point we are in compatibility mode
	
	jmpl $gdtselector(KTEXT_DES), $start64
 
.code64
start64:
	movq $(PA2KA(START_STACK)), %rsp
 
	# arch_pre_main(grub_eax, grub_ebx)
	xorq %rdi, %rdi
	movl grub_eax, %edi
	xorq %rsi, %rsi
	movl grub_ebx, %esi
	call arch_pre_main
 
	call main_bsp
 
	# Not reached.
	
	cli
	hlt
 
#ifdef CONFIG_FB
.code32
vesa_init:
	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init
	
.code16
vesa_init_real:
	
	mov %cr0, %eax
	and $~1, %eax
	mov %eax, %cr0
	
	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
	
vesa_init_real2:
	
	mov $VESA_INIT_SEGMENT, %bx
	
	mov %bx, %es
	mov %bx, %fs
	mov %bx, %gs
	mov %bx, %ds
	mov %bx, %ss
	
	movl $0x0000fffc, %esp
	movl $0x0000fffc, %ebp
	
#define VESA_INFO_SIZE 1024
 
#define VESA_MODE_ATTRIBUTES_OFFSET 0
#define VESA_MODE_LIST_PTR_OFFSET 14
#define VESA_MODE_SCANLINE_OFFSET 16
#define VESA_MODE_WIDTH_OFFSET 18
#define VESA_MODE_HEIGHT_OFFSET 20
#define VESA_MODE_BPP_OFFSET 25
#define VESA_MODE_PHADDR_OFFSET 40
 
#define VESA_END_OF_MODES 0xffff
 
#define VESA_OK 0x4f
 
#define VESA_GET_INFO 0x4f00
#define VESA_GET_MODE_INFO 0x4f01
#define VESA_SET_MODE 0x4f02
#define VESA_SET_PALETTE 0x4f09
 
#define CONFIG_VESA_BPP_a 255
 
#if CONFIG_VESA_BPP == 24
#define CONFIG_VESA_BPP_VARIANT 32
#endif
 
	mov $VESA_GET_INFO, %ax
	mov $e_vesa_init - vesa_init, %di
	push %di
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
	
	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
	mov %si, %gs
	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
	
	add $VESA_INFO_SIZE, %di
 
1:# Try next mode
	mov %gs:(%si), %cx
	cmp $VESA_END_OF_MODES, %cx
	jz 0f
	
	inc %si
	inc %si
	push %cx
	push %di
	push %si
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %si
	pop %di
	pop %cx
	cmp $VESA_OK, %al
	jnz 0f
	
	mov $CONFIG_VESA_WIDTH, %ax
	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_HEIGHT, %ax
	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_BPP, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
 
#ifdef CONFIG_VESA_BPP_VARIANT
	jz 2f
	
	mov $CONFIG_VESA_BPP_VARIANT, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
#endif
	jnz 1b
	
2:
	
	mov %cx, %bx
	or $0xc000, %bx
	push %di
	mov $VESA_SET_MODE, %ax
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
 
#if CONFIG_VESA_BPP == 8
	
	# Set 3:2:3 VGA palette
	
	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax
	push %di
	mov $vga323 - vesa_init, %di
	mov $0x100, %ecx
	
	bt $5, %ax						# Test if VGA compatible registers are present
	jnc vga_compat
		
		# Try VESA routine to set palette
		
		mov $VESA_SET_PALETTE, %ax
		xor %bl, %bl
		xor %dx, %dx
		int $0x10
		
		cmp $0x00, %ah
		je vga_not_compat
	
	vga_compat:
		
		# Try VGA registers to set palette
		
		movw $0x3c6, %dx				# Set palette mask
		movb $0xff, %al
		outb %al, %dx
		
		movw $0x3c8, %dx				# First index to set
		xor %al, %al
		outb %al, %dx
		
		movw $0x3c9, %dx				# Data port
		vga_loop:
			movb %es:2(%di), %al
			outb %al, %dx
			
			movb %es:1(%di), %al
			outb %al, %dx
			
			movb %es:(%di), %al
			outb %al, %dx
			
			addw $4, %di
			loop vga_loop
		
	vga_not_compat:
	
	pop %di
	
#endif
	
	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
	shl $16, %eax
	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
	mov VESA_MODE_BPP_OFFSET(%di), %bl
	xor %bh, %bh
	shl $16, %ebx
	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
	mov %eax, %edi
	
8:
	
	mov %cr0, %eax
	or $1, %eax
	mov %eax, %cr0
	
	jmp 9f
9:
	
	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
	
0:# No prefered mode found
	mov $0x111, %cx
	push %di
	push %cx
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %cx
	pop %di
	cmp $VESA_OK, %al
	jnz 1f
	jz 2b						# Force relative jump
 
1:
	mov $0x0003, %ax
	int $0x10
	mov $0xffffffff, %edi				# EGA text mode used, because of problems with VESA
	xor %ax, %ax
	jz 8b						# Force relative jump
 
vga323:
#include "vga323.pal"	
	
.code32
vesa_init_protect:
	movw $gdtselector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %ds					# kernel data + stack
	movw %cx, %ss
	# Simics seems to remove hidden part of GS on entering user mode
	#  when _visible_ part of GS does not point to user-mode segment
	movw $gdtselector(UDATA_DES), %cx
	movw %cx, %fs
	movw %cx, %gs
	
	movl $START_STACK, %esp				# initialize stack pointer
	
	jmpl $gdtselector(KTEXT32_DES), $vesa_meeting_point
	
.align 4
e_vesa_init:
#endif
 
# Print string from %esi to EGA display (in red) and halt
error_halt:
	movl $0xb8000, %edi				# base of EGA text mode memory
	xorl %eax, %eax
	
	movw $0x3d4, %dx				# read bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	shl $8, %ax
	
	movw $0x3d4, %dx				# read bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	
	cmp $1920, %ax
	jbe cursor_ok
		movw $1920, %ax				# sanity check for the cursor on the last line
	cursor_ok:
	
	movw %ax, %bx
	shl $1, %eax
	addl %eax, %edi
	
	movw $0x0c00, %ax				# black background, light red foreground
	
	ploop:
		lodsb
		cmp $0, %al
		je ploop_end
		stosw
		inc %bx	
		jmp ploop
	ploop_end:
	
	movw $0x3d4, %dx				# write bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bh, %al
	outb %al, %dx
	
	movw $0x3d4, %dx				# write bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bl, %al
	outb %al, %dx
		
	cli
	hlt
				
 
.section K_INI_PTLS, "aw", @progbits
 
#
# Macro for generating initial page table contents.
# @param cnt	Number of entries to generat. Must be multiple of 8.
# @param g	Number of GB that will be added to the mapping.
#
.macro ptl2gen cnt g 
.if \cnt
	ptl2gen "\cnt - 8" \g 
	.quad ((\cnt - 8) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 7) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 6) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 5) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 4) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 3) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 2) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad ((\cnt - 1) * 0x200000) + (\g * 1024 * 1024 * 1024) | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
.endif
.endm
 
# Page table for pages in the first gigabyte.
.align 4096
.global ptl_2_0g
ptl_2_0g:	
	ptl2gen 512 0
 
# Page table for pages in the second gigabyte.
.align 4096
.global ptl_2_1g
ptl_2_1g:
	ptl2gen 512 1
 
# Page table for pages in the third gigabyte.
.align 4096
.global ptl_2_2g
ptl_2_2g:
	ptl2gen 512 2
 
# Page table for pages in the fourth gigabyte.
.align 4096
.global ptl_2_3g
ptl_2_3g:
	ptl2gen 512 3
 
.align 4096
.global ptl_1
ptl_1:
	# Identity mapping for [0; 4G)
	.quad ptl_2_0g + (PTL_WRITABLE | PTL_PRESENT)
	.quad ptl_2_1g + (PTL_WRITABLE | PTL_PRESENT) 
	.quad ptl_2_2g + (PTL_WRITABLE | PTL_PRESENT)
	.quad ptl_2_3g + (PTL_WRITABLE | PTL_PRESENT)
	.fill 506, 8, 0
	# Mapping of [0; 1G) at -2G
	.quad ptl_2_0g + (PTL_WRITABLE | PTL_PRESENT)
	.fill 1, 8, 0
	
.align 4096
.global ptl_0
ptl_0:
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
	.fill 255,8,0
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
	.fill 254,8,0
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
 
.section K_DATA_START, "aw", @progbits
 
.global bootstrap_gdtr
bootstrap_gdtr:
	.word gdtselector(GDT_ITEMS)
	.long KA2PA(gdt)
 
grub_eax:
	.long 0
 
grub_ebx:
	.long 0
 
extended_cpuid_msg:
	.asciz "Extended CPUID not supported. System halted."
long_mode_msg:
	.asciz "64 bit long mode not supported. System halted."
noexecute_msg:
	.asciz "No-execute pages not supported. System halted."
fx_msg:
	.asciz "FXSAVE/FXRESTORE instructions not supported. System halted."
sse2_msg:
	.asciz "SSE2 instructions not supported. System halted."
 

Rev 4022	Rev 4100
1	#	1	#
2	# Copyright (c) 2005 Ondrej Palkovsky	2	# Copyright (c) 2005 Ondrej Palkovsky
3	# Copyright (c) 2006 Martin Decky	3	# Copyright (c) 2006 Martin Decky
4	# Copyright (c) 2008 Jakub Jermar	4	# Copyright (c) 2008 Jakub Jermar
5	# All rights reserved.	5	# All rights reserved.
6	#	6	#
7	# Redistribution and use in source and binary forms, with or without	7	# Redistribution and use in source and binary forms, with or without
8	# modification, are permitted provided that the following conditions	8	# modification, are permitted provided that the following conditions
9	# are met:	9	# are met:
10	#	10	#
11	# - Redistributions of source code must retain the above copyright	11	# - Redistributions of source code must retain the above copyright
12	# notice, this list of conditions and the following disclaimer.	12	# notice, this list of conditions and the following disclaimer.
13	# - Redistributions in binary form must reproduce the above copyright	13	# - Redistributions in binary form must reproduce the above copyright
14	# notice, this list of conditions and the following disclaimer in the	14	# notice, this list of conditions and the following disclaimer in the
15	# documentation and/or other materials provided with the distribution.	15	# documentation and/or other materials provided with the distribution.
16	# - The name of the author may not be used to endorse or promote products	16	# - The name of the author may not be used to endorse or promote products
17	# derived from this software without specific prior written permission.	17	# derived from this software without specific prior written permission.
18	#	18	#
19	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR	19	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
20	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES	20	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
21	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.	21	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
22	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,	22	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
23	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT	23	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
24	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,	24	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
25	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY	25	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
26	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT	26	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF	27	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.	28	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29	#	29	#
30		30
31	#include <arch/boot/boot.h>	31	#include <arch/boot/boot.h>
32	#include <arch/boot/memmap.h>	32	#include <arch/boot/memmap.h>
33	#include <arch/mm/page.h>	33	#include <arch/mm/page.h>
34	#include <arch/mm/ptl.h>	34	#include <arch/mm/ptl.h>
35	#include <arch/pm.h>	35	#include <arch/pm.h>
36	#include <arch/cpu.h>	36	#include <arch/cpu.h>
37	#include <arch/cpuid.h>	37	#include <arch/cpuid.h>
38		38
39	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)	39	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
40		40
41	.section K_TEXT_START, "ax"	41	.section K_TEXT_START, "ax"
42		42
43	.code32	43	.code32
44	.align 4	44	.align 4
45	.global multiboot_image_start	45	.global multiboot_image_start
46	multiboot_header:	46	multiboot_header:
47	.long MULTIBOOT_HEADER_MAGIC	47	.long MULTIBOOT_HEADER_MAGIC
48	.long MULTIBOOT_HEADER_FLAGS	48	.long MULTIBOOT_HEADER_FLAGS
49	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum	49	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum
50	.long multiboot_header	50	.long multiboot_header
51	.long unmapped_ktext_start	51	.long unmapped_ktext_start
52	.long 0	52	.long 0
53	.long 0	53	.long 0
54	.long multiboot_image_start	54	.long multiboot_image_start
55		55
56	multiboot_image_start:	56	multiboot_image_start:
57	cld	57	cld
58	movl $START_STACK, %esp # initialize stack pointer	58	movl $START_STACK, %esp # initialize stack pointer
59	lgdtl bootstrap_gdtr # initialize Global Descriptor Table register	59	lgdtl bootstrap_gdtr # initialize Global Descriptor Table register
60		60
61	movw $gdtselector(KDATA_DES), %cx	61	movw $gdtselector(KDATA_DES), %cx
62	movw %cx, %es	62	movw %cx, %es
63	movw %cx, %ds # kernel data + stack	63	movw %cx, %ds # kernel data + stack
64	movw %cx, %ss	64	movw %cx, %ss
65	# Simics seems to remove hidden part of GS on entering user mode	65	# Simics seems to remove hidden part of GS on entering user mode
66	# when _visible_ part of GS does not point to user-mode segment	66	# when _visible_ part of GS does not point to user-mode segment
67	movw $gdtselector(UDATA_DES), %cx	67	movw $gdtselector(UDATA_DES), %cx
68	movw %cx, %fs	68	movw %cx, %fs
69	movw %cx, %gs	69	movw %cx, %gs
70		70
71	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point	71	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point
72	multiboot_meeting_point:	72	multiboot_meeting_point:
73		73
74	movl %eax, grub_eax # save parameters from GRUB	74	movl %eax, grub_eax # save parameters from GRUB
75	movl %ebx, grub_ebx	75	movl %ebx, grub_ebx
76		76
77	# Protected 32-bit. We want to reuse the code-seg descriptor,	77	# Protected 32-bit. We want to reuse the code-seg descriptor,
78	# the Default operand size must not be 1 when entering long mode	78	# the Default operand size must not be 1 when entering long mode
79		79
80	movl $(INTEL_CPUID_EXTENDED), %eax	80	movl $(INTEL_CPUID_EXTENDED), %eax
81	cpuid	81	cpuid
82	cmp $(INTEL_CPUID_EXTENDED), %eax	82	cmp $(INTEL_CPUID_EXTENDED), %eax
83	ja extended_cpuid_supported	83	ja extended_cpuid_supported
84		84
85	movl $extended_cpuid_msg, %esi	85	movl $extended_cpuid_msg, %esi
86	jmp error_halt	86	jmp error_halt
87		87
88	extended_cpuid_supported:	88	extended_cpuid_supported:
89		89
90	movl $(AMD_CPUID_EXTENDED), %eax	90	movl $(AMD_CPUID_EXTENDED), %eax
91	cpuid	91	cpuid
92	bt $(AMD_EXT_LONG_MODE), %edx	92	bt $(AMD_EXT_LONG_MODE), %edx
93	jc long_mode_supported	93	jc long_mode_supported
94		94
95	movl $long_mode_msg, %esi	95	movl $long_mode_msg, %esi
96	jmp error_halt	96	jmp error_halt
97		97
98	long_mode_supported:	98	long_mode_supported:
99		99
100	bt $(AMD_EXT_NOEXECUTE), %edx	100	bt $(AMD_EXT_NOEXECUTE), %edx
101	jc noexecute_supported	101	jc noexecute_supported
102		102
103	movl $noexecute_msg, %esi	103	movl $noexecute_msg, %esi
104	jmp error_halt	104	jmp error_halt
105		105
106	noexecute_supported:	106	noexecute_supported:
107		107
108	movl $(INTEL_CPUID_STANDARD), %eax	108	movl $(INTEL_CPUID_STANDARD), %eax
109	cpuid	109	cpuid
110	bt $(INTEL_FXSAVE), %edx	110	bt $(INTEL_FXSAVE), %edx
111	jc fx_supported	111	jc fx_supported
112		112
113	movl $fx_msg, %esi	113	movl $fx_msg, %esi
114	jmp error_halt	114	jmp error_halt
115		115
116	fx_supported:	116	fx_supported:
117		117
118	bt $(INTEL_SSE2), %edx	118	bt $(INTEL_SSE2), %edx
119	jc sse2_supported	119	jc sse2_supported
120		120
121	movl $sse2_msg, %esi	121	movl $sse2_msg, %esi
122	jmp error_halt	122	jmp error_halt
123		123
124	sse2_supported:	124	sse2_supported:
125		125
126	#ifdef CONFIG_FB	126	#ifdef CONFIG_FB
127	mov $vesa_init, %esi	127	mov $vesa_init, %esi
128	mov $VESA_INIT_SEGMENT << 4, %edi	128	mov $VESA_INIT_SEGMENT << 4, %edi
129	mov $e_vesa_init - vesa_init, %ecx	129	mov $e_vesa_init - vesa_init, %ecx
130	rep movsb	130	rep movsb
131		131
132	mov $VESA_INIT_SEGMENT << 4, %edi	132	mov $VESA_INIT_SEGMENT << 4, %edi
133	jmpl *%edi	133	jmpl *%edi
134		134
135	vesa_meeting_point:	135	vesa_meeting_point:
136		136
137	mov %esi, KA2PA(vesa_ph_addr)	137	mov %esi, KA2PA(vesa_ph_addr)
138	mov %di, KA2PA(vesa_height)	138	mov %di, KA2PA(vesa_height)
139	shr $16, %edi	139	shr $16, %edi
140	mov %di, KA2PA(vesa_width)	140	mov %di, KA2PA(vesa_width)
141	mov %bx, KA2PA(vesa_scanline)	141	mov %bx, KA2PA(vesa_scanline)
142	shr $16, %ebx	142	shr $16, %ebx
143	mov %bx, KA2PA(vesa_bpp)	143	mov %bx, KA2PA(vesa_bpp)
144	#endif	144	#endif
145		145
146	# Enable 64-bit page translation entries - CR4.PAE = 1.	146	# Enable 64-bit page translation entries - CR4.PAE = 1.
147	# Paging is not enabled until after long mode is enabled	147	# Paging is not enabled until after long mode is enabled
148		148
149	movl %cr4, %eax	149	movl %cr4, %eax
150	btsl $5, %eax	150	btsl $5, %eax
151	movl %eax, %cr4	151	movl %eax, %cr4
152		152
153	# Set up paging tables	153	# Set up paging tables
154		154
155	leal ptl_0, %eax	155	leal ptl_0, %eax
156	movl %eax, %cr3	156	movl %eax, %cr3
157		157
158	# Enable long mode	158	# Enable long mode
159		159
160	movl $EFER_MSR_NUM, %ecx # EFER MSR number	160	movl $EFER_MSR_NUM, %ecx # EFER MSR number
161	rdmsr # Read EFER	161	rdmsr # Read EFER
162	btsl $AMD_LME_FLAG, %eax # Set LME = 1	162	btsl $AMD_LME_FLAG, %eax # Set LME = 1
163	wrmsr # Write EFER	163	wrmsr # Write EFER
164		164
165	# Enable paging to activate long mode (set CR0.PG = 1)	165	# Enable paging to activate long mode (set CR0.PG = 1)
166		166
167	movl %cr0, %eax	167	movl %cr0, %eax
168	btsl $31, %eax	168	btsl $31, %eax
169	movl %eax, %cr0	169	movl %eax, %cr0
170		170
171	# At this point we are in compatibility mode	171	# At this point we are in compatibility mode
172		172
173	jmpl $gdtselector(KTEXT_DES), $start64	173	jmpl $gdtselector(KTEXT_DES), $start64
174		174
175	.code64	175	.code64
176	start64:	176	start64:
177	movq $(PA2KA(START_STACK)), %rsp	177	movq $(PA2KA(START_STACK)), %rsp
178		178
179	# arch_pre_main(grub_eax, grub_ebx)	179	# arch_pre_main(grub_eax, grub_ebx)
180	xorq %rdi, %rdi	180	xorq %rdi, %rdi
181	movl grub_eax, %edi	181	movl grub_eax, %edi
182	xorq %rsi, %rsi	182	xorq %rsi, %rsi
183	movl grub_ebx, %esi	183	movl grub_ebx, %esi
184	call arch_pre_main	184	call arch_pre_main
185		185
186	call main_bsp	186	call main_bsp
187		187
188	# Not reached.	188	# Not reached.
189		189
190	cli	190	cli
191	hlt	191	hlt
192		192
193	#ifdef CONFIG_FB	193	#ifdef CONFIG_FB
194	.code32	194	.code32
195	vesa_init:	195	vesa_init:
196	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init	196	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init
197		197
198	.code16	198	.code16
199	vesa_init_real:	199	vesa_init_real:
200		200
201	mov %cr0, %eax	201	mov %cr0, %eax
202	and $~1, %eax	202	and $~1, %eax
203	mov %eax, %cr0	203	mov %eax, %cr0
204		204
205	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init	205	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
206		206
207	vesa_init_real2:	207	vesa_init_real2:
208		208
209	mov $VESA_INIT_SEGMENT, %bx	209	mov $VESA_INIT_SEGMENT, %bx
210		210
211	mov %bx, %es	211	mov %bx, %es
212	mov %bx, %fs	212	mov %bx, %fs
213	mov %bx, %gs	213	mov %bx, %gs
214	mov %bx, %ds	214	mov %bx, %ds
215	mov %bx, %ss	215	mov %bx, %ss
216		216
217	movl $0x0000fffc, %esp	217	movl $0x0000fffc, %esp
218	movl $0x0000fffc, %ebp	218	movl $0x0000fffc, %ebp
219		219
220	#define VESA_INFO_SIZE 1024	220	#define VESA_INFO_SIZE 1024
221		221
222	#define VESA_MODE_ATTRIBUTES_OFFSET 0	222	#define VESA_MODE_ATTRIBUTES_OFFSET 0
223	#define VESA_MODE_LIST_PTR_OFFSET 14	223	#define VESA_MODE_LIST_PTR_OFFSET 14
224	#define VESA_MODE_SCANLINE_OFFSET 16	224	#define VESA_MODE_SCANLINE_OFFSET 16
225	#define VESA_MODE_WIDTH_OFFSET 18	225	#define VESA_MODE_WIDTH_OFFSET 18
226	#define VESA_MODE_HEIGHT_OFFSET 20	226	#define VESA_MODE_HEIGHT_OFFSET 20
227	#define VESA_MODE_BPP_OFFSET 25	227	#define VESA_MODE_BPP_OFFSET 25
228	#define VESA_MODE_PHADDR_OFFSET 40	228	#define VESA_MODE_PHADDR_OFFSET 40
229		229
230	#define VESA_END_OF_MODES 0xffff	230	#define VESA_END_OF_MODES 0xffff
231		231
232	#define VESA_OK 0x4f	232	#define VESA_OK 0x4f
233		233
234	#define VESA_GET_INFO 0x4f00	234	#define VESA_GET_INFO 0x4f00
235	#define VESA_GET_MODE_INFO 0x4f01	235	#define VESA_GET_MODE_INFO 0x4f01
236	#define VESA_SET_MODE 0x4f02	236	#define VESA_SET_MODE 0x4f02
237	#define VESA_SET_PALETTE 0x4f09	237	#define VESA_SET_PALETTE 0x4f09
238		238
239	#define CONFIG_VESA_BPP_a 255	239	#define CONFIG_VESA_BPP_a 255
240		240
241	#if CONFIG_VESA_BPP == 24	241	#if CONFIG_VESA_BPP == 24
242	#define CONFIG_VESA_BPP_VARIANT 32	242	#define CONFIG_VESA_BPP_VARIANT 32
243	#endif	243	#endif
244		244
245	mov $VESA_GET_INFO, %ax	245	mov $VESA_GET_INFO, %ax
246	mov $e_vesa_init - vesa_init, %di	246	mov $e_vesa_init - vesa_init, %di
247	push %di	247	push %di
248	int $0x10	248	int $0x10
249		249
250	pop %di	250	pop %di
251	cmp $VESA_OK, %al	251	cmp $VESA_OK, %al
252	jnz 0f	252	jnz 0f
253		253
254	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si	254	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
255	mov %si, %gs	255	mov %si, %gs
256	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si	256	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
257		257
258	add $VESA_INFO_SIZE, %di	258	add $VESA_INFO_SIZE, %di
259		259
260	1:# Try next mode	260	1:# Try next mode
261	mov %gs:(%si), %cx	261	mov %gs:(%si), %cx
262	cmp $VESA_END_OF_MODES, %cx	262	cmp $VESA_END_OF_MODES, %cx
263	jz 0f	263	jz 0f
264		264
265	inc %si	265	inc %si
266	inc %si	266	inc %si
267	push %cx	267	push %cx
268	push %di	268	push %di
269	push %si	269	push %si
270	mov $VESA_GET_MODE_INFO, %ax	270	mov $VESA_GET_MODE_INFO, %ax
271	int $0x10	271	int $0x10
272		272
273	pop %si	273	pop %si
274	pop %di	274	pop %di
275	pop %cx	275	pop %cx
276	cmp $VESA_OK, %al	276	cmp $VESA_OK, %al
277	jnz 0f	277	jnz 0f
278		278
279	mov $CONFIG_VESA_WIDTH, %ax	279	mov $CONFIG_VESA_WIDTH, %ax
280	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax	280	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
281	jnz 1b	281	jnz 1b
282		282
283	mov $CONFIG_VESA_HEIGHT, %ax	283	mov $CONFIG_VESA_HEIGHT, %ax
284	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax	284	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
285	jnz 1b	285	jnz 1b
286		286
287	mov $CONFIG_VESA_BPP, %al	287	mov $CONFIG_VESA_BPP, %al
288	cmp VESA_MODE_BPP_OFFSET(%di), %al	288	cmp VESA_MODE_BPP_OFFSET(%di), %al
289		289
290	#ifdef CONFIG_VESA_BPP_VARIANT	290	#ifdef CONFIG_VESA_BPP_VARIANT
291	jz 2f	291	jz 2f
292		292
293	mov $CONFIG_VESA_BPP_VARIANT, %al	293	mov $CONFIG_VESA_BPP_VARIANT, %al
294	cmp VESA_MODE_BPP_OFFSET(%di), %al	294	cmp VESA_MODE_BPP_OFFSET(%di), %al
295	#endif	295	#endif
296	jnz 1b	296	jnz 1b
297		297
298	2:	298	2:
299		299
300	mov %cx, %bx	300	mov %cx, %bx
301	or $0xc000, %bx	301	or $0xc000, %bx
302	push %di	302	push %di
303	mov $VESA_SET_MODE, %ax	303	mov $VESA_SET_MODE, %ax
304	int $0x10	304	int $0x10
305		305
306	pop %di	306	pop %di
307	cmp $VESA_OK, %al	307	cmp $VESA_OK, %al
308	jnz 0f	308	jnz 0f
309		309
310	#if CONFIG_VESA_BPP == 8	310	#if CONFIG_VESA_BPP == 8
311		311
312	# Set 3:2:3 VGA palette	312	# Set 3:2:3 VGA palette
313		313
314	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax	314	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax
315	push %di	315	push %di
316	mov $vga323 - vesa_init, %di	316	mov $vga323 - vesa_init, %di
317	mov $0x100, %ecx	317	mov $0x100, %ecx
318		318
319	bt $5, %ax # Test if VGA compatible registers are present	319	bt $5, %ax # Test if VGA compatible registers are present
320	jnc vga_compat	320	jnc vga_compat
321		321
322	# Try VESA routine to set palette	322	# Try VESA routine to set palette
323		323
324	mov $VESA_SET_PALETTE, %ax	324	mov $VESA_SET_PALETTE, %ax
325	xor %bl, %bl	325	xor %bl, %bl
326	xor %dx, %dx	326	xor %dx, %dx
327	int $0x10	327	int $0x10
328		328
329	cmp $0x00, %ah	329	cmp $0x00, %ah
330	je vga_not_compat	330	je vga_not_compat
331		331
332	vga_compat:	332	vga_compat:
333		333
334	# Try VGA registers to set palette	334	# Try VGA registers to set palette
335		335
336	movw $0x3c6, %dx # Set palette mask	336	movw $0x3c6, %dx # Set palette mask
337	movb $0xff, %al	337	movb $0xff, %al
338	outb %al, %dx	338	outb %al, %dx
339		339
340	movw $0x3c8, %dx # First index to set	340	movw $0x3c8, %dx # First index to set
341	xor %al, %al	341	xor %al, %al
342	outb %al, %dx	342	outb %al, %dx
343		343
344	movw $0x3c9, %dx # Data port	344	movw $0x3c9, %dx # Data port
345	vga_loop:	345	vga_loop:
346	movb %es:2(%di), %al	346	movb %es:2(%di), %al
347	outb %al, %dx	347	outb %al, %dx
348		348
349	movb %es:1(%di), %al	349	movb %es:1(%di), %al
350	outb %al, %dx	350	outb %al, %dx
351		351
352	movb %es:(%di), %al	352	movb %es:(%di), %al
353	outb %al, %dx	353	outb %al, %dx
354		354
355	addw $4, %di	355	addw $4, %di
356	loop vga_loop	356	loop vga_loop
357		357
358	vga_not_compat:	358	vga_not_compat:
359		359
360	pop %di	360	pop %di
361		361
362	#endif	362	#endif
363		363
364	mov VESA_MODE_PHADDR_OFFSET(%di), %esi	364	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
365	mov VESA_MODE_WIDTH_OFFSET(%di), %ax	365	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
366	shl $16, %eax	366	shl $16, %eax
367	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax	367	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
368	mov VESA_MODE_BPP_OFFSET(%di), %bl	368	mov VESA_MODE_BPP_OFFSET(%di), %bl
369	xor %bh, %bh	369	xor %bh, %bh
370	shl $16, %ebx	370	shl $16, %ebx
371	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx	371	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
372	mov %eax, %edi	372	mov %eax, %edi
373		373
374	8:	374	8:
375		375
376	mov %cr0, %eax	376	mov %cr0, %eax
377	or $1, %eax	377	or $1, %eax
378	mov %eax, %cr0	378	mov %eax, %cr0
379		379
380	jmp 9f	380	jmp 9f
381	9:	381	9:
382		382
383	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)	383	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
384		384
385	0:# No prefered mode found	385	0:# No prefered mode found
386	mov $0x111, %cx	386	mov $0x111, %cx
387	push %di	387	push %di
388	push %cx	388	push %cx
389	mov $VESA_GET_MODE_INFO, %ax	389	mov $VESA_GET_MODE_INFO, %ax
390	int $0x10	390	int $0x10
391		391
392	pop %cx	392	pop %cx
393	pop %di	393	pop %di
394	cmp $VESA_OK, %al	394	cmp $VESA_OK, %al
395	jnz 1f	395	jnz 1f
396	jz 2b # Force relative jump	396	jz 2b # Force relative jump
397		397
398	1:	398	1:
399	mov $0x0003, %ax	399	mov $0x0003, %ax
400	int $0x10	400	int $0x10
401	mov $0xffffffff, %edi # EGA text mode used, because of problems with VESA	401	mov $0xffffffff, %edi # EGA text mode used, because of problems with VESA
402	xor %ax, %ax	402	xor %ax, %ax
403	jz 8b # Force relative jump	403	jz 8b # Force relative jump
404		404
405	vga323:	405	vga323:
406	#include "vga323.pal"	406	#include "vga323.pal"
407		407
408	.code32	408	.code32
409	vesa_init_protect:	409	vesa_init_protect:
410	movw $gdtselector(KDATA_DES), %cx	410	movw $gdtselector(KDATA_DES), %cx
411	movw %cx, %es	411	movw %cx, %es
412	movw %cx, %ds # kernel data + stack	412	movw %cx, %ds # kernel data + stack
413	movw %cx, %ss	413	movw %cx, %ss
414	# Simics seems to remove hidden part of GS on entering user mode	414	# Simics seems to remove hidden part of GS on entering user mode
415	# when _visible_ part of GS does not point to user-mode segment	415	# when _visible_ part of GS does not point to user-mode segment
416	movw $gdtselector(UDATA_DES), %cx	416	movw $gdtselector(UDATA_DES), %cx
417	movw %cx, %fs	417	movw %cx, %fs
418	movw %cx, %gs	418	movw %cx, %gs
419		419
420	movl $START_STACK, %esp # initialize stack pointer	420	movl $START_STACK, %esp # initialize stack pointer
421		421
422	jmpl $gdtselector(KTEXT32_DES), $vesa_meeting_point	422	jmpl $gdtselector(KTEXT32_DES), $vesa_meeting_point
423		423
424	.align 4	424	.align 4
425	e_vesa_init:	425	e_vesa_init:
426	#endif	426	#endif
427		427
428	# Print string from %esi to EGA display (in red) and halt	428	# Print string from %esi to EGA display (in red) and halt
429	error_halt:	429	error_halt:
430	movl $0xb8000, %edi # base of EGA text mode memory	430	movl $0xb8000, %edi # base of EGA text mode memory
431	xorl %eax, %eax	431	xorl %eax, %eax
432		432
433	movw $0x3d4, %dx # read bits 8 - 15 of the cursor address	433	movw $0x3d4, %dx # read bits 8 - 15 of the cursor address
434	movb $0xe, %al	434	movb $0xe, %al
435	outb %al, %dx	435	outb %al, %dx
436		436
437	movw $0x3d5, %dx	437	movw $0x3d5, %dx
438	inb %dx, %al	438	inb %dx, %al
439	shl $8, %ax	439	shl $8, %ax
440		440
441	movw $0x3d4, %dx # read bits 0 - 7 of the cursor address	441	movw $0x3d4, %dx # read bits 0 - 7 of the cursor address
442	movb $0xf, %al	442	movb $0xf, %al
443	outb %al, %dx	443	outb %al, %dx
444		444
445	movw $0x3d5, %dx	445	movw $0x3d5, %dx
446	inb %dx, %al	446	inb %dx, %al
447		447
448	cmp $1920, %ax	448	cmp $1920, %ax
449	jbe cursor_ok	449	jbe cursor_ok
450	movw $1920, %ax # sanity check for the cursor on the last line	450	movw $1920, %ax # sanity check for the cursor on the last line
451	cursor_ok:	451	cursor_ok:
452		452
453	movw %ax, %bx	453	movw %ax, %bx
454	shl $1, %eax	454	shl $1, %eax
455	addl %eax, %edi	455	addl %eax, %edi
456		456
457	movw $0x0c00, %ax # black background, light red foreground	457	movw $0x0c00, %ax # black background, light red foreground
458		458
459	ploop:	459	ploop:
460	lodsb	460	lodsb
461	cmp $0, %al	461	cmp $0, %al
462	je ploop_end	462	je ploop_end
463	stosw	463	stosw
464	inc %bx	464	inc %bx
465	jmp ploop	465	jmp ploop
466	ploop_end:	466	ploop_end:
467		467
468	movw $0x3d4, %dx # write bits 8 - 15 of the cursor address	468	movw $0x3d4, %dx # write bits 8 - 15 of the cursor address
469	movb $0xe, %al	469	movb $0xe, %al
470	outb %al, %dx	470	outb %al, %dx
471		471
472	movw $0x3d5, %dx	472	movw $0x3d5, %dx
473	movb %bh, %al	473	movb %bh, %al
474	outb %al, %dx	474	outb %al, %dx
475		475
476	movw $0x3d4, %dx # write bits 0 - 7 of the cursor address	476	movw $0x3d4, %dx # write bits 0 - 7 of the cursor address
477	movb $0xf, %al	477	movb $0xf, %al
478	outb %al, %dx	478	outb %al, %dx
479		479
480	movw $0x3d5, %dx	480	movw $0x3d5, %dx
481	movb %bl, %al	481	movb %bl, %al
482	outb %al, %dx	482	outb %al, %dx
483		483
484	cli	484	cli
485	hlt	485	hlt
486		486
487		487
488	.section K_INI_PTLS, "aw", @progbits	488	.section K_INI_PTLS, "aw", @progbits
489		489
490	#	490	#
491	# Macro for generating initial page table contents.	491	# Macro for generating initial page table contents.
492	# @param cnt Number of entries to generat. Must be multiple of 8.	492	# @param cnt Number of entries to generat. Must be multiple of 8.
493	# @param g Number of GB that will be added to the mapping.	493	# @param g Number of GB that will be added to the mapping.
494	#	494	#
495	.macro ptl2gen cnt g	495	.macro ptl2gen cnt g
496	.if \cnt	496	.if \cnt
497	ptl2gen "\cnt - 8" \g	497	ptl2gen "\cnt - 8" \g
498	.quad ((\cnt - 8) * 0x200000) + (\g * 1024 * 1024 * 1024) \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)	498	.quad ((\cnt - 8) * 0x200000) + (\g * 1024 * 1024 * 1024) \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
499	.quad ((\cnt - 7) * 0x200000) + (\g * 1024 * 1024 * 1024) \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)	499	.quad ((\cnt - 7) * 0x200000) + (\g * 1024 * 1024 * 1024) \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)
500	.quad ((\cnt - 6) * 0x200000) + (\g * 1024 * 1024 * 1024) \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)	500	.quad ((\cnt - 6) * 0x200000) + (\g * 1024 * 1024 * 1024) \| (PTL_WRITABLE \| PTL_PRESENT \| PTL_2MB_PAGE)

Subversion Repositories HelenOS

(root)/trunk/kernel/arch/amd64/src/boot/boot.S @ 2071 – Rev 4022 → 4100