WebSVN – HelenOS – Diff – /tags/0.2.0.5/kernel/arch/amd64/src/boot/boot.S


#
# Copyright (c) 2005 Ondrej Palkovsky
# Copyright (c) 2006 Martin Decky
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
#
# - Redistributions of source code must retain the above copyright
#   notice, this list of conditions and the following disclaimer.
# - Redistributions in binary form must reproduce the above copyright
#   notice, this list of conditions and the following disclaimer in the
#   documentation and/or other materials provided with the distribution.
# - The name of the author may not be used to endorse or promote products
#   derived from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
#
 
#include <arch/boot/boot.h>
#include <arch/boot/memmap.h>
#include <arch/mm/page.h>	
#include <arch/mm/ptl.h>
#include <arch/pm.h>
#include <arch/cpu.h>
#include <arch/cpuid.h>
 
#define START_STACK	(BOOT_OFFSET - BOOT_STACK_SIZE)
	
.section K_TEXT_START, "ax"
 
.code32
.align 4
.global multiboot_image_start
multiboot_header:
	.long MULTIBOOT_HEADER_MAGIC
	.long MULTIBOOT_HEADER_FLAGS
	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS)	# checksum
	.long multiboot_header
	.long unmapped_ktext_start
	.long 0
	.long 0
	.long multiboot_image_start
 
multiboot_image_start:
	movl $START_STACK, %esp			# initialize stack pointer
	lgdt bootstrap_gdtr				# initialize Global Descriptor Table register
 
	movw $gdtselector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %ds							# kernel data + stack
	movw %cx, %ss
	# Simics seems to remove hidden part of GS on entering user mode
	#  when _visible_ part of GS does not point to user-mode segment
	movw $gdtselector(UDATA_DES), %cx
	movw %cx, %fs
	movw %cx, %gs
	
	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point
	multiboot_meeting_point:
	
	movl %eax, grub_eax							# save parameters from GRUB
	movl %ebx, grub_ebx
	
	# Protected 32-bit. We want to reuse the code-seg descriptor,
	# the Default operand size must not be 1 when entering long mode
	
	movl $0x80000000, %eax  
 	cpuid
 	cmp $0x80000000, %eax						# any function > 80000000h?
	jbe long_mode_unsupported
	movl $(AMD_CPUID_EXTENDED), %eax			# Extended function code 80000001
	cpuid
	bt $29, %edx								# Test if long mode is supported.
 	jc long_mode_supported
 
	long_mode_unsupported:
		movl $long_mode_msg, %esi
		jmp error_halt
	
	long_mode_supported:
	
#ifdef CONFIG_FB
	mov $vesa_init, %esi
	mov $VESA_INIT_SEGMENT << 4, %edi
	mov $e_vesa_init - vesa_init, %ecx
	cld
	rep movsb
 
	mov $VESA_INIT_SEGMENT << 4, %edi
	jmpl *%edi
	
	vesa_meeting_point:
	
	mov %esi, KA2PA(vesa_ph_addr)
	mov %di, KA2PA(vesa_height)
	shr $16, %edi
	mov %di, KA2PA(vesa_width)
	mov %bx, KA2PA(vesa_scanline)
	shr $16, %ebx
	mov %bx, KA2PA(vesa_bpp)
#endif	
	
	# Enable 64-bit page transaltion entries - CR4.PAE = 1.
	# Paging is not enabled until after long mode is enabled
	
	movl %cr4, %eax
	btsl $5, %eax
	movl %eax, %cr4
 
	# Set up paging tables
	
	leal ptl_0, %eax
	movl %eax, %cr3
	
	# Enable long mode
	
	movl $EFER_MSR_NUM, %ecx	# EFER MSR number
	rdmsr						# Read EFER
	btsl $AMD_LME_FLAG, %eax	# Set LME=1
	wrmsr						# Write EFER
	
	# Enable paging to activate long mode (set CR0.PG=1)
	
	movl %cr0, %eax
	btsl $31, %eax
	movl %eax, %cr0
	
	# At this point we are in compatibility mode
	
	jmpl $gdtselector(KTEXT_DES), $start64
 
.code64
start64:
	movq $(PA2KA(START_STACK)), %rsp
	movl grub_eax, %eax
	movl grub_ebx, %ebx
	
	cmpl $MULTIBOOT_LOADER_MAGIC, %eax				# compare GRUB signature
	je valid_boot
		
		xorl %ecx, %ecx							# no memory size or map available
		movl %ecx, e801memorysize
		movl %ecx, e820counter
		
		jmp invalid_boot
		
	valid_boot:
		
		movl (%ebx), %eax						# ebx = physical address of struct multiboot_info
		
		bt $0, %eax								# mbi->flags[0] (mem_lower, mem_upper valid)
		jc mem_valid
			
			xorl %ecx, %ecx
			jmp mem_invalid
			
		mem_valid:
		movl 4(%ebx), %ecx						# mbi->mem_lower
		addl 8(%ebx), %ecx						# mbi->mem_upper
		
		mem_invalid:
		movl %ecx, e801memorysize
		
		bt $3, %eax								# mbi->flags[3] (mods_count, mods_addr valid)
		jc mods_valid
			
			xorq %rcx, %rcx
			movq %rcx, init
			jmp mods_end
		
		mods_valid:
		
		xorq %rcx, %rcx
		movl 20(%ebx), %ecx						# mbi->mods_count
		movq %rcx, init
		
		cmpl $0, %ecx
		je mods_end
		
		movl 24(%ebx), %esi						# mbi->mods_addr
		movq $init, %rdi
		
		mods_loop:
			
			xorq %rdx, %rdx
			movl 0(%esi), %edx					# mods->mod_start
			movq $0xffff800000000000, %r10
			addq %r10, %rdx
			movq %rdx, 8(%rdi)
			
			xorq %rdx, %rdx
			movl 4(%esi), %edx
			subl 0(%esi), %edx					# mods->mod_end - mods->mod_start
			movq %rdx, 16(%rdi)
			
			addl $16, %esi
			addq $16, %rdi
			
			loop mods_loop
			
		mods_end:
		
		bt $6, %eax								# mbi->flags[6] (mmap_length, mmap_addr valid)	
		jc mmap_valid
			
			xorl %edx, %edx
			jmp mmap_invalid
			
		mmap_valid:
		movl 44(%ebx), %ecx						# mbi->mmap_length
		movl 48(%ebx), %esi						# mbi->mmap_addr
		movq $e820table, %rdi
		xorl %edx, %edx
		
		mmap_loop:
			cmpl $0, %ecx
			jle mmap_end
			
			movl 4(%esi), %eax					# mmap->base_addr_low
			movl %eax, (%rdi)
			
			movl 8(%esi), %eax					# mmap->base_addr_high
			movl %eax, 4(%rdi)
			
			movl 12(%esi), %eax					# mmap->length_low
			movl %eax, 8(%rdi)
			
			movl 16(%esi), %eax					# mmap->length_high
			movl %eax, 12(%rdi)
			
			movl 20(%esi), %eax					# mmap->type
			movl %eax, 16(%rdi)
			
			movl (%esi), %eax					# mmap->size
			addl $0x4, %eax
			addl %eax, %esi
			subl %eax, %ecx
			addq $MEMMAP_E820_RECORD_SIZE, %rdi
			incl %edx
			jmp mmap_loop
		
		mmap_end:
		
		mmap_invalid:
		movl %edx, e820counter
		
	invalid_boot:
	
#ifdef CONFIG_SMP
	
	# copy AP bootstrap routines below 1 MB
	
	movq $BOOT_OFFSET, %rsi
	movq $AP_BOOT_OFFSET, %rdi
	movq $_hardcoded_unmapped_size, %rcx
	cld
	rep movsb
	
#endif
	
	call main_bsp   # never returns
	
	cli
	hlt
 
#ifdef CONFIG_FB
.code32
vesa_init:
	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init
	
.code16
vesa_init_real:
	
	mov %cr0, %eax
	and $~1, %eax
	mov %eax, %cr0
	
	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
	
vesa_init_real2:
	
	mov $VESA_INIT_SEGMENT, %bx
	
	mov %bx, %es
	mov %bx, %fs
	mov %bx, %gs
	mov %bx, %ds
	mov %bx, %ss
	
	movl $0x0000fffc, %esp
    movl $0x0000fffc, %ebp
	
#define VESA_INFO_SIZE 1024
 
#define VESA_MODE_ATTRIBUTES_OFFSET 0
#define VESA_MODE_LIST_PTR_OFFSET 14
#define VESA_MODE_SCANLINE_OFFSET 16
#define VESA_MODE_WIDTH_OFFSET 18
#define VESA_MODE_HEIGHT_OFFSET 20
#define VESA_MODE_BPP_OFFSET 25
#define VESA_MODE_PHADDR_OFFSET 40
 
#define VESA_END_OF_MODES 0xffff
 
#define VESA_OK 0x4f
 
#define VESA_GET_INFO 0x4f00
#define VESA_GET_MODE_INFO 0x4f01
#define VESA_SET_MODE 0x4f02
#define VESA_SET_PALETTE 0x4f09
 
#define CONFIG_VESA_BPP_a 255
 
#if CONFIG_VESA_BPP == 24
#define CONFIG_VESA_BPP_VARIANT 32
#endif
 
	mov $VESA_GET_INFO, %ax
	mov $e_vesa_init - vesa_init, %di
	push %di
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
	
	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
	mov %si, %gs
	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
	
	add $VESA_INFO_SIZE, %di
 
1:# Try next mode
	mov %gs:(%si), %cx
	cmp $VESA_END_OF_MODES, %cx
	jz 0f
	
	inc %si
	inc %si
	push %cx
	push %di
	push %si
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %si
	pop %di
	pop %cx
	cmp $VESA_OK, %al
	jnz 0f
	
	mov $CONFIG_VESA_WIDTH, %ax
	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_HEIGHT, %ax
	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
	jnz 1b
	
	mov $CONFIG_VESA_BPP, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
 
#ifdef CONFIG_VESA_BPP_VARIANT
	jz 2f
	
	mov $CONFIG_VESA_BPP_VARIANT, %al
	cmp VESA_MODE_BPP_OFFSET(%di), %al
#endif
	jnz 1b
	
2:
	
	mov %cx, %bx
	or $0xc000, %bx
	push %di
	mov $VESA_SET_MODE, %ax
	int $0x10
	
	pop %di
	cmp $VESA_OK, %al
	jnz 0f
 
#if CONFIG_VESA_BPP == 8
	
	# Set 3:2:3 VGA palette
	
	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax
	push %di
	mov $vga323 - vesa_init, %di
	mov $0x100, %ecx
	
	bt $5, %ax							# Test if VGA compatible registers are present
	jnc vga_compat
		
		# Try VESA routine to set palette
		
		mov $VESA_SET_PALETTE, %ax
		xor %bl, %bl
		xor %dx, %dx
		int $0x10
		
		jmp vga_not_compat
	
	vga_compat:
		
		# Try VGA registers to set palette
		
		movw $0x3c6, %dx						# Set palette mask
		movb $0xff, %al
		outb %al, %dx
		
		movw $0x3c8, %dx						# First index to set
		xor %al, %al
		outb %al, %dx
		
		movw $0x3c9, %dx						# Data port
		vga_loop:
			movb %es:2(%di), %al
			outb %al, %dx
			
			movb %es:1(%di), %al
			outb %al, %dx
			
			movb %es:(%di), %al
			outb %al, %dx
			
			addw $4, %di
			loop vga_loop
		
	vga_not_compat:
	
	pop %di
	
#endif
	
	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
	shl $16, %eax
	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
	mov VESA_MODE_BPP_OFFSET(%di), %bl
	xor %bh, %bh
	shl $16, %ebx
	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
	mov %eax, %edi
	
8:
	
	mov %cr0, %eax
	or $1, %eax
	mov %eax, %cr0
	
	jmp 9f
9:
	
	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
	
0:# No prefered mode found
	mov $0x111, %cx
	push %di
	push %cx
	mov $VESA_GET_MODE_INFO, %ax
	int $0x10
	
	pop %cx
	pop %di
	cmp $VESA_OK, %al
	jnz 1f
	jz 2b						# Force relative jump
 
1:
	mov $0x0003, %ax
	int $0x10
	mov $0xffffffff, %edi		# EGA text mode used, because of problems with VESA
	xor %ax, %ax
	jz 8b						# Force relative jump
 
vga323:
#include "vga323.pal"	
	
.code32
vesa_init_protect:
	movw $gdtselector(KDATA_DES), %cx
	movw %cx, %es
	movw %cx, %ds							# kernel data + stack
	movw %cx, %ss
	# Simics seems to remove hidden part of GS on entering user mode
	#  when _visible_ part of GS does not point to user-mode segment
	movw $gdtselector(UDATA_DES), %cx
	movw %cx, %fs
	movw %cx, %gs
	
	movl $START_STACK, %esp			# initialize stack pointer
	
	jmpl $gdtselector(KTEXT32_DES), $vesa_meeting_point
	
.align 4
e_vesa_init:
#endif
 
# Print string from %esi to EGA display (in red) and halt
error_halt:
	movl $0xb8000, %edi						# base of EGA text mode memory
	xorl %eax, %eax
	
	movw $0x3d4, %dx						# read bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	shl $8, %ax
	
	movw $0x3d4, %dx						# read bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	inb %dx, %al
	
	cmp $1920, %ax
	jbe cursor_ok
		movw $1920, %ax						# sanity check for the cursor on the last line
	cursor_ok:
	
	movw %ax, %bx
	shl $1, %eax
	addl %eax, %edi
	
	movw $0x0c00, %ax						# black background, light red foreground
	cld
	
	ploop:
		lodsb
		cmp $0, %al
		je ploop_end
		stosw
		inc %bx	
		jmp ploop
	ploop_end:
	
	movw $0x3d4, %dx						# write bits 8 - 15 of the cursor address
	movb $0xe, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bh, %al
	outb %al, %dx
	
	movw $0x3d4, %dx						# write bits 0 - 7 of the cursor address
	movb $0xf, %al
	outb %al, %dx
	
	movw $0x3d5, %dx
	movb %bl, %al
	outb %al, %dx
		
	cli
	hlt
				
.section K_DATA_START, "aw", @progbits
.align 4096
 
# Identical mapping of first 64MB and the same of -2GB -> 0	
.global ptl_2
ptl_2:	
	.quad 0x0 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0xa00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0xc00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0xe00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1000000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1a00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1c00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x1e00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2000000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2a00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2c00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x2e00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3000000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3200000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3400000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3600000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3800000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3a00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3c00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	.quad 0x3e00000 | (PTL_WRITABLE | PTL_PRESENT | PTL_2MB_PAGE)
	
.align 4096
.global ptl_1
ptl_1:
	.quad ptl_2 + (PTL_WRITABLE | PTL_PRESENT)
	.fill 509,8,0
	.quad ptl_2 + (PTL_WRITABLE | PTL_PRESENT)
	.fill 1,8,0
	
.align 4096
.global ptl_0
ptl_0:
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
	.fill 255,8,0
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
	.fill 254,8,0
	.quad ptl_1 + (PTL_WRITABLE | PTL_PRESENT)
 
.global bootstrap_gdtr
bootstrap_gdtr:
	.word gdtselector(GDT_ITEMS)
	.long KA2PA(gdt)
 
grub_eax:
	.long 0
 
grub_ebx:
	.long 0
 
long_mode_msg:
	.asciz "64 bit long mode not supported. System halted."
 

Rev 2302	Rev 2474
1	#	1	#
2	# Copyright (c) 2005 Ondrej Palkovsky	2	# Copyright (c) 2005 Ondrej Palkovsky
3	# Copyright (c) 2006 Martin Decky	3	# Copyright (c) 2006 Martin Decky
4	# All rights reserved.	4	# All rights reserved.
5	#	5	#
6	# Redistribution and use in source and binary forms, with or without	6	# Redistribution and use in source and binary forms, with or without
7	# modification, are permitted provided that the following conditions	7	# modification, are permitted provided that the following conditions
8	# are met:	8	# are met:
9	#	9	#
10	# - Redistributions of source code must retain the above copyright	10	# - Redistributions of source code must retain the above copyright
11	# notice, this list of conditions and the following disclaimer.	11	# notice, this list of conditions and the following disclaimer.
12	# - Redistributions in binary form must reproduce the above copyright	12	# - Redistributions in binary form must reproduce the above copyright
13	# notice, this list of conditions and the following disclaimer in the	13	# notice, this list of conditions and the following disclaimer in the
14	# documentation and/or other materials provided with the distribution.	14	# documentation and/or other materials provided with the distribution.
15	# - The name of the author may not be used to endorse or promote products	15	# - The name of the author may not be used to endorse or promote products
16	# derived from this software without specific prior written permission.	16	# derived from this software without specific prior written permission.
17	#	17	#
18	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR	18	# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
19	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES	19	# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
20	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.	20	# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
21	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,	21	# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
22	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT	22	# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
23	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,	23	# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
24	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY	24	# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
25	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT	25	# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
26	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF	26	# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
27	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.	27	# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
28	#	28	#
29		29
30	#include <arch/boot/boot.h>	30	#include <arch/boot/boot.h>
31	#include <arch/boot/memmap.h>	31	#include <arch/boot/memmap.h>
32	#include <arch/mm/page.h>	32	#include <arch/mm/page.h>
33	#include <arch/mm/ptl.h>	33	#include <arch/mm/ptl.h>
34	#include <arch/pm.h>	34	#include <arch/pm.h>
35	#include <arch/cpu.h>	35	#include <arch/cpu.h>
36	#include <arch/cpuid.h>	36	#include <arch/cpuid.h>
37		37
38	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)	38	#define START_STACK (BOOT_OFFSET - BOOT_STACK_SIZE)
39		39
40	.section K_TEXT_START, "ax"	40	.section K_TEXT_START, "ax"
41		41
42	.code32	42	.code32
43	.align 4	43	.align 4
44	.global multiboot_image_start	44	.global multiboot_image_start
45	multiboot_header:	45	multiboot_header:
46	.long MULTIBOOT_HEADER_MAGIC	46	.long MULTIBOOT_HEADER_MAGIC
47	.long MULTIBOOT_HEADER_FLAGS	47	.long MULTIBOOT_HEADER_FLAGS
48	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum	48	.long -(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS) # checksum
49	.long multiboot_header	49	.long multiboot_header
50	.long unmapped_ktext_start	50	.long unmapped_ktext_start
51	.long 0	51	.long 0
52	.long 0	52	.long 0
53	.long multiboot_image_start	53	.long multiboot_image_start
54		54
55	multiboot_image_start:	55	multiboot_image_start:
56	movl $START_STACK, %esp # initialize stack pointer	56	movl $START_STACK, %esp # initialize stack pointer
57	lgdt bootstrap_gdtr # initialize Global Descriptor Table register	57	lgdt bootstrap_gdtr # initialize Global Descriptor Table register
58		58
59	movw $gdtselector(KDATA_DES), %cx	59	movw $gdtselector(KDATA_DES), %cx
60	movw %cx, %es	60	movw %cx, %es
61	movw %cx, %ds # kernel data + stack	61	movw %cx, %ds # kernel data + stack
62	movw %cx, %ss	62	movw %cx, %ss
63	# Simics seems to remove hidden part of GS on entering user mode	63	# Simics seems to remove hidden part of GS on entering user mode
64	# when _visible_ part of GS does not point to user-mode segment	64	# when _visible_ part of GS does not point to user-mode segment
65	movw $gdtselector(UDATA_DES), %cx	65	movw $gdtselector(UDATA_DES), %cx
66	movw %cx, %fs	66	movw %cx, %fs
67	movw %cx, %gs	67	movw %cx, %gs
68		68
69	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point	69	jmpl $gdtselector(KTEXT32_DES), $multiboot_meeting_point
70	multiboot_meeting_point:	70	multiboot_meeting_point:
71		71
72	movl %eax, grub_eax # save parameters from GRUB	72	movl %eax, grub_eax # save parameters from GRUB
73	movl %ebx, grub_ebx	73	movl %ebx, grub_ebx
74		74
75	# Protected 32-bit. We want to reuse the code-seg descriptor,	75	# Protected 32-bit. We want to reuse the code-seg descriptor,
76	# the Default operand size must not be 1 when entering long mode	76	# the Default operand size must not be 1 when entering long mode
77		77
78	movl $0x80000000, %eax	78	movl $0x80000000, %eax
79	cpuid	79	cpuid
80	cmp $0x80000000, %eax # any function > 80000000h?	80	cmp $0x80000000, %eax # any function > 80000000h?
81	jbe long_mode_unsupported	81	jbe long_mode_unsupported
82	movl $(AMD_CPUID_EXTENDED), %eax # Extended function code 80000001	82	movl $(AMD_CPUID_EXTENDED), %eax # Extended function code 80000001
83	cpuid	83	cpuid
84	bt $29, %edx # Test if long mode is supported.	84	bt $29, %edx # Test if long mode is supported.
85	jc long_mode_supported	85	jc long_mode_supported
86		86
87	long_mode_unsupported:	87	long_mode_unsupported:
88	movl $long_mode_msg, %esi	88	movl $long_mode_msg, %esi
89	jmp error_halt	89	jmp error_halt
90		90
91	long_mode_supported:	91	long_mode_supported:
92		92
93	#ifdef CONFIG_FB	93	#ifdef CONFIG_FB
94	mov $vesa_init, %esi	94	mov $vesa_init, %esi
95	mov $VESA_INIT_SEGMENT << 4, %edi	95	mov $VESA_INIT_SEGMENT << 4, %edi
96	mov $e_vesa_init - vesa_init, %ecx	96	mov $e_vesa_init - vesa_init, %ecx
97	cld	97	cld
98	rep movsb	98	rep movsb
99		99
100	mov $VESA_INIT_SEGMENT << 4, %edi	100	mov $VESA_INIT_SEGMENT << 4, %edi
101	jmpl *%edi	101	jmpl *%edi
102		102
103	vesa_meeting_point:	103	vesa_meeting_point:
104		104
105	mov %esi, KA2PA(vesa_ph_addr)	105	mov %esi, KA2PA(vesa_ph_addr)
106	mov %di, KA2PA(vesa_height)	106	mov %di, KA2PA(vesa_height)
107	shr $16, %edi	107	shr $16, %edi
108	mov %di, KA2PA(vesa_width)	108	mov %di, KA2PA(vesa_width)
109	mov %bx, KA2PA(vesa_scanline)	109	mov %bx, KA2PA(vesa_scanline)
110	shr $16, %ebx	110	shr $16, %ebx
111	mov %bx, KA2PA(vesa_bpp)	111	mov %bx, KA2PA(vesa_bpp)
112	#endif	112	#endif
113		113
114	# Enable 64-bit page transaltion entries - CR4.PAE = 1.	114	# Enable 64-bit page transaltion entries - CR4.PAE = 1.
115	# Paging is not enabled until after long mode is enabled	115	# Paging is not enabled until after long mode is enabled
116		116
117	movl %cr4, %eax	117	movl %cr4, %eax
118	btsl $5, %eax	118	btsl $5, %eax
119	movl %eax, %cr4	119	movl %eax, %cr4
120		120
121	# Set up paging tables	121	# Set up paging tables
122		122
123	leal ptl_0, %eax	123	leal ptl_0, %eax
124	movl %eax, %cr3	124	movl %eax, %cr3
125		125
126	# Enable long mode	126	# Enable long mode
127		127
128	movl $EFER_MSR_NUM, %ecx # EFER MSR number	128	movl $EFER_MSR_NUM, %ecx # EFER MSR number
129	rdmsr # Read EFER	129	rdmsr # Read EFER
130	btsl $AMD_LME_FLAG, %eax # Set LME=1	130	btsl $AMD_LME_FLAG, %eax # Set LME=1
131	wrmsr # Write EFER	131	wrmsr # Write EFER
132		132
133	# Enable paging to activate long mode (set CR0.PG=1)	133	# Enable paging to activate long mode (set CR0.PG=1)
134		134
135	movl %cr0, %eax	135	movl %cr0, %eax
136	btsl $31, %eax	136	btsl $31, %eax
137	movl %eax, %cr0	137	movl %eax, %cr0
138		138
139	# At this point we are in compatibility mode	139	# At this point we are in compatibility mode
140		140
141	jmpl $gdtselector(KTEXT_DES), $start64	141	jmpl $gdtselector(KTEXT_DES), $start64
142		142
143	.code64	143	.code64
144	start64:	144	start64:
145	movq $(PA2KA(START_STACK)), %rsp	145	movq $(PA2KA(START_STACK)), %rsp
146	movl grub_eax, %eax	146	movl grub_eax, %eax
147	movl grub_ebx, %ebx	147	movl grub_ebx, %ebx
148		148
149	cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature	149	cmpl $MULTIBOOT_LOADER_MAGIC, %eax # compare GRUB signature
150	je valid_boot	150	je valid_boot
151		151
152	xorl %ecx, %ecx # no memory size or map available	152	xorl %ecx, %ecx # no memory size or map available
153	movl %ecx, e801memorysize	153	movl %ecx, e801memorysize
154	movl %ecx, e820counter	154	movl %ecx, e820counter
155		155
156	jmp invalid_boot	156	jmp invalid_boot
157		157
158	valid_boot:	158	valid_boot:
159		159
160	movl (%ebx), %eax # ebx = physical address of struct multiboot_info	160	movl (%ebx), %eax # ebx = physical address of struct multiboot_info
161		161
162	bt $0, %eax # mbi->flags[0] (mem_lower, mem_upper valid)	162	bt $0, %eax # mbi->flags[0] (mem_lower, mem_upper valid)
163	jc mem_valid	163	jc mem_valid
164		164
165	xorl %ecx, %ecx	165	xorl %ecx, %ecx
166	jmp mem_invalid	166	jmp mem_invalid
167		167
168	mem_valid:	168	mem_valid:
169	movl 4(%ebx), %ecx # mbi->mem_lower	169	movl 4(%ebx), %ecx # mbi->mem_lower
170	addl 8(%ebx), %ecx # mbi->mem_upper	170	addl 8(%ebx), %ecx # mbi->mem_upper
171		171
172	mem_invalid:	172	mem_invalid:
173	movl %ecx, e801memorysize	173	movl %ecx, e801memorysize
174		174
175	bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)	175	bt $3, %eax # mbi->flags[3] (mods_count, mods_addr valid)
176	jc mods_valid	176	jc mods_valid
177		177
178	xorq %rcx, %rcx	178	xorq %rcx, %rcx
179	movq %rcx, init	179	movq %rcx, init
180	jmp mods_end	180	jmp mods_end
181		181
182	mods_valid:	182	mods_valid:
183		183
184	xorq %rcx, %rcx	184	xorq %rcx, %rcx
185	movl 20(%ebx), %ecx # mbi->mods_count	185	movl 20(%ebx), %ecx # mbi->mods_count
186	movq %rcx, init	186	movq %rcx, init
187		187
188	cmpl $0, %ecx	188	cmpl $0, %ecx
189	je mods_end	189	je mods_end
190		190
191	movl 24(%ebx), %esi # mbi->mods_addr	191	movl 24(%ebx), %esi # mbi->mods_addr
192	movq $init, %rdi	192	movq $init, %rdi
193		193
194	mods_loop:	194	mods_loop:
195		195
196	xorq %rdx, %rdx	196	xorq %rdx, %rdx
197	movl 0(%esi), %edx # mods->mod_start	197	movl 0(%esi), %edx # mods->mod_start
198	movq $0xffff800000000000, %r10	198	movq $0xffff800000000000, %r10
199	addq %r10, %rdx	199	addq %r10, %rdx
200	movq %rdx, 8(%rdi)	200	movq %rdx, 8(%rdi)
201		201
202	xorq %rdx, %rdx	202	xorq %rdx, %rdx
203	movl 4(%esi), %edx	203	movl 4(%esi), %edx
204	subl 0(%esi), %edx # mods->mod_end - mods->mod_start	204	subl 0(%esi), %edx # mods->mod_end - mods->mod_start
205	movq %rdx, 16(%rdi)	205	movq %rdx, 16(%rdi)
206		206
207	addl $16, %esi	207	addl $16, %esi
208	addq $16, %rdi	208	addq $16, %rdi
209		209
210	loop mods_loop	210	loop mods_loop
211		211
212	mods_end:	212	mods_end:
213		213
214	bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)	214	bt $6, %eax # mbi->flags[6] (mmap_length, mmap_addr valid)
215	jc mmap_valid	215	jc mmap_valid
216		216
217	xorl %edx, %edx	217	xorl %edx, %edx
218	jmp mmap_invalid	218	jmp mmap_invalid
219		219
220	mmap_valid:	220	mmap_valid:
221	movl 44(%ebx), %ecx # mbi->mmap_length	221	movl 44(%ebx), %ecx # mbi->mmap_length
222	movl 48(%ebx), %esi # mbi->mmap_addr	222	movl 48(%ebx), %esi # mbi->mmap_addr
223	movq $e820table, %rdi	223	movq $e820table, %rdi
224	xorl %edx, %edx	224	xorl %edx, %edx
225		225
226	mmap_loop:	226	mmap_loop:
227	cmpl $0, %ecx	227	cmpl $0, %ecx
228	jle mmap_end	228	jle mmap_end
229		229
230	movl 4(%esi), %eax # mmap->base_addr_low	230	movl 4(%esi), %eax # mmap->base_addr_low
231	movl %eax, (%rdi)	231	movl %eax, (%rdi)
232		232
233	movl 8(%esi), %eax # mmap->base_addr_high	233	movl 8(%esi), %eax # mmap->base_addr_high
234	movl %eax, 4(%rdi)	234	movl %eax, 4(%rdi)
235		235
236	movl 12(%esi), %eax # mmap->length_low	236	movl 12(%esi), %eax # mmap->length_low
237	movl %eax, 8(%rdi)	237	movl %eax, 8(%rdi)
238		238
239	movl 16(%esi), %eax # mmap->length_high	239	movl 16(%esi), %eax # mmap->length_high
240	movl %eax, 12(%rdi)	240	movl %eax, 12(%rdi)
241		241
242	movl 20(%esi), %eax # mmap->type	242	movl 20(%esi), %eax # mmap->type
243	movl %eax, 16(%rdi)	243	movl %eax, 16(%rdi)
244		244
245	movl (%esi), %eax # mmap->size	245	movl (%esi), %eax # mmap->size
246	addl $0x4, %eax	246	addl $0x4, %eax
247	addl %eax, %esi	247	addl %eax, %esi
248	subl %eax, %ecx	248	subl %eax, %ecx
249	addq $MEMMAP_E820_RECORD_SIZE, %rdi	249	addq $MEMMAP_E820_RECORD_SIZE, %rdi
250	incl %edx	250	incl %edx
251	jmp mmap_loop	251	jmp mmap_loop
252		252
253	mmap_end:	253	mmap_end:
254		254
255	mmap_invalid:	255	mmap_invalid:
256	movl %edx, e820counter	256	movl %edx, e820counter
257		257
258	invalid_boot:	258	invalid_boot:
259		259
260	#ifdef CONFIG_SMP	260	#ifdef CONFIG_SMP
261		261
262	# copy AP bootstrap routines below 1 MB	262	# copy AP bootstrap routines below 1 MB
263		263
264	movq $BOOT_OFFSET, %rsi	264	movq $BOOT_OFFSET, %rsi
265	movq $AP_BOOT_OFFSET, %rdi	265	movq $AP_BOOT_OFFSET, %rdi
266	movq $_hardcoded_unmapped_size, %rcx	266	movq $_hardcoded_unmapped_size, %rcx
267	cld	267	cld
268	rep movsb	268	rep movsb
269		269
270	#endif	270	#endif
271		271
272	call main_bsp # never returns	272	call main_bsp # never returns
273		273
274	cli	274	cli
275	hlt	275	hlt
276		276
277	#ifdef CONFIG_FB	277	#ifdef CONFIG_FB
278	.code32	278	.code32
279	vesa_init:	279	vesa_init:
280	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init	280	jmp $gdtselector(VESA_INIT_DES), $vesa_init_real - vesa_init
281		281
282	.code16	282	.code16
283	vesa_init_real:	283	vesa_init_real:
284		284
285	mov %cr0, %eax	285	mov %cr0, %eax
286	and $~1, %eax	286	and $~1, %eax
287	mov %eax, %cr0	287	mov %eax, %cr0
288		288
289	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init	289	jmp $VESA_INIT_SEGMENT, $vesa_init_real2 - vesa_init
290		290
291	vesa_init_real2:	291	vesa_init_real2:
292		292
293	mov $VESA_INIT_SEGMENT, %bx	293	mov $VESA_INIT_SEGMENT, %bx
294		294
295	mov %bx, %es	295	mov %bx, %es
296	mov %bx, %fs	296	mov %bx, %fs
297	mov %bx, %gs	297	mov %bx, %gs
298	mov %bx, %ds	298	mov %bx, %ds
299	mov %bx, %ss	299	mov %bx, %ss
300		300
301	movl $0x0000fffc, %esp	301	movl $0x0000fffc, %esp
302	movl $0x0000fffc, %ebp	302	movl $0x0000fffc, %ebp
303		303
304	#define VESA_INFO_SIZE 1024	304	#define VESA_INFO_SIZE 1024
305		305
306	#define VESA_MODE_ATTRIBUTES_OFFSET 0	306	#define VESA_MODE_ATTRIBUTES_OFFSET 0
307	#define VESA_MODE_LIST_PTR_OFFSET 14	307	#define VESA_MODE_LIST_PTR_OFFSET 14
308	#define VESA_MODE_SCANLINE_OFFSET 16	308	#define VESA_MODE_SCANLINE_OFFSET 16
309	#define VESA_MODE_WIDTH_OFFSET 18	309	#define VESA_MODE_WIDTH_OFFSET 18
310	#define VESA_MODE_HEIGHT_OFFSET 20	310	#define VESA_MODE_HEIGHT_OFFSET 20
311	#define VESA_MODE_BPP_OFFSET 25	311	#define VESA_MODE_BPP_OFFSET 25
312	#define VESA_MODE_PHADDR_OFFSET 40	312	#define VESA_MODE_PHADDR_OFFSET 40
313		313
314	#define VESA_END_OF_MODES 0xffff	314	#define VESA_END_OF_MODES 0xffff
315		315
316	#define VESA_OK 0x4f	316	#define VESA_OK 0x4f
317		317
318	#define VESA_GET_INFO 0x4f00	318	#define VESA_GET_INFO 0x4f00
319	#define VESA_GET_MODE_INFO 0x4f01	319	#define VESA_GET_MODE_INFO 0x4f01
320	#define VESA_SET_MODE 0x4f02	320	#define VESA_SET_MODE 0x4f02
321	#define VESA_SET_PALETTE 0x4f09	321	#define VESA_SET_PALETTE 0x4f09
322		322
323	#define CONFIG_VESA_BPP_a 255	323	#define CONFIG_VESA_BPP_a 255
324		324
325	#if CONFIG_VESA_BPP == 24	325	#if CONFIG_VESA_BPP == 24
326	#define CONFIG_VESA_BPP_VARIANT 32	326	#define CONFIG_VESA_BPP_VARIANT 32
327	#endif	327	#endif
328		328
329	mov $VESA_GET_INFO, %ax	329	mov $VESA_GET_INFO, %ax
330	mov $e_vesa_init - vesa_init, %di	330	mov $e_vesa_init - vesa_init, %di
331	push %di	331	push %di
332	int $0x10	332	int $0x10
333		333
334	pop %di	334	pop %di
335	cmp $VESA_OK, %al	335	cmp $VESA_OK, %al
336	jnz 0f	336	jnz 0f
337		337
338	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si	338	mov 2 + VESA_MODE_LIST_PTR_OFFSET(%di), %si
339	mov %si, %gs	339	mov %si, %gs
340	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si	340	mov VESA_MODE_LIST_PTR_OFFSET(%di), %si
341		341
342	add $VESA_INFO_SIZE, %di	342	add $VESA_INFO_SIZE, %di
343		343
344	1:# Try next mode	344	1:# Try next mode
345	mov %gs:(%si), %cx	345	mov %gs:(%si), %cx
346	cmp $VESA_END_OF_MODES, %cx	346	cmp $VESA_END_OF_MODES, %cx
347	jz 0f	347	jz 0f
348		348
349	inc %si	349	inc %si
350	inc %si	350	inc %si
351	push %cx	351	push %cx
352	push %di	352	push %di
353	push %si	353	push %si
354	mov $VESA_GET_MODE_INFO, %ax	354	mov $VESA_GET_MODE_INFO, %ax
355	int $0x10	355	int $0x10
356		356
357	pop %si	357	pop %si
358	pop %di	358	pop %di
359	pop %cx	359	pop %cx
360	cmp $VESA_OK, %al	360	cmp $VESA_OK, %al
361	jnz 0f	361	jnz 0f
362		362
363	mov $CONFIG_VESA_WIDTH, %ax	363	mov $CONFIG_VESA_WIDTH, %ax
364	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax	364	cmp VESA_MODE_WIDTH_OFFSET(%di), %ax
365	jnz 1b	365	jnz 1b
366		366
367	mov $CONFIG_VESA_HEIGHT, %ax	367	mov $CONFIG_VESA_HEIGHT, %ax
368	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax	368	cmp VESA_MODE_HEIGHT_OFFSET(%di), %ax
369	jnz 1b	369	jnz 1b
370		370
371	mov $CONFIG_VESA_BPP, %al	371	mov $CONFIG_VESA_BPP, %al
372	cmp VESA_MODE_BPP_OFFSET(%di), %al	372	cmp VESA_MODE_BPP_OFFSET(%di), %al
373		373
374	#ifdef CONFIG_VESA_BPP_VARIANT	374	#ifdef CONFIG_VESA_BPP_VARIANT
375	jz 2f	375	jz 2f
376		376
377	mov $CONFIG_VESA_BPP_VARIANT, %al	377	mov $CONFIG_VESA_BPP_VARIANT, %al
378	cmp VESA_MODE_BPP_OFFSET(%di), %al	378	cmp VESA_MODE_BPP_OFFSET(%di), %al
379	#endif	379	#endif
380	jnz 1b	380	jnz 1b
381		381
382	2:	382	2:
383		383
384	mov %cx, %bx	384	mov %cx, %bx
385	or $0xc000, %bx	385	or $0xc000, %bx
386	push %di	386	push %di
387	mov $VESA_SET_MODE, %ax	387	mov $VESA_SET_MODE, %ax
388	int $0x10	388	int $0x10
389		389
390	pop %di	390	pop %di
391	cmp $VESA_OK, %al	391	cmp $VESA_OK, %al
392	jnz 0f	392	jnz 0f
393		393
394	#if CONFIG_VESA_BPP == 8	394	#if CONFIG_VESA_BPP == 8
395		395
396	# Set 3:2:3 VGA palette	396	# Set 3:2:3 VGA palette
397		397
398	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax	398	mov VESA_MODE_ATTRIBUTES_OFFSET(%di), %ax
399	push %di	399	push %di
400	mov $vga323 - vesa_init, %di	400	mov $vga323 - vesa_init, %di
401	mov $0x100, %ecx	401	mov $0x100, %ecx
402		402
403	bt $5, %ax # Test if VGA compatible registers are present	403	bt $5, %ax # Test if VGA compatible registers are present
404	jnc vga_compat	404	jnc vga_compat
405		405
406	# Try VESA routine to set palette	406	# Try VESA routine to set palette
407		407
408	mov $VESA_SET_PALETTE, %ax	408	mov $VESA_SET_PALETTE, %ax
409	xor %bl, %bl	409	xor %bl, %bl
410	xor %dx, %dx	410	xor %dx, %dx
411	int $0x10	411	int $0x10
412		412
413	jmp vga_not_compat	413	jmp vga_not_compat
414		414
415	vga_compat:	415	vga_compat:
416		416
417	# Try VGA registers to set palette	417	# Try VGA registers to set palette
418		418
419	movw $0x3c6, %dx # Set palette mask	419	movw $0x3c6, %dx # Set palette mask
420	movb $0xff, %al	420	movb $0xff, %al
421	outb %al, %dx	421	outb %al, %dx
422		422
423	movw $0x3c8, %dx # First index to set	423	movw $0x3c8, %dx # First index to set
424	xor %al, %al	424	xor %al, %al
425	outb %al, %dx	425	outb %al, %dx
426		426
427	movw $0x3c9, %dx # Data port	427	movw $0x3c9, %dx # Data port
428	vga_loop:	428	vga_loop:
429	movb %es:2(%di), %al	429	movb %es:2(%di), %al
430	outb %al, %dx	430	outb %al, %dx
431		431
432	movb %es:1(%di), %al	432	movb %es:1(%di), %al
433	outb %al, %dx	433	outb %al, %dx
434		434
435	movb %es:(%di), %al	435	movb %es:(%di), %al
436	outb %al, %dx	436	outb %al, %dx
437		437
438	addw $4, %di	438	addw $4, %di
439	loop vga_loop	439	loop vga_loop
440		440
441	vga_not_compat:	441	vga_not_compat:
442		442
443	pop %di	443	pop %di
444		444
445	#endif	445	#endif
446		446
447	mov VESA_MODE_PHADDR_OFFSET(%di), %esi	447	mov VESA_MODE_PHADDR_OFFSET(%di), %esi
448	mov VESA_MODE_WIDTH_OFFSET(%di), %ax	448	mov VESA_MODE_WIDTH_OFFSET(%di), %ax
449	shl $16, %eax	449	shl $16, %eax
450	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax	450	mov VESA_MODE_HEIGHT_OFFSET(%di), %ax
451	mov VESA_MODE_BPP_OFFSET(%di), %bl	451	mov VESA_MODE_BPP_OFFSET(%di), %bl
452	xor %bh, %bh	452	xor %bh, %bh
453	shl $16, %ebx	453	shl $16, %ebx
454	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx	454	mov VESA_MODE_SCANLINE_OFFSET(%di), %bx
455	mov %eax, %edi	455	mov %eax, %edi
456		456
457	8:	457	8:
458		458
459	mov %cr0, %eax	459	mov %cr0, %eax
460	or $1, %eax	460	or $1, %eax
461	mov %eax, %cr0	461	mov %eax, %cr0
462		462
463	jmp 9f	463	jmp 9f
464	9:	464	9:
465		465
466	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)	466	ljmpl $gdtselector(KTEXT32_DES), $(vesa_init_protect - vesa_init + VESA_INIT_SEGMENT << 4)
467		467
468	0:# No prefered mode found	468	0:# No prefered mode found
469	mov $0x111, %cx	469	mov $0x111, %cx
470	push %di	470	push %di
471	push %cx	471	push %cx
472	mov $VESA_GET_MODE_INFO, %ax	472	mov $VESA_GET_MODE_INFO, %ax
473	int $0x10	473	int $0x10
474		474
475	pop %cx	475	pop %cx
476	pop %di	476	pop %di
477	cmp $VESA_OK, %al	477	cmp $VESA_OK, %al
478	jnz 1f	478	jnz 1f
479	jz 2b # Force relative jump	479	jz 2b # Force relative jump
480		480
481	1:	481	1:
482	mov $0x0003, %ax	482	mov $0x0003, %ax
483	int $0x10	483	int $0x10
484	mov $0xffffffff, %edi # EGA text mode used, because of problems with VESA	484	mov $0xffffffff, %edi # EGA text mode used, because of problems with VESA
485	xor %ax, %ax	485	xor %ax, %ax
486	jz 8b # Force relative jump	486	jz 8b # Force relative jump
487		487
488	vga323:	488	vga323:
489	#include "vga323.pal"	489	#include "vga323.pal"
490		490
491	.code32	491	.code32
492	vesa_init_protect:	492	vesa_init_protect:
493	movw $gdtselector(KDATA_DES), %cx	493	movw $gdtselector(KDATA_DES), %cx
494	movw %cx, %es	494	movw %cx, %es
495	movw %cx, %ds # kernel data + stack	495	movw %cx, %ds # kernel data + stack
496	movw %cx, %ss	496	movw %cx, %ss
497	# Simics seems to remove hidden part of GS on entering user mode	497	# Simics seems to remove hidden part of GS on entering user mode
498	# when _visible_ part of GS does not point to user-mode segment	498	# when _visible_ part of GS does not point to user-mode segment
499	movw $gdtselector(UDATA_DES), %cx	499	movw $gdtselector(UDATA_DES), %cx
500	movw %cx, %fs	500	movw %cx, %fs

Subversion Repositories HelenOS

(root)/tags/0.2.0.5/kernel/arch/amd64/src/boot/boot.S – Rev 2302 → 2474